source: trunk/Car.pas

unit Car;

interface

uses
  Classes, SysUtils, Generics.Collections, Generics.Defaults, DateUtils,
  PrefixMultiplier;

type
  TRents = class;
  TCompany = class;

  TEngineType = (etNone, etPetrol, etDiesel, etElectric, etCng, etLpg);

  { TCar }

  TCar = class
    Name: string;
    EngineType: TEngineType;
    Rents: TRents;
    constructor Create;
    destructor Destroy; override;
    function GetConsumption: Double;
  end;

  { TCars }

  TCars = class(TObjectList<TCar>)
    function AddNew(Name: string): TCar;
    function SearchByName(Name: string): TCar;
    function SearchByNameEngine(Name: string; EngineType: TEngineType): TCar;
  end;

  { TCarComparer }

  TCarComparer = class(TInterfacedObject, IComparer<TCar>)
    function Compare(constref Left, Right: TCar): Integer; overload;
  end;

  { TRent }

  TRent = class
    Time: TDateTime;
    Car: TCar;
    Company: TCompany;
    Price: Double;
    PriceWithFuel: Double;
    Distance: Double;
    Consumption: Double;
    Odometer: Integer;
    procedure Assign(Source: TRent);
    function GetEmission: Double;
    function GetFuel: Double;
  end;

  { TRents }

  TRents = class(TObjectList<TRent>)
    function AddNew: TRent;
  end;

  { TCompany }

  TCompany = class
    Name: string;
    Rents: TRents;
    constructor Create;
    destructor Destroy; override;
    function GetPrice: Double;
    function GetPriceWithFuel: Double;
    function GetAverageOdometer: Integer;
  end;

  { TCompanies }

  TCompanies = class(TObjectList<TCompany>)
    function AddNew(Name: string): TCompany;
    function SearchByName(Name: string): TCompany;
  end;

  TLogEvent = procedure (Text: string) of object;

  { TSummary }

  TSummary = class
  private
    FOnLog: TLogEvent;
    procedure Log(Text: string);
    procedure SaveAndFreeCar(var CarName: string; var EngineType: TEngineType;
      var CompanyName: string; var Distance: Double; var Odometer: Integer;
      var Price: double; var PriceWithFuel: double; var RentTime: TDateTime;
      var Consumption: double);
  public
    Cars: TCars;
    Rents: TRents;
    Companies: TCompanies;
    constructor Create;
    destructor Destroy; override;
    procedure LoadFromFile(FileName: string);
    function Print: string;
    property OnLog: TLogEvent read FOnLog write FOnLog;
  end;

  { TSummaryYear }

  TSummaryYear = class
    Year: Integer;
    Price: Double;
    PriceWithFuel: Double;
    Distance: Double;
    RentCount: Integer;
    Companies: TCompanies;
    constructor Create;
    destructor Destroy; override;
  end;

  { TSummaryYears }

  TSummaryYears = class(TObjectList<TSummaryYear>)
    function AddNew(Year: Integer): TSummaryYear;
    function SearchByYear(Year: Integer): TSummaryYear;
  end;


implementation

const
  EngineTypeText: array[TEngineType] of string = ('Žádný', 'Benzín', 'Diesel', 'Elektrické',
    'CNG', 'LPG');
  EngineTypeUnit: array[TEngineType] of string = ('', 'l', 'l', 'Wh',
    'g', 'g');
  DistanceUnits: array[TEngineType] of Integer = (1, 100, 100, 1, 100, 100);

function Explode(Separator: string; Data: string): TStringArray;
var
  Index: Integer;
begin
  Result := Default(TStringArray);
  repeat
    Index := Pos(Separator, Data);
    if Index > 0 then begin
      SetLength(Result, Length(Result) + 1);
      Result[High(Result)] := Copy(Data, 1, Index - 1);
      Delete(Data, 1, Index + Length(Separator) - 1);
    end else Break;
  until False;
  if Data <> '' then begin
    SetLength(Result, Length(Result) + 1);
    Result[High(Result)] := Data;
  end;
