source: trunk/Forms/UFormConnect.pas

unit UFormConnect;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, Spin, UDatabase;

type

  { TFormConnect }

  TFormConnect = class(TForm)
    ButtonXmlBrowse: TButton;
    ButtonOk: TButton;
    ButtonCancel: TButton;
    ComboBoxDbEngines: TComboBox;
    EditHost: TEdit;
    EditXml: TEdit;
    EditName: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    OpenDialog1: TOpenDialog;
    PageControl1: TPageControl;
    SpinEditPort: TSpinEdit;
    TabSheetSqlite: TTabSheet;
    TabSheetRegistry: TTabSheet;
    TabSheetXml: TTabSheet;
    TabSheetSql: TTabSheet;
    procedure ButtonXmlBrowseClick(Sender: TObject);
    procedure ComboBoxDbEnginesChange(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  public
    procedure Load(ConnectProfile: TDbConnectProfile);
    procedure Save(ConnectProfile: TDbConnectProfile);
    procedure ReloadDbEngines;
    procedure UpdateInterface;
  end;


implementation

{$R *.lfm}

uses
  UCore, UEngineXML, UEngineMySQL;

resourcestring
  SAnyFile = 'Any file';
  SXmlFiles = 'XML files';

{ TFormConnect }

procedure TFormConnect.ButtonXmlBrowseClick(Sender: TObject);
begin
  OpenDialog1.Filter := SXmlFiles + ' (.xml)|*.xml|' + SAnyFile + '|*.*';
  OpenDialog1.InitialDir := ExtractFileDir(EditXml.Text);
  OpenDialog1.FileName := ExtractFileName(EditXml.Text);
  if OpenDialog1.Execute then
    EditXml.Text := OpenDialog1.FileName;
end;

procedure TFormConnect.ComboBoxDbEnginesChange(Sender: TObject);
begin
  UpdateInterface;
end;

procedure TFormConnect.FormCreate(Sender: TObject);
begin
  ReloadDbEngines;
end;

procedure TFormConnect.Load(ConnectProfile: TDbConnectProfile);
begin
  EditName.Text := ConnectProfile.Name;
  //EditConnectionString.Text := Database.ConnectionString;
  ComboBoxDbEngines.ItemIndex := ComboBoxDbEngines.Items.IndexOfObject(ConnectProfile.ClientType);
  if (ComboBoxDbEngines.ItemIndex = -1) and (ComboBoxDbEngines.Items.Count > 0) then
    ComboBoxDbEngines.ItemIndex := 0;
  if ConnectProfile.Params is TDbConnectParamsXml then
    EditXml.Text := TDbConnectParamsXml(ConnectProfile.Params).FileName;
  if ConnectProfile.Params is TDbConnectParamsMysql then begin
    EditHost.Text := TDbConnectParamsMysql(ConnectProfile.Params).Host;
    SpinEditPort.Value := TDbConnectParamsMysql(ConnectProfile.Params).Port;
  end;
  UpdateInterface;
end;

procedure TFormConnect.Save(ConnectProfile: TDbConnectProfile);
begin
  ConnectProfile.Name := EditName.Text;
  //DatabaseClient.ConnectionString := EditConnectionString.Text;
  ConnectProfile.ClientType := TDbClientType(ComboBoxDbEngines.Items.Objects[ComboBoxDbEngines.ItemIndex]);
  if ConnectProfile.Params is TDbConnectParamsXml then
    TDbConnectParamsXml(ConnectProfile.Params).FileName := EditXml.Text;
  if ConnectProfile.Params is TDbConnectParamsMysql then begin
    TDbConnectParamsMysql(ConnectProfile.Params).Host := EditHost.Text;
    TDbConnectParamsMysql(ConnectProfile.Params).Port := SpinEditPort.Value;
  end;
end;

procedure TFormConnect.ReloadDbEngines;
var
  I: Integer;
begin
  ComboBoxDbEngines.Items.BeginUpdate;
  try
    ComboBoxDbEngines.Items.Clear;
    for I := 0 to Core.DbManager.ClientTypes.Count - 1 do
      ComboBoxDbEngines.Items.AddObject(Core.DbManager.ClientTypes[I].Name,
        Core.DbManager.ClientTypes[I]);
  finally
    ComboBoxDbEngines.Items.Endupdate;
  end;
end;

procedure TFormConnect.UpdateInterface;
begin
  PageControl1.TabIndex := ComboBoxDbEngines.ItemIndex;
end;

end.