source: trunk/Backends/Subversion/USubversion.pas

unit USubversion;

{$mode delphi}

interface

uses
  Classes, SysUtils, UVCS, UBackend, XMLRead, DOM, UXMLUtils;

type

  { TBackendSubversion }

  TBackendSubversion = class(TBackend)
    constructor Create;
    function IsWorkingCopy(Directory: string): Boolean; override;
  end;


  { TSubversion }

  TSubversion = class(TWorkingCopy)
  protected
    procedure Execute(Parameters: array of string);
  public
    procedure Checkout; override;
    procedure Update; override;
    procedure CleanUp; override;
    procedure Commit(Message: TStrings); override;
    procedure Move(Source, Dest: string); override;
    procedure Merge; override;
    procedure Add(FileName: string); override;
    procedure Remove(FileName: string); override;
    procedure GetLog(FileName: string; Log: TLogList); override;
    procedure GetStatus(FileName: string; Status: TFileStatusList); override;
  end;

  { TRepositorySubversion }

  TRepositorySubversion = class(TRepository)
  protected
    procedure Execute(Parameters: array of string);
  public
    procedure Init; override;
  end;

implementation

{ TRepositorySubversion }

procedure TRepositorySubversion.Execute(Parameters: array of string);
var
  ToolPath: string;
begin
  {$IFDEF Linux}
  ToolPath := '/usr/bin/svnadmin';
  {$ENDIF}
  {$IFDEF Windows}
  ToolPath := 'c:\Program Files\Subversion\bin\svnadmin.exe';
  if not FileExists(ToolPath) then
    ToolPath := 'C:\Program Files\TortoiseSVN\bin\svnadmin.exe';
  {$ENDIF}
  ExecuteProcess(ToolPath, Parameters);
end;

procedure TRepositorySubversion.Init;
begin
  Execute(['create', Path]);
end;

{ TBackendSubversion }

constructor TBackendSubversion.Create;
begin
  Name := 'Subversion';
  HomePage := 'https://subversion.apache.org/';
  WorkingCopyClass := TSubversion;
  RepositoryClass := TRepositorySubversion;
end;

function TBackendSubversion.IsWorkingCopy(Directory: string): Boolean;
begin
  Result := DirectoryExists(Directory + DirectorySeparator + '.svn') and
    FileExists(Directory + DirectorySeparator + '.svn' + DirectorySeparator + 'wc.db');
end;

{ TSubversion }

procedure TSubversion.Execute(Parameters: array of string);
var
  ToolPath: string;
begin
  {$IFDEF Linux}
  ToolPath := '/usr/bin/svn';
  {$ENDIF}
  {$IFDEF Windows}
  ToolPath := 'c:\Program Files\Subversion\bin\svn.exe';
  if not FileExists(ToolPath) then
    ToolPath := 'C:\Program Files\TortoiseSVN\bin\svn.exe';
  {$ENDIF}
  ExecuteProcess(ToolPath, Parameters);
end;

procedure TSubversion.Checkout;
begin
  Execute(['checkout', RepositoryURL, Path]);
end;

procedure TSubversion.Update;
begin
  Execute(['update']);
end;

procedure TSubversion.CleanUp;
begin
  Execute(['cleanup']);
end;

procedure TSubversion.Commit(Message: TStrings);
begin
  Execute(['commit', '-m "' + Message.Text + '"']);
end;

procedure TSubversion.Move(Source, Dest: string);
begin
  Execute(['move', Source, Dest]);
end;

procedure TSubversion.Merge;
begin
  Execute(['merge']);
end;

procedure TSubversion.Add(FileName: string);
begin
  Execute(['add', FileName]);
end;

procedure TSubversion.Remove(FileName: string);
begin
  Execute(['remove', FileName]);
end;

procedure TSubversion.GetLog(FileName: string; Log: TLogList);
var
  NewItem: TLogItem;
  I: Integer;
  Line: string;
  ChangedFiles: Boolean;
  Action: string;
begin
  NewItem := nil;
  Log.Clear;
  SilentExecution := True;
  Execute(['log', FileName, '-v']);
  SilentExecution := False;
  for I := 0 to ExecutionOutput.Count - 1 do begin
    Line := Trim(ExecutionOutput[I]);
    if Line = '------------------------------------------------------------------------' then begin
      if Assigned(NewItem) then Log.Add(NewItem);
      NewItem := TLogItem.Create;
    end else
    if Pos('|', Line) > 0 then begin
      NewItem.Revision := Trim(GetNext(Line, '|'));
      NewItem.Author := Trim(GetNext(Line, '|'));
      GetNext(Line, '|');
      //NewItem.Time := StrToDateTime(Trim(GetNext(Line, '|')));
    end else
    if Line = 'Changed paths:' then begin
      ChangedFiles := True;
    end else
    if ChangedFiles then begin
      if (Line <> '') and (Copy(ExecutionOutput[I], 1, 3) = '   ') then begin
        Action := GetNext(Line, ' ');
        NewItem.Actions := NewItem.Actions + Action;
        NewItem.ChangedFiles.Add(Line);
      end else
      if Line = '' then begin
        ChangedFiles := False;
      end;
    end else
      NewItem.Messages.Add(Line);
  end;
  if Assigned(NewItem) then Log.Add(NewItem);
end;

procedure TSubversion.GetStatus(FileName: string; Status: TFileStatusList);
var
  Doc: TXMLDocument;
  S: TStringStream;
  Node: TDOMNode;
  Node2: TDOMNode;
  RootNode: TDOMNode;
  TargetNode: TDOMNode;
  StatusNode: TDOMNode;
  StatusItem: TFileStatus;
  CommitNode: TDOMNode;
  ItemState: string;
begin
  Status.Clear;
  SilentExecution := True;
  Execute(['status', '--xml', '-v']);
  SilentExecution := False;
  S := TStringStream.Create(ExecutionOutput.Text);
  try
    // Read complete XML document
    ReadXMLFile(Doc, S);
    RootNode := Doc.DocumentElement;
    if RootNode.NodeName = 'status' then begin
      TargetNode := RootNode.FindNode('target');
      if Assigned(TargetNode) then begin
        Node := TargetNode.FirstChild;
        while Assigned(Node) do begin
          if Node.NodeName = 'entry' then begin
            StatusItem := TFileStatus.Create;
            StatusItem.FileName := TDOMElement(Node).GetAttribute('path');
            StatusNode := Node.FindNode('wc-status');
            if Assigned(StatusNode) then begin
              ItemState := TDOMElement(StatusNode).GetAttribute('item');
              if ItemState = 'normal' then StatusItem.State := fssNotModified;
              if ItemState = 'modified' then StatusItem.State := fssModified;
              if ItemState = 'deleted' then StatusItem.State := fssRemoved;
              if ItemState = 'added' then StatusItem.State := fssAdded;

              CommitNode := StatusNode.FindNode('commit');
              if Assigned(CommitNode) then begin
                 StatusItem.Version := TDOMElement(CommitNode).GetAttribute('revision');
                 StatusItem.Author := ReadString(CommitNode, 'author', '');
                 StatusItem.Time := ReadDateTime(CommitNode, 'date', 0);
              end;
            end;
            Status.Add(StatusItem);
          end;
          Node := Node.NextSibling;
        end;
      end;
    end;
  finally
    Doc.Free;
    S.Free;
  end;
end;

end.