end;

function Trim(const S: string; What: Char): string; overload;
var
  Ofs, Len: Integer;
begin
  Len := Length(S);
  while (Len > 0) and (S[Len] = What) do
    Dec(Len);
  Ofs := 1;
  while (Ofs <= Len) and (S[Ofs] = What) do
    Inc(Ofs);
  Result := Copy(S, Ofs, 1 + Len - Ofs);
end;

{ TSummaryYear }

constructor TSummaryYear.Create;
begin
  Companies := TCompanies.Create(False);
end;

destructor TSummaryYear.Destroy;
begin
  FreeAndNil(Companies);
  inherited;
end;

{ TSummaryYears }

function TSummaryYears.AddNew(Year: Integer): TSummaryYear;
begin
  Result := TSummaryYear.Create;
  Result.Year := Year;
  Add(Result);
end;

function TSummaryYears.SearchByYear(Year: Integer): TSummaryYear;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and (Items[I].Year <> Year) do Inc(I);
  if I < Count then Result := Items[I]
    else Result := nil;
end;

{ TCompanies }

function TCompanies.AddNew(Name: string): TCompany;
begin
  Result := TCompany.Create;
  Result.Name := Name;
  Add(Result);
end;

function TCompanies.SearchByName(Name: string): TCompany;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and (Items[I].Name <> Name) do Inc(I);
  if I < Count then Result := Items[I]
    else Result := nil;
end;

{ TCompany }

constructor TCompany.Create;
begin
  Rents := TRents.Create(False);
end;

destructor TCompany.Destroy;
begin
  FreeAndNil(Rents);
  inherited;
end;

function TCompany.GetPrice: Double;
var
  I: Integer;
begin
  Result := 0;
  for I := 0 to Rents.Count - 1 do begin
    Result := Result + Rents[I].Price;
  end;
end;

function TCompany.GetPriceWithFuel: Double;
var
  I: Integer;
begin
  Result := 0;
  for I := 0 to Rents.Count - 1 do begin
    Result := Result + Rents[I].PriceWithFuel;
  end;
end;

function TCompany.GetAverageOdometer: Integer;
var
  I: Integer;
  Count: Integer;
begin
  Result := 0;
  Count := 0;
  for I := 0 to Rents.Count - 1 do
  if Rents[I].Odometer > 0 then begin
    Result := Result + Rents[I].Odometer;
    Inc(Count);
  end;
  if Count > 0 then
    Result := Result div Count;
end;

{ TRent }

procedure TRent.Assign(Source: TRent);
begin
  Time := Source.Time;
  Price := Source.Price;
  PriceWithFuel := Source.PriceWithFuel;
  Distance := Source.Distance;
  Consumption := Source.Consumption;
  Odometer := Source.Odometer;
end;

function TRent.GetEmission: Double;
begin
  // https://www.autolexicon.net/cs/articles/vypocet-emisi-co2/
  case Car.EngineType of
    etPetrol: Result := GetFuel * 2390;
    etDiesel: Result := GetFuel * 2640;
    etLpg: Result := GetFuel * 1660;
    etCng: Result := GetFuel * 2666;
    etElectric: Result := GetFuel * 1-17;
  end;
end;

function TRent.GetFuel: Double;
begin
  Result := Distance / DistanceUnits[Car.EngineType] * Consumption;
end;

{ TCarComparer }

function TCarComparer.Compare(constref Left, Right: TCar): Integer;
begin
  if Left.Name > Right.Name then Result := 1
  else if Left.Name < Right.Name then Result := -1
  else Result := 0;
end;

{ TRents }

function TRents.AddNew: TRent;
begin
  Result := TRent.Create;
  Add(Result);
end;

{ TCar }

constructor TCar.Create;
begin
  Rents := TRents.Create(False);
end;

destructor TCar.Destroy;
begin
  FreeAndNil(Rents);
  inherited;
end;

function TCar.GetConsumption: Double;
var
  I: Integer;
  TotalCount: Integer;
