source: trunk/Units/UProject.pas

unit UProject;

{$mode delphi}

interface

uses
  Classes, SysUtils, UVCS, UBackend, Contnrs, DOM, XMLRead, XMLWrite, UXMLUtils,
  LazFileUtils;

type

{ TProject }

  TProject = class
  private
    FBackend: TBackend;
    function GetDirectory: string;
    function GetRepositoryURL: string;
    procedure SetDirectory(AValue: string);
    procedure SetRepositoryURL(AValue: string);
    procedure SetBackend(AValue: TBackend);
  public
    WorkingCopy: TWorkingCopy;
    Repository: TRepository;
    procedure Open(Directory: string);
    constructor Create;
    destructor Destroy; override;
    procedure LoadXMLNOde(Node: TDOMNode);
    procedure SaveXMLNOde(Node: TDOMNode);
    property Backend: TBackend read FBackend write SetBackend;
    property Directory: string read GetDirectory write SetDirectory;
    property RepositoryURL: string read GetRepositoryURL write SetRepositoryURL;
  end;

  { TProjects }

  TProjects = class(TObjectList)
    procedure LoadXMLNode(Node: TDOMNode);
    procedure SaveXMLNode(Node: TDOMNode);
  end;

  { TProjectGroup }

  TProjectGroup = class
    FileName: string;
    Projects: TProjects;
    constructor Create;
    destructor Destroy; override;
    procedure LoadFromFile(FileName: string);
    procedure SaveToFile(FileName: string);
  end;


implementation

resourcestring
  SWrongFileFormat = 'Wrong file format';

{ TProjects }

procedure TProjects.LoadXMLNode(Node: TDOMNode);
var
  NewProject: TProject;
  Node2: TDOMNode;
begin
  Node2 := Node.FirstChild;
  while Assigned(Node2) and (Node2.NodeName = 'Project') do begin
    NewProject := TProject.Create;
    NewProject.LoadXMLNode(Node2);
    Add(NewProject);
    Node2 := Node2.NextSibling;
  end;
end;

procedure TProjects.SaveXMLNode(Node: TDOMNode);
var
  I: Integer;
  NewNode: TDOMNode;
begin
  for I := 0 to Count - 1 do begin;
    NewNode := Node.OwnerDocument.CreateElement('Project');
    Node.AppendChild(NewNode);
    TProject(Items[I]).SaveXMLNode(NewNode);
  end;
end;


{ TProjectGroup }

constructor TProjectGroup.Create;
begin
  Projects := TProjects.Create;
end;

destructor TProjectGroup.Destroy;
begin
  Projects.Free;
  inherited Destroy;
end;

procedure TProjectGroup.LoadFromFile(FileName: string);
var
  Doc: TXMLDocument;
  RootNode: TDOMNode;
  Node: TDOMNode;
  Node2: TDOMNode;
begin
  Self.FileName := FileName;
  ReadXMLFile(Doc, UTF8Decode(FileName));
  with Doc do try
    if Doc.DocumentElement.NodeName <> 'ProjectGroup' then
      raise Exception.Create(SWrongFileFormat);
    RootNode := Doc.DocumentElement;
    with RootNode do begin
      Node := FindNode('Projects');
      if Assigned(Node) then Projects.LoadXMLNode(Node);
    end;
  finally
    Doc.Free;
  end;
end;

procedure TProjectGroup.SaveToFile(FileName: string);
var
  NewNode: TDOMNode;
  Doc: TXMLDocument;
  RootNode: TDOMNode;
begin
  if FileName = '' then Exit;
  Self.FileName := FileName;
  Doc := TXMLDocument.Create;
  with Doc do try
    RootNode := CreateElement('ProjectGroup');
    AppendChild(RootNode);
    with RootNode do begin
      NewNode := OwnerDocument.CreateElement('Projects');
      AppendChild(NewNode);
      Projects.SaveXMLNode(NewNode);
    end;
    ForceDirectoriesUTF8(ExtractFileDir(FileName));
    WriteXMLFile(Doc, UTF8Decode(FileName));
  finally
    Doc.Free;
  end;
end;

{ TProject }

procedure TProject.SetBackend(AValue: TBackend);
begin
  if FBackend = AValue then Exit;
  FBackend := AValue;
  FreeAndNil(WorkingCopy);
  WorkingCopy := AValue.WorkingCopyClass.Create;
  FreeAndNil(Repository);
  Repository := AValue.RepositoryClass.Create;
end;

function TProject.GetDirectory: string;
begin
  Result := WorkingCopy.Path;
end;

function TProject.GetRepositoryURL: string;
begin
  Result := WorkingCopy.RepositoryURL;
end;

procedure TProject.SetDirectory(AValue: string);
begin
  WorkingCopy.Path := AValue;
end;

procedure TProject.SetRepositoryURL(AValue: string);
begin
  WorkingCopy.RepositoryURL := AValue;
  Repository.Path := AValue;
end;

procedure TProject.Open(Directory: string);
begin
  WorkingCopy.Path := Directory;
end;

constructor TProject.Create;
begin
  WorkingCopy := TWorkingCopy.Create;
  Repository := TRepository.Create;
end;

destructor TProject.Destroy;
begin
  WorkingCopy.Free;
  Repository.Free;
  inherited Destroy;
end;

procedure TProject.LoadXMLNOde(Node: TDOMNode);
begin
  RepositoryURL := ReadString(Node, 'RepositoryURL', '');
  Directory := ReadString(Node, 'Directory', '');
end;

procedure TProject.SaveXMLNOde(Node: TDOMNode);
begin
  WriteString(Node, 'RepositoryURL', RepositoryURL);
  WriteString(Node, 'Directory', Directory);
end;

end.