source: trunk/Forms/UFormRecords.pas

unit UFormRecords;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  ActnList, Menus, UDatabase;

type

  { TFormRecords }

  TFormRecords = class(TForm)
    AAdd: TAction;
    ActionList1: TActionList;
    AModify: TAction;
    ARemove: TAction;
    ListViewRecords: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    PopupMenu1: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewRecordsData(Sender: TObject; Item: TListItem);
    procedure ListViewRecordsSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  public
    Table: TTable;
    procedure UpdateInterface;
    procedure ReloadList;
  end;


implementation

uses
  UFormRecord;

{$R *.lfm}

resourcestring
  STable = 'Table';
  SRemoveRecord = 'Remove record';
  SRemoveRecordConfirm = 'Do you want to remove record?';

{ TFormRecords }

procedure TFormRecords.FormShow(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
  Caption := STable + ' - ' + Table.Caption;
  Table.Fields.Load;
  ReloadList;
end;

procedure TFormRecords.ListViewRecordsData(Sender: TObject; Item: TListItem);
var
  I: Integer;
begin
  if (Item.Index >= 0) and (Item.Index < Table.Records.Count) then
  with Table.Records[Item.Index] do begin
    for I := 0 to Table.Fields.Count - 1 do begin
      if I = 0 then Item.Caption := Values[0].GetString
        else Item.SubItems.Add(Values[I].GetString);
    end;
    Item.Data := Table.Records[Item.Index];
  end
end;

procedure TFormRecords.ListViewRecordsSelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormRecords.AModifyExecute(Sender: TObject);
begin
  if Assigned(ListViewRecords.Selected) then begin
    with TFormRecord.Create(nil) do
    try
      Table := Self.Table;
      Load(TRecord(ListViewRecords.Selected.Data));
      if ShowModal = mrOk then begin
        Save(TRecord(ListViewRecords.Selected.Data));
        ReloadList;
      end;
    finally
      Free;
    end;
  end;
end;

procedure TFormRecords.ARemoveExecute(Sender: TObject);
begin
  if Assigned(ListViewRecords.Selected) then
  if MessageDlg(SRemoveRecord, SRemoveRecordConfirm,
  mtConfirmation, [mbYes, mbNo], 0) = mrYes then begin
    Table.Records.Remove(ListViewRecords.Selected.Data);
    ReloadList;
  end;
end;

procedure TFormRecords.AAddExecute(Sender: TObject);
var
  NewRecord: TRecord;
  ValueClass: TValueClass;
  I: Integer;
  NewValue: TValue;
  Columns: string;
  Values: string;
begin
  NewRecord := TRecord.Create;
  NewRecord.Table := Table;
  NewRecord.Values.Count := Table.Fields.Count;
  for I := 0 to Table.Fields.Count - 1 do begin
    ValueClass := Table.Fields[I].GetValueClass;
    NewValue := ValueClass.Create;
    NewRecord.Values[I] := NewValue;
  end;

  with TFormRecord.Create(nil) do
  try
    Table := Self.Table;
    Load(NewRecord);
    if ShowModal = mrOk then begin
      Save(NewRecord);

      Values := '';
      Columns := '';
      for I := 0 to Table.Fields.Count - 1 do begin
        Columns := Columns + Table.Fields[I].Name;
        Values := Values + '"' + NewRecord.Values[I].GetString + '"';
        if I < Table.Fields.Count - 1 then begin
          Columns := Columns + ' , ';
          Values := Values + ' , ';
        end;
      end;
      Table.DbClient.Query('INSERT INTO ' + Table.Name + ' ( ' + Columns + ' )' +
        ' VALUES ( ' + Values + ' )');

      NewRecord.Free;
      ReloadList;
    end else NewRecord.Free;
  finally
    Free;
  end;
end;

procedure TFormRecords.UpdateInterface;
begin
  AModify.Enabled := Assigned(ListViewRecords.Selected);
  ARemove.Enabled := Assigned(ListViewRecords.Selected);
end;

procedure TFormRecords.ReloadList;
var
  I: Integer;
begin
  Table.Records.Load;

  ListViewRecords.Columns.BeginUpdate;
  try
    while ListViewRecords.Columns.Count > Table.Fields.Count do
      ListViewRecords.Columns[ListViewRecords.ColumnCount - 1].Free;
    while ListViewRecords.Columns.Count < Table.Fields.Count do
      ListViewRecords.Columns.Add;
    for I := 0 to Table.Fields.Count - 1 do begin
      ListViewRecords.Columns[I].Caption := Table.Fields[I].TextBefore;
      ListViewRecords.Columns[I].Width := 200;
    end;
  finally
    ListViewRecords.Columns.EndUpdate;
  end;

  ListViewRecords.Items.Count := Table.Records.Count;
  ListViewRecords.Repaint;
end;

end.