begin
  Result := 0;
  TotalCount := 0;
  for I := 0 to Rents.Count - 1 do begin
    if Rents[I].Consumption > 0 then begin
      Result := Result + Rents[I].Consumption;
      Inc(TotalCount);
    end;
  end;
  if TotalCount > 0 then Result := Result / TotalCount;
end;

{ TCars }

function TCars.AddNew(Name: string): TCar;
begin
  Result := TCar.Create;
  Result.Name := Name;
  Add(Result);
end;

function TCars.SearchByName(Name: string): TCar;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and (Items[I].Name <> Name) do Inc(I);
  if I < Count then Result := Items[I]
    else Result := nil;
end;

function TCars.SearchByNameEngine(Name: string; EngineType: TEngineType): TCar;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and ((Items[I].Name <> Name) or
    (Items[I].EngineType <> EngineType)) do Inc(I);
  if I < Count then Result := Items[I]
    else Result := nil;
end;

{ TSummary }

constructor TSummary.Create;
begin
  Cars := TCars.Create;
  Rents := TRents.Create;
  Companies := TCompanies.Create;
end;

destructor TSummary.Destroy;
begin
  FreeAndNil(Companies);
  FreeAndNil(Rents);
  FreeAndNil(Cars);
  inherited;
end;

procedure TSummary.LoadFromFile(FileName: string);
var
  I: Integer;
  Lines: TStringList;
  Line: string;
  CarComparer: TCarComparer;
  ValueDouble: Double;
  ValueDate: TDateTime;
  Parts: TStringArray;
  Part: string;
  Odometer: Integer;
  ValueInteger: Integer;
  InBetween: string;
  LeftIndex: Integer;
  RightIndex: Integer;
  CarName: string;
  EngineType: TEngineType;
  CompanyName: string;
  Distance: double;
  Price: double;
  PriceWithFuel: double;
  RentTime: TDateTime;
  Consumption: double;
const
  DistanceText = '* Vzdálenost:';
  DistanceUnit = 'km';
  PriceText = '* Půjčení:';
  PriceWithFuelText = '* Půjčení včetně paliva:';
  PriceWithFuelText2 = '* Půjčení včetně energie:';
  PriceUnit = 'Kč';
  ConsumptionText = '* Průměrná spotřeba:';
  ConsumptionUnit = 'l/100km';
  ConsumptionUnitElectric = 'Wh/km';
  ConsumptionUnitCng = 'Kg/100km';
  CompanyText = '* Půjčovna:';
  DateText = '* Datum:';
  BrandText = '* Značka:';
  TableLineStartText = '| ';
  TableLineCellSeparator = '||';
