source: trunk/Forms/UFormTest.pas

unit UFormTest;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  StdCtrls, LazFileUtils;

type
  { TFormTest }

  TFormTest = class(TForm)
    ButtonStart: TButton;
    ComboBox1: TComboBox;
    Label1: TLabel;
    ListView1: TListView;
    procedure ButtonStartClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    OperationItem: TListItem;
    OperationTimeStart: TDateTime;
    procedure OperationStart(Name: string);
    procedure OperationStop;
  public
    { public declarations }
  end;

var
  FormTest: TFormTest;

implementation

{$R *.lfm}

uses
  UCore, UBackend, UProject, UVCS;

{ TFormTest }

procedure TFormTest.FormShow(Sender: TObject);
var
  I: Integer;
begin
  ComboBox1.Clear;
  for I := 0 to Core.Backends.Count - 1 do
    ComboBox1.AddItem(TBackend(Core.Backends[I]).Name, Core.Backends[I]);
  if ComboBox1.Items.Count > 0 then
    ComboBox1.ItemIndex := 0;

end;

procedure TFormTest.OperationStart(Name: string);
begin
  OperationItem := ListView1.Items.Add;
  OperationItem.Caption := Name;
  OperationTimeStart := Now;
end;

procedure TFormTest.OperationStop;
begin
  OperationItem.SubItems.Add(TimeToStr(Now - OperationTimeStart));
  OperationItem := nil;
end;

procedure TFormTest.ButtonStartClick(Sender: TObject);
var
  Project: TProject;
  TestDir: string;
  TestFile: string;
  NewFile: TFileStream;
  Comment: TStringList;
begin
  ListView1.Items.Clear;
  Project := TProject.Create;
  Project.Backend := TBackend(Core.Backends[ComboBox1.ItemIndex]);
  Project.WorkingCopy.UserName := Core.UserName;
  Project.WorkingCopy.Email := Core.Email;
  try
    //RemoveDir(TestDir);

    TestDir := TestDir + DirectorySeparator + Project.Backend.Name;
    ForceDirectoriesUTF8(TestDir);

    OperationStart('Create repository');
    Project.RepositoryURL := TestDir + DirectorySeparator + 'repo';
    Project.Repository.Init;
    OperationStop;

    OperationStart('Checkout working copy');
    Project.Directory := TestDir + DirectorySeparator + 'work';
    Project.RepositoryURL := URLFromDirectory(TestDir + DirectorySeparator + 'repo', True);
    Project.WorkingCopy.Checkout;
    OperationStop;

    OperationStart('Update working copy');
    Project.WorkingCopy.Update;
    OperationStop;

    OperationStart('Add file');
    ForceDirectoriesUTF8(TestDir + DirectorySeparator + 'work');
    TestFile := 'TestFile.bin';
    NewFile := TFileStream.Create(TestDir + DirectorySeparator + 'work' + DirectorySeparator + TestFile, fmCreate);
    NewFile.Size := 10000;
    NewFile.Free;
    Project.WorkingCopy.Add(TestFile);
    OperationStop;

    OperationStart('Commit working copy');
    Comment := TStringList.Create;
    Comment.Text := 'Test commit message';
    Project.WorkingCopy.Commit(Comment);
    Comment.Free;
    OperationStop;

    OperationStart('Remove file');
    Project.WorkingCopy.Remove(TestFile);
    OperationStop;

    OperationStart('Commit working copy');
    Comment := TStringList.Create;
    Comment.Text := 'Test commit message 2';
    Project.WorkingCopy.Commit(Comment);
    Comment.Free;
    OperationStop;
  finally
    Project.Free;
  end;
end;

end.