source: trunk/Forms/FormDatabases.pas

unit FormDatabases;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Menus, ActnList, DbEngine, FormEx;

type

  { TFormDatabases }

  TFormDatabases = class(TFormEx)
    AAdd: TAction;
    AOpen: TAction;
    AModify: TAction;
    ARemove: TAction;
    ActionList1: TActionList;
    ListView1: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    PopupMenu1: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    ToolButton4: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure AOpenExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1DblClick(Sender: TObject);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  public
    SelectedProfile: TDbConnectProfile;
    DbManager: TDbManager;
    procedure ReloadList;
    procedure UpdateInterface;
  end;


implementation

{$R *.lfm}

uses
  FormConnect;

resourcestring
  SRemoveDatabaseConnection = 'Remove database connection';
  SRemoveDatabaseConnectionQuery = 'Do you want to really remove database connection %s?';
  SNewDatabase = 'New database';

{ TFormDatabases }

procedure TFormDatabases.ListView1DblClick(Sender: TObject);
begin
  AOpen.Execute;
end;

procedure TFormDatabases.AOpenExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    SelectedProfile := TDbConnectProfile(ListView1.Selected.Data);
    ModalResult := mrOk;
  end;
end;

procedure TFormDatabases.ARemoveExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    if MessageDlg(SRemoveDatabaseConnection, Format(SRemoveDatabaseConnectionQuery, [
    TDbConnectProfile(ListView1.Selected.Data).Name]), mtConfirmation, [mbYes, mbNo], 0) = mrYes then begin
      DbManager.ConnectProfiles.Remove(ListView1.Selected.Data);
      ReloadList;
    end;
  end;
end;

procedure TFormDatabases.AAddExecute(Sender: TObject);
var
  NewConnectProfile: TDbConnectProfile;
begin
  NewConnectProfile := TDbConnectProfile.Create;
  NewConnectProfile.Name := SNewDatabase;
  with TFormConnect.Create(nil) do
  try
    DbManager := Self.DbManager;
    Load(NewConnectProfile);
    if ShowModal = mrOk then begin
      Save(NewConnectProfile);
      DbManager.ConnectProfiles.Add(NewConnectProfile);
      ReloadList;
    end else NewConnectProfile.Free;
  finally
    Free;
  end;
end;

procedure TFormDatabases.AModifyExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    DbManager := Self.DbManager;
    with TFormConnect.Create(nil) do
    try
      DbManager := Self.DbManager;
      Load(TDbConnectProfile(ListView1.Selected.Data));
      if ShowModal = mrOk then begin
        Save(TDbConnectProfile(ListView1.Selected.Data));
        ReloadList;
      end;
    finally
      Free;
    end;
  end;
end;

procedure TFormDatabases.FormShow(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
  ReloadList;
end;

procedure TFormDatabases.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < DbManager.ConnectProfiles.Count) then
  with TDbConnectProfile(DbManager.ConnectProfiles[Item.Index]) do begin
    Item.Caption := Name;
    Item.SubItems.Add(ClientType.Name);
    Item.SubItems.Add(Params.ConnectionString);
    Item.Data := DbManager.ConnectProfiles[Item.Index];
  end
end;

procedure TFormDatabases.ListView1SelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormDatabases.ReloadList;
begin
  ListView1.Items.Count := DbManager.ConnectProfiles.Count;
  ListView1.Repaint;
  UpdateInterface;
end;

procedure TFormDatabases.UpdateInterface;
begin
  AModify.Enabled := Assigned(ListView1.Selected);
  ARemove.Enabled := Assigned(ListView1.Selected);
  AOpen.Enabled := Assigned(ListView1.Selected);
end;

end.