begin
  Lines := TStringList.Create;
  Lines.LoadFromFile(FileName);
  for I := 0 to Lines.Count - 1 do begin
    Line := Lines[I];
    if Pos('==', Line) > 0 then begin
      SaveAndFreeCar(CarName, EngineType, CompanyName, Distance, Odometer, Price,
        PriceWithFuel, RentTime, Consumption);
      CarName := Trim(Line, '=');
    end else
    if Line.StartsWith(DistanceText) then begin
      Line := Copy(Line, Length(DistanceText) + 1, MaxInt);
      LeftIndex := Pos('(', Line);
      RightIndex := Pos(')', Line);
      if (LeftIndex > 0) and (RightIndex > 0) then begin
        InBetween := Copy(Line, LeftIndex + 1, RightIndex - LeftIndex - 1);
        if Pos('-', InBetween) > 0 then InBetween := Copy(InBetween, Pos('-', InBetween) + 1, MaxInt);
        if TryStrToInt(Trim(InBetween), ValueInteger) then
          Odometer := ValueInteger;
        Line := Copy(Line, 1, LeftIndex - 1) + Copy(Line, RightIndex + 1, MaxInt);
      end;
      if Pos(DistanceUnit, Line) > 0 then
        Line := Trim(Copy(Line, 1, Pos(DistanceUnit, Line) - 1));
      if TryStrToFloat(Line, ValueDouble) then begin
        Distance := ValueDouble;
      end else begin
        Log('Špatná vzdálenost ' + Line);
      end;
    end else
    if Line.StartsWith(BrandText) then begin
      Line := LowerCase(Copy(Line, Length(BrandText) + 1, MaxInt));
      if Line.Contains('diesel') then EngineType := etDiesel
      else if Line.Contains('lpg') then EngineType := etLpg
      else if Line.Contains('kwh') then EngineType := etElectric;
    end else
    if Line.StartsWith(PriceText) then begin
      Line := Copy(Line, Length(PriceText) + 1, MaxInt);
      if Pos(PriceUnit, Line) > 0 then
        Line := Trim(Copy(Line, 1, Pos(PriceUnit, Line) - 1));
      if TryStrToFloat(Line, ValueDouble) then begin
        Price := ValueDouble;
      end else begin
        Log('Špatná cena ' + Line);
      end
    end else
    if Line.StartsWith(PriceWithFuelText) then begin
      Line := Copy(Line, Length(PriceWithFuelText) + 1, MaxInt);
      if Pos(PriceUnit, Line) > 0 then
        Line := Trim(Copy(Line, 1, Pos(PriceUnit, Line) - 1));
      if TryStrToFloat(Line, ValueDouble) then begin
        PriceWithFuel := ValueDouble;
      end else begin
        Log('Špatná cena včetně paliva ' + Line);
      end
    end else
    if Line.StartsWith(PriceWithFuelText2) then begin
      Line := Copy(Line, Length(PriceWithFuelText2) + 1, MaxInt);
      if Pos(PriceUnit, Line) > 0 then
        Line := Trim(Copy(Line, 1, Pos(PriceUnit, Line) - 1));
      if TryStrToFloat(Line, ValueDouble) then begin
        PriceWithFuel := ValueDouble;
      end else begin
        Log('Špatný cena včetně energie ' + Line);
      end
    end else
    if Line.StartsWith(DateText) then begin
      Line := Trim(Copy(Line, Length(DateText) + 1, MaxInt));
      if TryStrToDate(Line, ValueDate) then begin
        RentTime := ValueDate;
      end else begin
        Log('Špatný datum ' + Line);
      end;
    end else
    if Line.StartsWith(ConsumptionText) then begin
      Line := Copy(Line, Length(ConsumptionText) + 1, MaxInt);
      if Pos(ConsumptionUnit, Line) > 0 then begin
        Line := Trim(Copy(Line, 1, Pos(ConsumptionUnit, Line) - 1));
        if EngineType = etNone then
          EngineType := etPetrol;
        if TryStrToFloat(Line, ValueDouble) then
          Consumption := ValueDouble;
      end;
      if Pos(ConsumptionUnitElectric, Line) > 0 then begin
        Line := Trim(Copy(Line, 1, Pos(ConsumptionUnitElectric, Line) - 1));
        if EngineType = etNone then
          EngineType := etElectric;
        if TryStrToFloat(Line, ValueDouble) then
          Consumption := ValueDouble;
      end;
      if Pos(ConsumptionUnitCng, Line) > 0 then begin
        Line := Trim(Copy(Line, 1, Pos(ConsumptionUnitCng, Line) - 1));
        if EngineType = etNone then
          EngineType := etCng;
        if TryStrToFloat(Line, ValueDouble) then
          Consumption := ValueDouble * 1000;
      end;
    end else
    if Line.StartsWith(CompanyText) then begin
      CompanyName := Trim(Copy(Line, Length(CompanyText) + 1, MaxInt));
    end else
    if Line.StartsWith(TableLineStartText) then begin
      Parts := Explode(TableLineCellSeparator, Line);
      if Length(Parts) > 4 then begin
        Part := Parts[4];
        Part := Trim(Part);
        if TryStrToInt(Part, Odometer) and (Odometer = 0) then
          Odometer := Odometer;
      end;
    end else begin
