source: branches/test1/Client/Forms/UFormItemView.pas

unit UFormItemView;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ExtCtrls, ComCtrls, USqlDatabase, USystem, SpecializedList;

type

  { TItemViewForm }

  TItemViewForm = class(TForm)
    ButtonClose: TButton;
    ButtonEdit: TButton;
    ListView1: TListView;
    Panel1: TPanel;
    Panel2: TPanel;
    PanelControls: TPanel;
    Splitter1: TSplitter;
    TabControl1: TTabControl;
    procedure ButtonCancelClick(Sender: TObject);
    procedure ButtonCloseClick(Sender: TObject);
    procedure ButtonEditClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormResize(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1Resize(Sender: TObject);
    procedure TabControl1Change(Sender: TObject);
  private
    SubListObject: TChronisObject;
    TabObjectList: TListInteger;
    TabDataTypeList: TListObject;
    procedure LoadSubList;
    { private declarations }
  public
    SelectedObject: TChronisObject;
    SelectedItemId: Integer;
    Report: TReport;
    procedure BuildControls;
  end;

var
  ItemViewForm: TItemViewForm;

implementation

uses
  UFormMain, UFormItemEdit, UDataTypes, UCore;

{$R *.lfm}

resourcestring
  SExpectedOneRow = 'Expected one row';

{ TItemViewForm }

procedure TItemViewForm.FormClose(Sender: TObject; var CloseAction: TCloseAction
  );
begin
  MainForm.PersistentForm.Save(Self);
end;

procedure TItemViewForm.FormCreate(Sender: TObject);
begin
  SubListObject := TChronisObject.Create;
  SubListObject.Base := Core.System;
  Report := TReport.Create;
  Report.Base := Core.System;
  TabObjectList := TListInteger.Create;
  TabDataTypeList := TListObject.Create;
  TabDataTypeList.OwnsObjects := False;
  TabControl1.Tabs.Clear;
  SelectedObject := TChronisObject.Create;
  SelectedObject.Base := Core.System;
end;

procedure TItemViewForm.FormDestroy(Sender: TObject);
begin
  SubListObject.Free;
  Report.Free;
  TabObjectList.Free;
  TabDataTypeList.Free;
  SelectedObject.Free;
end;

procedure TItemViewForm.FormResize(Sender: TObject);
begin
  ListView1Resize(Self);
end;

procedure TItemViewForm.ButtonCancelClick(Sender: TObject);
begin
  Close;
end;

procedure TItemViewForm.ButtonCloseClick(Sender: TObject);
begin
  Close;
end;

procedure TItemViewForm.ButtonEditClick(Sender: TObject);
var
  NewItemEditForm: TItemEditForm;
begin
  try
    NewItemEditForm := TItemEditForm.Create(nil);
    NewItemEditForm.SelectedObject.Assign(SelectedObject);
    NewItemEditForm.SelectedItemId := SelectedItemId;
    NewItemEditForm.Caption := NewItemEditForm.Caption + ' ' + SelectedObject.Name;
    NewItemEditForm.ShowModal;
  finally
    NewItemEditForm.Free;
  end;
end;

procedure TItemViewForm.FormShow(Sender: TObject);
begin
  MainForm.PersistentForm.Load(Self);
  BuildControls;
  LoadSubList;
end;

procedure TItemViewForm.ListView1Data(Sender: TObject; Item: TListItem);
var
  I: Integer;
begin
  if Item.Index < Report.Count then
  with TReportLine(Report[Item.Index]) do begin
    Item.Caption := Items[0];
    for I := 1 to Items.Count - 1 do
    if not TReportColumn(Report.Columns[I]).VirtualItem then
      Item.SubItems.Add(Items[I]);
  end;
end;

procedure TItemViewForm.BuildControls;
var
  NewControl: TControl;
  LastTop: Integer;
  I: Integer;
  Column: Integer;
  DataType: TDataType;
const
  ColumnCount = 2;
begin
  LastTop := 8;
  Column := 0;
  Report.Load(SelectedObject, SelectedObject.PrimaryKey + ' = ' +
    IntToStr(SelectedItemId));
  for I := PanelControls.ControlCount - 1 downto 0 do
    PanelControls.Controls[I].Free;

  TabControl1.Tabs.Clear;
  TabObjectList.Clear;
  TabDataTypeList.Clear;
  // Load column names

  if Report.Count > 1 then raise Exception.Create(SExpectedOneRow);
  if Report.Count > 0 then
  for I := 0 to Report.Columns.Count - 1 do begin
    DataType := TReportColumn(Report.Columns[I]).CustomType;
    DataType.LoadDef(TReportColumn(Report.Columns[I]).CustomType.CustomType);
    if DataType is TDataTypeRelationMany then begin
      TabControl1.Tabs.Add(TReportColumn(Report.Columns[I]).Caption);
      TabDataTypeList.Add(DataType);
      TabObjectList.Add(SelectedItemId);
    end else begin
      NewControl := TLabel.Create(PanelControls);
      NewControl.Parent := PanelControls;
      NewControl.Top := LastTop;
      NewControl.Left := Column * Width div ColumnCount + 10;
      TLabel(NewControl).Caption := TReportColumn(Report.Columns[I]).Caption + ':';

      NewControl := TLabel.Create(PanelControls);
      NewControl.Parent := PanelControls;
      NewControl.Top := LastTop;
      NewControl.Left := Column * Width div ColumnCount + (Width div ColumnCount) div 2;
      TLabel(NewControl).Caption := TReportLine(Report[0]).Items[I];

      Column := (Column + 1) mod 2;
      if Column = 0 then LastTop := LastTop + 24;
    end;
  end;
  Panel2.Visible := TabControl1.Tabs.Count > 0;
end;

procedure TItemViewForm.LoadSubList;
begin
  //SelectedObjectId := 0;
  if (TabControl1.TabIndex >= 0) and (TabControl1.TabIndex < TabControl1.Tabs.Count) then
  with ListView1 do
  with TDataTypeRelationMany(TabDataTypeList[TabControl1.TabIndex]) do begin
    Visible := True;
    SubListObject.Load(ObjectId);
    Report.Load(SubListObject, '`' + PropertyName + '`=' + IntToStr(TabObjectList[TabControl1.TabIndex]));

    Report.FillListColumns(Columns);
    Items.Count := Report.Count;
    Refresh;
  end;
  ListView1Resize(Self);
end;

procedure TItemViewForm.ListView1Resize(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ListView1.Columns.Count - 1 do
    ListView1.Columns[I].Width := ListView1.Width div ListView1.Columns.Count;
end;

procedure TItemViewForm.TabControl1Change(Sender: TObject);
begin
  LoadSubList;
end;


end.