source: trunk/Forms/FormLog.pas

unit FormLog;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  StdCtrls, ExtCtrls, VCS;

type

  { TFormLog }

  TFormLog = class(TForm)
    Button1: TButton;
    ListViewItems: TListView;
    ListViewFiles: TListView;
    MemoMessages: TMemo;
    Splitter1: TSplitter;
    Splitter2: TSplitter;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewFilesData(Sender: TObject; Item: TListItem);
    procedure ListViewItemsData(Sender: TObject; Item: TListItem);
    procedure ListViewItemsSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  public
    FileName: string;
    LogList: TLogItems;
    procedure ReloadList;
    procedure UpdateInterface;
  end;


implementation

uses
  Core;

{$R *.lfm}

{ TFormLog }

procedure TFormLog.FormCreate(Sender: TObject);
begin
  LogList := TLogItems.Create;
end;

procedure TFormLog.FormDestroy(Sender: TObject);
begin
  FreeAndNil(LogList);
end;

procedure TFormLog.FormShow(Sender: TObject);
begin
  Core.Core.Project.WorkingCopy.GetLog(FileName, LogList);
  ReloadList;
end;

procedure TFormLog.ListViewFilesData(Sender: TObject; Item: TListItem);
begin
  if Assigned(ListViewItems.Selected) and (Item.Index >= 0) and (Item.Index < TLogItem(ListViewItems.Selected.Data).ChangedFiles.Count) then
  with TLogItem(ListViewItems.Selected.Data) do begin
    Item.Caption := ChangedFiles[Item.Index];
  end;
end;

procedure TFormLog.ListViewItemsData(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < LogList.Count) then
  with TLogItem(LogList[Item.Index]) do begin
    Item.Caption := Revision;
    Item.SubItems.Add(Actions);
    Item.SubItems.Add(Author);
    Item.SubItems.Add(DateTimeToStr(Time));
    Item.SubItems.Add(StringReplace(Messages.Text, LineEnding, ' ', [rfReplaceAll]));
    Item.Data := LogList[Item.Index];
  end;
end;

procedure TFormLog.ListViewItemsSelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  ReloadList;
end;

procedure TFormLog.ReloadList;
begin
  ListViewItems.Items.Count := LogList.Count;
  ListViewItems.Refresh;
  if Assigned(ListViewItems.Selected) then
  with TLogItem(ListViewItems.Selected.Data) do begin
    ListViewFiles.Items.Count := ChangedFiles.Count;
    ListViewFiles.Refresh;
    MemoMessages.Lines.Assign(Messages);
  end else begin
    ListViewFiles.Items.Count := 0;
    ListViewFiles.Refresh;
    MemoMessages.Lines.Clear;
  end;
  UpdateInterface;
end;

procedure TFormLog.UpdateInterface;
begin
  MemoMessages.Enabled := Assigned(ListViewItems.Selected);
  ListViewFiles.Enabled := Assigned(ListViewItems.Selected)
end;

end.