//      Line := Trim(Line);
    end;
  end;
  SaveAndFreeCar(CarName, EngineType, CompanyName, Distance, Odometer, Price,
    PriceWithFuel, RentTime, Consumption);
  Lines.Free;
  CarComparer := TCarComparer.Create;
  Cars.Sort(CarComparer);
end;

function TSummary.Print: string;
var
  I: Integer;
  TotalDistance: Double;
  TotalPrice: Double;
  TotalPriceWithFuel: Double;
  TotalEmission: Double;
  TotalFuel: array[TEngineType] of Double;
  CarName: string;
  CompanyName: string;
  E: TEngineType;
  PrefixMultiplier: TPrefixMultiplier;
  SummaryYears: TSummaryYears;
  SummaryYear: TSummaryYear;
  Year: Integer;

procedure AddLine(Text: string = '');
begin
  Result := Result + Text + LineEnding;
end;

begin
  PrefixMultiplier := TPrefixMultiplier.Create(nil);
  SummaryYears := TSummaryYears.Create;

  TotalDistance := 0;
  TotalPrice := 0;
  TotalPriceWithFuel := 0;
  TotalEmission := 0;
  for E := Low(TEngineType) to High(TEngineType) do
    TotalFuel[E] := 0;
  for I := 0 to Rents.Count - 1 do
  with TRent(Rents[I]) do begin
    TotalDistance := TotalDistance + Distance;
    TotalPrice := TotalPrice + Price;
    TotalPriceWithFuel := TotalPriceWithFuel + PriceWithFuel;
    TotalEmission := TotalEmission + GetEmission;
    TotalFuel[Car.EngineType] := TotalFuel[Car.EngineType] + GetFuel;

    Year := YearOf(Time);
    SummaryYear := SummaryYears.SearchByYear(Year);
    if not Assigned(SummaryYear) then begin
      SummaryYear := SummaryYears.AddNew(Year);
    end;
    SummaryYear.Distance := SummaryYear.Distance + Distance;
    SummaryYear.Price := SummaryYear.Price + Price;
    SummaryYear.PriceWithFuel := SummaryYear.PriceWithFuel + PriceWithFuel;
    Inc(SummaryYear.RentCount);
    if SummaryYear.Companies.IndexOf(Company) = -1 then
      SummaryYear.Companies.Add(Company);
  end;

  AddLine;
  AddLine('=Souhrn=');
  AddLine('* Počet půjčení: ' + IntToStr(Rents.Count));
  AddLine('* Cena půjčení: ' + FloatToStr(TotalPrice) + ' Kč');
  AddLine('* Cena půjčení včetně paliva: ' + FloatToStr(TotalPriceWithFuel) + ' Kč');
  AddLine('* Vzdálenost: ' + FloatToStr(TotalDistance) + ' km');
  for E := Succ(Low(TEngineType)) to High(TEngineType) do
    AddLine('* Palivo ' + EngineTypeText[E] + ': ' + PrefixMultiplier.Add(TotalFuel[E], BasePrefixMultipliers, EngineTypeUnit[E]));
  AddLine('* Emise CO2: ' + FloatToStr(TotalEmission / 1000) + ' Kg');

  AddLine;
  AddLine('==Roky==');
  AddLine('{| class="wikitable sortable"');
  AddLine('! Rok !! Cena [Kč] !! Cena včetně paliva [Kč] !! Vzdálenost [km] !! Zápůjček !! Půjčoven');
  AddLine('|-');
  for I := 0 to SummaryYears.Count - 1 do
  with TSummaryYear(SummaryYears[I]) do begin
    AddLine('| ' + IntToStr(Year) + ' || ' + FloatToStr(Price) + ' || ' +
      FloatToStr(PriceWithFuel) + ' || ' +
      FloatToStr(Distance) + ' || ' + IntToStr(RentCount) + ' || ' +
      IntToStr(Companies.Count));
    if I < SummaryYears.Count - 1 then AddLine('|-');
  end;
  AddLine('|}');

  AddLine;
  AddLine('==Auta==');
  AddLine('{| class="wikitable sortable"');
  AddLine('! Jméno !! Půjčení !! Průměrná spotřeba !! Typ paliva');
  AddLine('|-');
  for I := 0 to Cars.Count - 1 do
  with TCar(Cars[I]) do begin
    AddLine('| ' + Name + ' || ' + IntToStr(Rents.Count) + ' || ' +
      FloatToStr(Round(GetConsumption * 100) / 100) + ' || ' + EngineTypeText[EngineType]);
    if I < Cars.Count - 1 then AddLine('|-');
  end;
  AddLine('|}');

  AddLine;
  AddLine('==Půjčovny==');
  AddLine('{| class="wikitable sortable"');
  AddLine('! Jméno !! Půjčení !! Celkem cena [Kč] !! Celkem cena s palivem [Kč] !! Průměrně odometr [Km]');
  AddLine('|-');
  for I := 0 to Companies.Count - 1 do
  with TCompany(Companies[I]) do begin
    AddLine('| ' + Name + ' || ' + IntToStr(Rents.Count) + ' || ' +
      FloatToStr(GetPrice) + ' || ' + FloatToStr(GetPriceWithFuel) + ' || ' +
      IntToStr(GetAverageOdometer));
    if I < Companies.Count - 1 then AddLine('|-');
  end;
  AddLine('|}');

  AddLine;
  AddLine('==Zápůjčky==');
  AddLine('{| class="wikitable sortable"');
  AddLine('! Datum !! Auto !! Půjčovna !! Cena celkem [Kč] !! Celkem cena s palivem [Kč] !! Vzdálenost [km] !! Spotřeba !! Typ paliva || Energie');
  AddLine('|-');
  for I := 0 to Rents.Count - 1 do
  with TRent(Rents[I]) do begin
    if Assigned(Car) then CarName := Car.Name else CarName := '';
    if Assigned(Company) then CompanyName := Company.Name else CompanyName := '';
    AddLine('| ' + DateToStr(Time) + ' || ' + CarName + ' || ' +
      CompanyName + ' || ' + FloatToStr(Price) + ' || ' +
      FloatToStr(PriceWithFuel) + ' || ' +
      FloatToStr(Distance) + ' || ' + FloatToStr(Consumption) + ' || ' +
      EngineTypeText[Car.EngineType] + ' || ' + FloatToStr(GetFuel));
    if I < Rents.Count - 1 then AddLine('|-');
  end;
  AddLine('|}');

  SummaryYears.Free;
  PrefixMultiplier.Free;
