source: trunk/IDE/Forms/FormTargetProject.pas

unit FormTargetProject;

interface

uses
  Classes, SysUtils, LazFileUtils, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Project;

type
  TShowTargetCodeEvent = procedure(ProjectFile: TProjectFile) of object;

  { TFormTargetProject }

  TFormTargetProject = class(TForm)
    TreeViewProject: TTreeView;
    procedure TreeViewProjectChange(Sender: TObject; Node: TTreeNode);
  private
    FOnShowTargetCode: TShowTargetCodeEvent;
    procedure UpdateProjectFiles(Node: TTreeNode; Files: TProjectFiles);
    procedure UpdateProjectTree;
  public
    procedure UpdateInterface;
    property OnShowTargetCode: TShowTargetCodeEvent read FOnShowTargetCode
      write FOnShowTargetCode;
  end;


implementation

{$R *.lfm}

uses
  Core, FormMain, FormTargetCode;

procedure TFormTargetProject.UpdateProjectTree;
var
  NewNode: TTreeNode;
begin
  with Core.Core, FormMain.FormMain, TreeViewProject, Items do begin
    BeginUpdate;
    Clear;
    if Assigned(Project) then begin
      NewNode := AddChild(nil, ExtractFileNameWithoutExt(TargetProject.FileName));
      UpdateProjectFiles(NewNode, TargetProject.Files);
      NewNode.Expand(True);
    end;
    EndUpdate;
    if Assigned(TreeViewProject.TopItem) and
      (TreeViewProject.TopItem.Count > 0) then
      TreeViewProject.TopItem.Items[0].Selected := True
      else begin
        if Assigned(FOnShowTargetCode) then
          FOnShowTargetCode(nil);
      end;
  end;
end;

procedure TFormTargetProject.UpdateInterface;
begin
  UpdateProjectTree;
end;

procedure TFormTargetProject.TreeViewProjectChange(Sender: TObject;
  Node: TTreeNode);
begin
  with FormMain.FormMain do
  if Assigned(Node) then begin
    if TProjectFile(Node.Data) is TProjectFile then begin
      if Assigned(FOnShowTargetCode) then
        FOnShowTargetCode(TProjectFile(Node.Data))
    end;
  end;
end;

procedure TFormTargetProject.UpdateProjectFiles(Node: TTreeNode; Files: TProjectFiles);
var
  I: Integer;
  NewNode: TTreeNode;
  FileName: string;
  NamePart: string;
  SelNode: TTreeNode;
  SubNode: TTreeNode;
begin
  for I := 0 to Files.Count - 1 do begin
    FileName := TProjectFile(Files[I]).FileName;
    SelNode := Node;
    while Pos(DirectorySeparator, FileName) > 0 do begin
      NamePart := Copy(FileName, 1, Pos(DirectorySeparator, FileName) - 1);
      Delete(FileName, 1, Length(NamePart) + 1);
      SubNode := SelNode.FindNode(NamePart);
      if Assigned(SubNode) then SelNode := SubNode
      else begin
        SelNode := TreeViewProject.Items.AddChild(SelNode, NamePart);
      end;
    end;
    NewNode := TreeViewProject.Items.AddChild(SelNode, FileName);
    NewNode.Data := Pointer(Files[I]);
  end;
end;


end.