source: trunk/UProject.pas

unit UProject;

{$mode Delphi}{$H+}

interface

uses
  Classes, SysUtils, UFGraphics;

type

  { TFloatPoint }

  TFloatPoint = record
    X, Y: Double;
    function Create(AX, AY: Double): TFloatPoint;
  end;

  { TView }

  TView = class
  private
    FSrcRect: TRect;
    FDestRect: TRect;
    FZoom: Double;
    procedure SetDestRect(AValue: TRect);
    procedure SetSrcRect(AValue: TRect);
    procedure SetZoom(AValue: Double);
  public
    procedure Center(Rect: TRect);
    constructor Create;
    procedure ZoomAll(BitmapSize: TPoint);
    function DestToSrcPos(Pos: TPoint): TPoint;
    function SrcToDestPos(Pos: TPoint): TPoint;
    property DestRect: TRect read FDestRect write SetDestRect;
    property Zoom: Double read FZoom write SetZoom;
    property SrcRect: TRect read FSrcRect write SetSrcRect;
  end;

  { TProject }

  TProject = class
    FileName: string;
    Bitmap: TFPixmap;
    View: TView;
    Saved: Boolean;
    constructor Create;
    destructor Destroy; override;
  end;

implementation

function RectEquals(A, B: TRect): Boolean;
begin
  Result := (A.Left = B.Left) and (A.Top = B.Top) and
    (A.Right = B.Right) and (A.Bottom = B.Bottom);
end;

{ TFloatPoint }

function TFloatPoint.Create(AX, AY: Double): TFloatPoint;
begin
  Result.X := AX;
  Result.Y := AY;
end;


{ TView }

procedure TView.SetDestRect(AValue: TRect);
var
  Diff: TPoint;
begin
  if RectEquals(FDestRect, AValue) then Exit;
  Diff := Point(Trunc((FDestRect.Right - FDestRect.Left) / FZoom -
    (AValue.Right - AValue.Left) / FZoom) div 2,
    Trunc((FDestRect.Bottom - FDestRect.Top) / FZoom -
    (AValue.Bottom - AValue.Top) / FZoom) div 2);
  FDestRect := AValue;
  SrcRect := Bounds(FSrcRect.Left + Diff.X, FSrcRect.Top + Diff.Y,
    Trunc((FDestRect.Right - FDestRect.Left) / FZoom),
    Trunc((FDestRect.Bottom - FDestRect.Top) / FZoom));
end;

procedure TView.SetSrcRect(AValue: TRect);
begin
  if RectEquals(FSrcRect, AValue) then Exit;
  FSrcRect := AValue;
end;

procedure TView.SetZoom(AValue: Double);
const
  ZoomMin = 1/10000;
  ZoomMax = 10000;
begin
  if FZoom = AValue then Exit;
  if (FZoom > ZoomMax) or (FZoom < ZoomMin) then Exit;
  FZoom := AValue;
  FSrcRect := Bounds(Trunc(FSrcRect.Left + (FSrcRect.Right - FSrcRect.Left) div 2 -
    (DestRect.Right - DestRect.Left) / FZoom / 2),
    Trunc(FSrcRect.Top + (FSrcRect.Bottom - FSrcRect.Top) div 2 -
    (DestRect.Bottom - DestRect.Top) / FZoom / 2),
    Trunc((DestRect.Right - DestRect.Left) / FZoom),
    Trunc((DestRect.Bottom - DestRect.Top) / FZoom));
end;

procedure TView.Center(Rect: TRect);
begin
  FSrcRect := Bounds(Rect.Left + (Rect.Right - Rect.Left) div 2 - (FSrcRect.Right - FSrcRect.Left) div 2,
    Rect.Top + (Rect.Bottom - Rect.Top) div 2 - (FSrcRect.Bottom - FSrcRect.Top) div 2,
    FSrcRect.Right - FSrcRect.Left,
    FSrcRect.Bottom - FSrcRect.Top);
end;

constructor TView.Create;
begin
  FZoom := 1;
end;

procedure TView.ZoomAll(BitmapSize: TPoint);
var
  Factor: TFloatPoint;
begin
  Factor := TFloatPoint.Create((DestRect.Right - DestRect.Left) / BitmapSize.X,
    (DestRect.Bottom - DestRect.Top) / BitmapSize.Y);
  if Factor.X < Factor.Y then Zoom := Factor.X
    else Zoom := Factor.Y;
  Center(Rect(0, 0, BitmapSize.X, BitmapSize.Y));
end;

function TView.DestToSrcPos(Pos: TPoint): TPoint;
begin
  Result := Point(Trunc(Pos.X / FZoom + FSrcRect.Left),
    Trunc(Pos.Y / FZoom + FSrcRect.Top));
end;

function TView.SrcToDestPos(Pos: TPoint): TPoint;
begin
  Result := Point(Trunc((Pos.X - FSrcRect.Left) * FZoom),
    Trunc((Pos.Y - FSrcRect.Top) * FZoom));
end;


{ TProject }

constructor TProject.Create;
begin
  Bitmap := TFPixmap.Create(nil);
  View := TView.Create;
end;

destructor TProject.Destroy;
begin
  View.Free;
  Bitmap.Free;
  inherited Destroy;
end;

end.