source: trunk/Packages/FastGraphics/ColorFormats/UColorGray2.pas

unit UColorGray2;

{$mode delphi}

interface

uses
  Classes, SysUtils, Graphics, UGGraphics, UFGraphics;

type
  { TColorFormatGray2 }

  TColorFormatGray2 = class(TColorFormat)
    constructor Create; override;
  end;

  TColorGray2 = Byte;

  { TPixmapGray2 }

  TPixmapGray2 = class(TGPixmapBit<TColorGray2>)
    function Gray2ToColor(Value: TColorGray2): TColor;
    function ColorToGray2(Value: TColor): TColorGray2;
  end;

  { TBColorGray2 }

  TBColorGray2 = class(TBColor)
    Value: TColorGray2;
    constructor Create(Color: TColorGray2);
    procedure SetColorName(ColorName: TColorName); override;
    procedure SetRandom; override;
  end;

  { TBPixmapGray2 }

  TBPixmapGray2 = class(TBPixmap)
  private
    FillCallBack: TGetColorPos;
    function FillGetColor(Position: TPoint): TColorGray2;
  protected
    procedure SetSize(AValue: TPoint); override;
    function GetPixel(X, Y: Integer): IBColor;  override;
    procedure SetPixel(X, Y: Integer; AValue: IBColor); override;
  public
    Pixmap: TPixmapGray2;
    procedure Fill(Color: IBColor); override;
    procedure Fill(Func: TGetColorPos); override;
    procedure Line(P1, P2: TPoint; Color: IBColor); override;
    procedure PaintToCanvas(Canvas: TCanvas); override;
    procedure PaintToCanvas(Canvas: TCanvas; Rect: TRect); override;
    procedure PaintToBitmap(Bitmap: TBitmap; Rect: TRect); override;
    procedure LoadFromCanvas(Canvas: TCanvas); override;
    procedure LoadFromBitmap(Bitmap: TBitmap); override;
    function GetDataSize: Integer; override;
    constructor Create; override;
    destructor Destroy; override;
  end;




implementation

{ TColorFormatGray2 }

constructor TColorFormatGray2.Create;
begin
  inherited;
  Name := 'Gray 2-bit';
  BitDepth := 2;
  BackendColorClass := TBColorGray2;
  BackendPixmapClass := TBPixmapGray2;
  AddChannel('Gray', 0, 2);
end;

{ TBColorGray2 }

constructor TBColorGray2.Create(Color: TColorGray2);
begin
  Value := Color;
end;

procedure TBColorGray2.SetColorName(ColorName: TColorName);
begin
  case ColorName of
    cnBlack: Value := 0;
    cnGray: Value := 1;
    cnSilver: Value := 2;
    cnWhite: Value := 3;
    else Value := 0;
  end;
end;

procedure TBColorGray2.SetRandom;
begin
  Value := Random(4);
end;

{ TBPixmapGray2 }

function TBPixmapGray2.FillGetColor(Position: TPoint): TColorGray2;
begin
  Result := (FillCallBack(Position) as TBColorGray2).Value;
end;

procedure TBPixmapGray2.SetSize(AValue: TPoint);
begin
  inherited;
  Pixmap.Size := AValue;
end;

function TBPixmapGray2.GetPixel(X, Y: Integer): IBColor;
begin
  Result := TBColorGray2.Create(Pixmap.Pixels[X, Y]);
end;

procedure TBPixmapGray2.SetPixel(X, Y: Integer; AValue: IBColor);
begin
  Pixmap.Pixels[X, Y] := (AValue as TBColorGray2).Value;
end;

procedure TBPixmapGray2.Fill(Color: IBColor);
begin
  if Color is TBColorGray2 then
    Pixmap.Fill((Color as TBColorGray2).Value);
end;

procedure TBPixmapGray2.Fill(Func: TGetColorPos);
begin
  FillCallBack := Func;
  Pixmap.Fill(FillGetColor);
end;

procedure TBPixmapGray2.Line(P1, P2: TPoint; Color: IBColor);
begin
  Pixmap.Canvas.Pen.Color := (Color as TBColorGray2).Value;
  Pixmap.Canvas.Pen.MoveTo(P1);
  Pixmap.Canvas.Pen.LineTo(P2);
end;

procedure TBPixmapGray2.PaintToCanvas(Canvas: TCanvas);
begin
  Pixmap.PaintToCanvas(Canvas, Pixmap.Gray2ToColor);
end;

procedure TBPixmapGray2.PaintToCanvas(Canvas: TCanvas; Rect: TRect);
begin
  Pixmap.PaintToCanvas(Canvas, Rect, Pixmap.Gray2ToColor);
end;

procedure TBPixmapGray2.PaintToBitmap(Bitmap: TBitmap; Rect: TRect);
begin
  Pixmap.PaintToBitmap(Bitmap, Rect, Pixmap.Gray2ToColor);
end;

procedure TBPixmapGray2.LoadFromCanvas(Canvas: TCanvas);
begin
  Pixmap.LoadFromCanvas(Canvas, Pixmap.ColorToGray2);
end;

procedure TBPixmapGray2.LoadFromBitmap(Bitmap: TBitmap);
begin
  Pixmap.LoadFromBitmap(Bitmap, Pixmap.ColorToGray2);
end;

function TBPixmapGray2.GetDataSize: Integer;
begin
  Result := Pixmap.GetDataSize;
end;

constructor TBPixmapGray2.Create;
begin
  Pixmap := TPixmapGray2.Create;
  Pixmap.BitsPerPixel := 2;
end;

destructor TBPixmapGray2.Destroy;
begin
  FreeAndNil(Pixmap);
  inherited;
end;

{ TPixmapGray2 }

function TPixmapGray2.Gray2ToColor(Value: TColorGray2): TColor;
begin
  Value := (Value and $3) * (255 div (4 - 1));
  Result := (Value shl 16) or (Value shl 8) or (Value shl 0);
end;

function TPixmapGray2.ColorToGray2(Value: TColor): TColorGray2;
begin
  Result := Trunc((((Value shr 16) and $ff) + ((Value shr 8) and $ff) + ((Value shr 0) and $ff)) / $300 * 4);
end;


end.