source: branches/test1/Client/Forms/UFormMain.pas

unit UFormMain;

{$mode objfpc}{$H+}

interface

uses
  Registry, Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  StdCtrls, ActnList, Menus, ExtCtrls, USqlDatabase, DOM, XMLRead, XMLWrite,
  UPersistentForm, UTreeState, SpecializedList, SpecializedDictionary,
  URegistry, UCoolTranslator, USystem, UFormItemList;

type
  { TMainForm }

  TMainForm = class(TForm)
  published
    AConnect: TAction;
    AAbout: TAction;
    ADisconnect: TAction;
    AImportStructure: TAction;
    ASettings: TAction;
    AToggleFullscreen: TAction;
    AExit: TAction;
    ActionListItem: TActionList;
    ImageListActions: TImageList;
    MainMenuMain: TMainMenu;
    MenuItem1: TMenuItem;
    MenuItem11: TMenuItem;
    MenuItem12: TMenuItem;
    MenuItem13: TMenuItem;
    MenuItem14: TMenuItem;
    MenuItem15: TMenuItem;
    MenuItem16: TMenuItem;
    MenuItem17: TMenuItem;
    MenuItem18: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem20: TMenuItem;
    MenuItem21: TMenuItem;
    MenuItem22: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    PanelMenu: TPanel;
    PanelData: TPanel;
    PopupMenuItem: TPopupMenu;
    Splitter1: TSplitter;
    StatusBar1: TStatusBar;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    ToolButton4: TToolButton;
    ToolButton5: TToolButton;
    procedure AAboutExecute(Sender: TObject);
    procedure AConnectExecute(Sender: TObject);
    procedure ADisconnectExecute(Sender: TObject);
    procedure AExitExecute(Sender: TObject);
    procedure AImportStructureExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure AToggleFullscreenExecute(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    OriginalBounds: TRect;
    OriginalWindowState: TWindowState;
    ScreenBounds: TRect;
    procedure LoadFromRegistry;
    procedure SaveToRegistry;
    procedure InitDock;
  public
    MainPanelForm: TItemListForm;
    PersistentForm: TPersistentForm;
    Report: TReport;
    procedure UpdateInterface;
  end;

var
  MainForm: TMainForm;

resourcestring
  SItemNotFound = 'Item not found';
  SObjectNotFound = 'Object not found';
  SGroup = 'Groups';
  SItemDeletion = 'Delete items';
  SReallyWantToDelete = 'Really want to delete selected items?';


implementation

uses
  UFormItemView, UFormItemEdit, UFormItemAdd, UFormLogin, UFormSetting, UApplicationInfo,
  UCore, UFormImportStructure, UFormAbout, UFormLoginProfile, UPDClientIni,
  UPDClient, UPDClientMySQL, UPDClientXMLRPC, UFormMenu, UPDClientRegistry;

{$R *.lfm}

{ TMainForm }

procedure TMainForm.LoadFromRegistry;
begin
  with TRegistryEx.Create do
  try
    RootKey := Core.RegistryRootKey;
    OpenKey(Core.RegistryKey, True);
    PanelMenu.Width := ReadIntegerWithDefault('GroupTreeWidth', 200);
    with Core.CoolTranslator1 do
      Language := Languages.SearchByCode(ReadStringWithDefault('LanguageCode', ''));
 finally
    Free;
  end;
end;

procedure TMainForm.SaveToRegistry;
begin
  with TRegistryEx.Create do
  try
    RootKey := Core.RegistryRootKey;
    OpenKey(Core.RegistryKey, True);
    WriteInteger('GroupTreeWidth', PanelMenu.Width);
    with Core.CoolTranslator1 do
      WriteString('LanguageCode', Language.Code);
  finally
    Free;
  end;
end;

procedure TMainForm.InitDock;
begin
  MainPanelForm := TItemListForm.Create(Self);
  MainPanelForm.ManualDock(PanelData, nil, alClient);
  MainPanelForm.Align := alClient;
  FormMenu.ManualDock(PanelMenu, nil, alClient);
  FormMenu.Align := alClient;
  FormMenu.Show;
end;

procedure TMainForm.UpdateInterface;
var
  I: Integer;
begin
  ADisconnect.Enabled := Core.System.Active;
  AConnect.Enabled := not Core.System.Active;
  AImportStructure.Enabled := Core.System.Active;
  if Assigned(MainPanelForm) then
    Caption := MainPanelForm.Caption + ' - ' + ApplicationInfo.Name
    else Caption := ApplicationInfo.Name;
  Application.Title := Caption;
  if Core.System.Active then
  with Core.System.Client do
    StatusBar1.Panels[0].Text := User + '@' + Host + ':' + IntToStr(Port) + '/' + Schema
    else StatusBar1.Panels[0].Text := '';

  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  Report := TReport.Create;
  Report.Base := Core.System;
  PersistentForm := TPersistentForm.Create;
  PersistentForm.RegistryKey := Core.RegistryKey;
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  FreeAndNil(MainPanelForm);
  FreeAndNil(Report);
  FreeAndNil(PersistentForm);
end;

procedure TMainForm.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  ADisconnect.Execute;
  PersistentForm.Save(Self);
  SaveToRegistry;
end;

procedure TMainForm.ASettingsExecute(Sender: TObject);
begin
  try
    SettingForm := TSettingForm.Create(nil);
    Core.CoolTranslator1.TranslateComponentRecursive(SettingForm);
    SettingForm.ShowModal;
  finally
    SettingForm.Free;
  end;
end;

procedure TMainForm.AToggleFullscreenExecute(Sender: TObject);
begin
   if BorderStyle <> bsNone then begin
    // To full screen
    OriginalWindowState := WindowState;
    OriginalBounds := BoundsRect;

    BorderStyle := bsNone;
    ScreenBounds := Screen.MonitorFromWindow(Handle).BoundsRect;
    with ScreenBounds do
      SetBounds(Left, Top, Right - Left, Bottom - Top) ;
  end else begin
    // From full screen
    {$IFDEF MSWINDOWS}
    BorderStyle := bsSizeable;
    {$ENDIF}
    if OriginalWindowState = wsMaximized then
      WindowState := wsMaximized
    else
      with OriginalBounds do
        SetBounds(Left, Top, Right - Left, Bottom - Top) ;
    {$IFDEF LINUX}
    BorderStyle := bsSizeable;
    {$ENDIF}
  end;
end;

procedure TMainForm.AExitExecute(Sender: TObject);
begin
  Close;
end;

procedure TMainForm.AImportStructureExecute(Sender: TObject);
begin
  try
    ImportStructureForm := TImportStructureForm.Create(MainForm);
    Core.CoolTranslator1.TranslateComponentRecursive(ImportStructureForm);
    ImportStructureForm.ShowModal;
  finally
    ImportStructureForm.Free;
  end;
end;

procedure TMainForm.AConnectExecute(Sender: TObject);
begin
  try
    LoginForm := TLoginForm.Create(MainForm);
    Core.CoolTranslator1.TranslateComponentRecursive(LoginForm);
    Core.Profiles.LoadFromRegistry(Core.RegistryRootKey, Core.RegistryKey);
    if LoginForm.ShowModal = mrOK then begin
      with TConnectProfile(Core.Profiles[Core.LastProfile]) do begin
        FreeAndNil(Core.System.Client);
        if Protocol = cpMySQL then Core.System.Client := TPDClientMySQL.Create
          //else if Protocol = cpDirect then Core.System.Client := TPDClientDirect.Create
          else if Protocol = cpXMLRPC then Core.System.Client := TPDClientXMLRPC.Create
          else if Protocol = cpINI then Core.System.Client := TPDClientIni.Create
          else if Protocol = cpRegistry then Core.System.Client := TPDClientRegistry.Create;
        Core.System.Client.Host := HostName;
        Core.System.Client.Schema := Database;
        Core.System.Client.User := Core.LastUserName;
        Core.System.Client.Password := Core.LastPassword;
        Core.System.Client.Port := Port;
      end;
      try
        Core.System.Active := True;
        FormMenu.LoadTree;
      except
        on E: Exception do ShowMessage(E.Message);
      end;
    end;
  finally
    LoginForm.Free;
    UpdateInterface;
  end;
end;

procedure TMainForm.ADisconnectExecute(Sender: TObject);
begin
  if Assigned(Core.System.Client) then
  if Core.System.Active then begin
    Core.System.Active := False;
    FormMenu.TreeViewMenu.Items.Clear;
  end;
  UpdateInterface;
end;

procedure TMainForm.AAboutExecute(Sender: TObject);
begin
  try
    AboutForm := TAboutForm.Create(nil);
    Core.CoolTranslator1.TranslateComponentRecursive(AboutForm);
    AboutForm.ShowModal;
  finally
    FreeAndNil(AboutForm);
  end;
end;

procedure TMainForm.FormShow(Sender: TObject);
begin
  PersistentForm.Load(Self);
  LoadFromRegistry;
  InitDock;
  AConnect.Execute;
end;

end.