source: trunk/DbEngines/EngineMySQL.pas

unit EngineMySQL;

interface

uses
  Classes, Dialogs, SysUtils, DbEngine, USqlDatabase, HtmlClasses,
  Generics;

type

  { TDatabaseMySQL }

  TDatabaseMySQL = class(TDbClient)
  private
    procedure LoadFields(Table: TTable);
  protected
  public
    SqlDatabase: TSqlDatabase;
    procedure Query(Text: string; DbRows: TDbRows = nil); override;
    constructor Create; override;
    destructor Destroy; override;
    procedure Load; override;
    procedure Save; override;
  end;

  { TDbConnectParamsMySQL }

  TDbConnectParamsMySQL = class(TDbConnectParams)
  protected
    function GetConnectionString: string; override;
    procedure SetConnectionString(AValue: string); override;
  public
    Host: string;
    Port: Word;
  end;


implementation

{ TDbConnectParamsMySQL }

function TDbConnectParamsMySQL.GetConnectionString: string;
begin
  Result := 'mysql://' + Host + ':' + IntToStr(Port);
end;

procedure TDbConnectParamsMySQL.SetConnectionString(AValue: string);
var
  URL: TURL;
begin
  URL := TURL.Create;
  try
    URL.AsString := AValue;
    if (URL.Scheme <> 'mysql') and (AValue <> '') then
      raise Exception.Create('Wrong connection string. Required mysql scheme.');
    Host := URL.Host.AsString;
    Port := URL.Port;
  finally
    URL.Free;
  end;
end;

{ TDatabaseMySQL }

procedure TDatabaseMySQL.LoadFields(Table: TTable);
var
  DbRows: TDbRows;
  DbRows2: TDbRows;
  NewField: TField;
  I: Integer;
  DataType: Integer;
  TypeName: string;
begin
  DbRows := TDbRows.Create;
  DbRows2 := TDbRows.Create;
  try
    SqlDatabase.Query(DbRows, 'SELECT * FROM `ModelField` WHERE `Model` = ' + IntToStr(Table.Id) + '');
    for I := 0 to DbRows.Count - 1 do begin
      NewField := TField.Create;
      NewField.Table := Table;
      NewField.Name := TDictionaryStringString(DbRows[I]).Items['Name'];
      NewField.TextBefore := TDictionaryStringString(DbRows[I]).Items['Title'];
      DataType := StrToInt(TDictionaryStringString(DbRows[I]).Items['Type']);
      SqlDatabase.Query(DbRows2, 'SELECT * FROM `DataType` WHERE `Id` = ' + IntToStr(DataType) + '');
      if DbRows2.Count > 0 then begin
        TypeName := TDictionaryStringString(DbRows2[0]).Items['Name'];
        NewField.DataType := Table.DbClient.ClientType.DataTypes.SearchByName(TypeName);
        if not Assigned(NewField.DataType) then
          NewField.DataType := Table.DbClient.ClientType.DataTypes.SearchByType(ftString);
      end else begin
        // Use string as default
        NewField.DataType := Table.DbClient.ClientType.DataTypes.SearchByType(ftString);
      end;
      Table.Fields.Add(NewField);
    end;
  finally
    DbRows.Free;
    DbRows2.Free;
  end;
end;

procedure TDatabaseMySQL.Query(Text: string; DbRows: TDbRows = nil);
begin
  SqlDatabase.Query(DbRows, Text);
end;

constructor TDatabaseMySQL.Create;
begin
  inherited Create;
  SqlDatabase := TSqlDatabase.Create(nil);
end;

destructor TDatabaseMySQL.Destroy;
begin
  SqlDatabase.Free;
  inherited Destroy;
end;

procedure TDatabaseMySQL.Load;
var
  URL: TURL;
begin
  URL := TURL.Create;
  try
    URL.AsString := ConnectProfile.Params.ConnectionString;
    if URL.Scheme <> 'mysql' then
      raise Exception.Create('Wrong connection string. Required mysql protocol.');

    SqlDatabase.HostName := URL.Host.AsString;
    if URL.Port <> 0 then
      SqlDatabase.Port := URL.Port;
    SqlDatabase.UserName := URL.UserName;
    SqlDatabase.Password := URL.Password;
    if Copy(URL.Path, 1, 1) = '/' then
      SqlDatabase.Database := Copy(URL.Path, 2, High(Integer));
    SqlDatabase.Connect;
  finally
    URL.Free;
  end;
  inherited Load;
end;

procedure TDatabaseMySQL.Save;
begin
  SqlDatabase.Disconnect;
  inherited Save;
end;

end.