source: trunk/Core.pas

unit Core;

interface

uses
  Classes, SysUtils, FileUtil, Controls, ActnList, DbEngine, Translator,
  ApplicationInfo, PersistentForm, Forms, RegistryEx, ScaleDPI, Theme, FormMain;

type
  { TCore }

  TCore = class(TDataModule)
    AAbout: TAction;
    ADatabaseConnect: TAction;
    ADatabaseDisconnect: TAction;
    ApplicationInfo1: TApplicationInfo;
    APreferences: TAction;
    AExit: TAction;
    ActionList1: TActionList;
    ThemeManager1: TThemeManager;
    Translator1: TTranslator;
    ImageList1: TImageList;
    PersistentForm1: TPersistentForm;
    ScaleDPI1: TScaleDPI;
    procedure AAboutExecute(Sender: TObject);
    procedure ADatabaseConnectExecute(Sender: TObject);
    procedure ADatabaseDisconnectExecute(Sender: TObject);
    procedure AExitExecute(Sender: TObject);
    procedure APreferencesExecute(Sender: TObject);
    procedure Translator1Translate(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    FDbClient: TDbClient;
    Initialized: Boolean;
    procedure SetDbClient(AValue: TDbClient);
  public
    Preferences: TPreferences;
    DbManager: TDbManager;
    FormMain: TFormMain;
    procedure LoadConfig;
    procedure SaveConfig;
    procedure Init;
    procedure Done;
    procedure UpdateInterface;
    property DbClient: TDbClient read FDbClient write SetDbClient;
  end;

var
  Core: TCore;

const
  DefaultRegKey = '\Software\Chronosoft\MyData';


implementation

uses
  FormTables, FormAbout, FormDatabases, FormPreferences, FormEx;

{$R *.lfm}

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  DbManager := TDbManager.Create;
  Preferences := TPreferences.Create;

  LoadConfig;

  TFormEx.ScaleDPI := ScaleDPI1;
  TFormEx.Translator := Translator1;
  TFormEx.ThemeManager := ThemeManager1;
  TFormEx.PersistentForm := PersistentForm1;

  FormMain := TFormMain.Create(nil);
  FormMain.Show;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  FreeAndNil(FormMain);
  DbClient := nil;
  FreeAndNil(Preferences);
  FreeAndNil(DbManager);
end;

procedure TCore.AExitExecute(Sender: TObject);
begin
  FormMain.Close;
end;

procedure TCore.ADatabaseDisconnectExecute(Sender: TObject);
begin
  DbClient := nil;
end;

procedure TCore.ADatabaseConnectExecute(Sender: TObject);
begin
  with TFormDatabases.Create(nil) do
  try
    DbManager := Self.DbManager;
    if ShowModal = mrOk then begin
      DbClient := nil;
      DbClient := SelectedProfile.GetClient;
    end;
  finally
    Free;
  end;
end;

procedure TCore.AAboutExecute(Sender: TObject);
begin
  with TFormAbout.Create(nil) do
  try
    ApplicationInfo := ApplicationInfo1;
    ShowModal;
  finally
    Free;
  end;
end;

procedure TCore.APreferencesExecute(Sender: TObject);
begin
  with TFormPreferences.Create(nil) do
  try
    Load(Preferences);
    if ShowModal = mrOk then Save(Preferences);
  finally
    Free;
  end;
end;

procedure TCore.Translator1Translate(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to DbManager.DataTypes.Count - 1 do begin
    DbManager.DataTypes[I].Title := Translator1.TranslateText(DbManager.DataTypes[I].Title, DbManager.DataTypes[I].Title);
  end;
end;

procedure TCore.SetDbClient(AValue: TDbClient);
begin
  if FDbClient = AValue then Exit;
  if Assigned(FDbClient) then begin
    FormMain.FormTables.DbClient := nil;
    DbClient.Save;
    FreeAndNil(FDbClient);
  end;
  FDbClient := AValue;
  if Assigned(FDbClient) then begin
    DbClient.Load;
    Preferences.LastDatabaseName := FDbClient.ConnectProfile.Name;
    FormMain.FormTables.DbClient := DbClient;
  end;
  UpdateInterface;
end;

procedure TCore.LoadConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey);
    Preferences.RememberDatabase := ReadBoolWithDefault('RememberDatabase', True);
    Preferences.LastDatabaseName := ReadStringWithDefault('LastDatabaseName', '');
    Translator1.Language := Translator1.Languages.SearchByCode(
      ReadStringWithDefault('Language', ''));
  finally
    Free;
  end;
  DbManager.ConnectProfiles.LoadFromRegistry(TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey + '\Database'));
end;

procedure TCore.SaveConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey);
    WriteBool('RememberDatabase', Preferences.RememberDatabase);
    WriteString('LastDatabaseName', Preferences.LastDatabaseName);
    WriteString('Language', Translator1.Language.Code);
  finally
    Free;
  end;
  DbManager.ConnectProfiles.SaveToRegistry(TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey + '\Database'));
end;

procedure TCore.Init;
var
  ConnectProfile: TDbConnectProfile;
begin
  if not Initialized then begin
    {$IFDEF UNIX}
    // If installed in Linux system then use installation directory for po files
    if Application.ExeName = '/usr/bin/MyData' then
      Translator1.POFilesFolder := '/usr/share/MyData/languages';
    {$ENDIF}
    Initialized := True;
    UpdateInterface;
    if Preferences.RememberDatabase then begin
      ConnectProfile := DbManager.ConnectProfiles.SearchByName(Preferences.LastDatabaseName);
      if Assigned(ConnectProfile) then begin
        DbClient := ConnectProfile.GetClient;
      end;
    end else ADatabaseConnect.Execute;
  end;
end;

procedure TCore.Done;
begin
  SaveConfig;
  DbClient := nil;
  Application.Terminate;
end;

procedure TCore.UpdateInterface;
begin
  ADatabaseDisconnect.Enabled := Assigned(DbClient);
  FormMain.UpdateInterface;
end;

end.