end;

procedure TSummary.Log(Text: string);
begin
  if Assigned(FOnLog) then FOnLog(Text);
end;

procedure TSummary.SaveAndFreeCar(var CarName: string;
  var EngineType: TEngineType; var CompanyName: string; var Distance: Double;
  var Odometer: Integer; var Price: double; var PriceWithFuel: double;
  var RentTime: TDateTime; var Consumption: double);
var
  Car: TCar;
  Rent: TRent;
  Company: TCompany;
begin
  if EngineType = etNone then EngineType := etPetrol;
  if CarName <> '' then begin
    Car := Cars.SearchByNameEngine(CarName, EngineType);
    if not Assigned(Car) then begin
      Car := Cars.AddNew(CarName);
      Car.EngineType := EngineType;
    end;

    Rent := Rents.AddNew;
    Car.Rents.Add(Rent);
    Rent.Car := Car;
    Rent.Odometer := Odometer;
    Rent.Distance := Distance;
    Rent.Price := Price;
    Rent.PriceWithFuel := PriceWithFuel;
    Rent.Time := RentTime;
    Rent.Consumption := Consumption;

    Company := Companies.SearchByName(CompanyName);
    if not Assigned(Company) then begin
      Company := Companies.AddNew(CompanyName);
    end;
    Company.Rents.Add(Rent);
    Rent.Company := Company;
  end;

  CarName := '';
  EngineType := etNone;
  CompanyName := '';
  Odometer := 0;
  Distance := 0;
  Price := 0;
  PriceWithFuel := 0;
  RentTime := 0;
  Consumption := 0;
end;

end.