source: trunk/StudioPackage/UDataModule.pas

unit UDataModule;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, ActnList, Controls, SpecializedList,
  USource, UModularSystem, UCoolTranslator, ULDStudioAPI, Menus, ComCtrls,
  Registry, URegistry, UApplicationInfo;

type
  { TOpenedFiles }

  TOpenedFiles = class(TListObject)
  private
    FOnChange: TNotifyEvent;
  public
    Selected: TSource;
    function FindByFileName(Value: string): TSource;
    procedure CloseFile(Source: TSource);
    procedure OpenFileName(FileName: string);
    procedure OpenFile(Source: TSource);
    property OnChange: TNotifyEvent read FOnChange write FOnChange;
  end;

  { TDataModule1 }

  TDataModule1 = class(TDataModule)
  published
    ActionListRegistred: TActionList;
    ApplicationInfo1: TApplicationInfo;
    CoolTranslator1: TCoolTranslator;
    ImageListMain: TImageList;
    API: TLDStudioAPI;
    procedure APIDockForm(Form: TForm; Target: TDockTarget);
    function APIGetRegistryContext: TRegistryContext;
    procedure APIRegisterFileTemplate(Template: TFileTemplate);
    procedure APIRegisterFileType(FileType: TSourceType);
    procedure APIRegisterForm(Form: TForm);
    procedure APIRegisterMainMenuItem(MenuItem: TMenuItem;
      ParentItem: TMenuItem; Index: Integer);
    procedure APIUnregisterAction(Action: TAction);
    procedure APIUnregisterFileTemplate(Template: TFileTemplate);
    procedure APIUnregisterFileType(FileType: TSourceType);
    procedure APIUnregisterForm(Form: TForm);
    procedure APIUnregisterMainMenuItem(MenuItem: TMenuItem);
    procedure APIOpenFile(FileName: string);
    procedure APIRegisterAction(Action: TAction);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    procedure AutoOpen;
    procedure DockToPageControl(PageControl: TPageControl; Form: TForm);
  public
    ModuleManager: TModuleManager;
    FileTypes: TFileTypes;
    FileTemplates: TFileTemplates;
    OpenedFiles: TOpenedFiles;
    procedure LoadFromRegistry(Context: TRegistryContext);
    procedure SaveToRegistry(Context: TRegistryContext);
  end;


var
  DataModule1: TDataModule1;


implementation

{$R *.lfm}

uses
  UFormMain, UFormSettings, UFormModuleList, UFormNewFile, ULDModuleBasic;

resourcestring
  SNewFile = 'New file';

{ TOpenedFiles }

function TOpenedFiles.FindByFileName(Value: string): TSource;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and (TSource(Items[I]).Name <> Value) do Inc(I);
  if I < Count then Result := TSource(Items[I])
    else Result := nil;
end;

procedure TOpenedFiles.CloseFile(Source: TSource);
begin
  FreeAndNil(Source.Form);
  Remove(Source);
  if Assigned(FOnChange) then FOnChange(Self);
end;

procedure TOpenedFiles.OpenFileName(FileName: string);
var
  NewFile: TSource;
  FileType: TSourceType;
begin
  FileType := DataModule1.FileTypes.FindByExt(ExtractFileExt(FileName));
  if Assigned(FileType) then begin
    NewFile := FileType.SourceClass.Create;
    NewFile.Name := FileName;
    OpenFile(NewFile);
  end;
end;

procedure TOpenedFiles.OpenFile(Source: TSource);
begin
  AddNew(Source);
  Source.Form := Source.FileType.Form.Create(nil);
  Source.Form.Caption := ExtractFileName(Source.Name);
  Source.Form.Visible := True;
  Selected := Source;
  if Assigned(FOnChange) then FOnChange(Self);
end;

{ TDataModule1 }

procedure TDataModule1.DataModuleCreate(Sender: TObject);
begin
  FileTemplates := TFileTemplates.Create;
  FileTemplates.OwnsObjects := False;
  FileTypes := TFileTypes.Create;
  FileTypes.OwnsObjects := False;
  OpenedFiles := TOpenedFiles.Create;
  ModuleManager := TModuleManager.Create(nil);
  ModuleManager.API := API;

  FormMain := TFormMain.Create(nil);
  Application.UpdateMainForm(FormMain);
  OpenedFiles.OnChange := FormMain.OpenedFileChange;
  FormSettings := TFormSettings.Create(nil);
  FormModuleList := TFormModuleList.Create(nil);
  FormNewFile := TFormNewFile.Create(nil);

  LoadFromRegistry(RegContext(HKEY(ApplicationInfo1.RegistryRoot), ApplicationInfo1.RegistryKey));

  DataModule1 := Self;
  FormMain.Show;
  AutoOpen;
end;

procedure TDataModule1.APIUnregisterMainMenuItem(MenuItem: TMenuItem);
begin
  MenuItem.Parent.Delete(MenuItem.Parent.IndexOf(MenuItem));
end;

procedure TDataModule1.APIRegisterMainMenuItem(MenuItem: TMenuItem;
  ParentItem: TMenuItem; Index: Integer);
begin
  if Assigned(ParentItem) then ParentItem.Insert(Index, MenuItem)
    else FormMain.MainMenu.Items.Insert(Index, MenuItem);
end;

procedure TDataModule1.APIRegisterForm(Form: TForm);
begin
  Form.Parent := FormMain;
end;

procedure TDataModule1.APIRegisterFileType(FileType: TSourceType);
begin
  FileTypes.Add(FileType);
end;

procedure TDataModule1.DockToPageControl(PageControl: TPageControl; Form: TForm
  );
var
  NewTabSheet: TTabSheet;
begin
  NewTabSheet := TTabSheet.Create(PageControl);
  NewTabSheet.Parent := PageControl;
  NewTabSheet.Visible := True;
  NewTabSheet.Caption := Form.Caption;
  Form.Align := alClient;
  Form.ManualDock(NewTabSheet, nil, alClient);
  Form.Visible := True;
end;

procedure TDataModule1.LoadFromRegistry(Context: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    RootKey := Context.RootKey;
    OpenKey(Context.Key, True);

  finally
    Free;
  end;
  FormMain.LoadFromRegistry(Context);
end;

procedure TDataModule1.SaveToRegistry(Context: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    RootKey := Context.RootKey;
    OpenKey(Context.Key, True);

  finally
    Free;
  end;
  FormMain.SaveToRegistry(Context);
end;

procedure TDataModule1.APIDockForm(Form: TForm; Target: TDockTarget);
begin
  with FormMain do
  case Target of
    dtCenter: DockToPageControl(PageControlCenter, Form);
//    dtTop: DockToPageControl(PageControlTop, Form);
    dtLeft: DockToPageControl(PageControlLeft, Form);
    dtRight: DockToPageControl(PageControlRight, Form);
    dtBottom: DockToPageControl(PageControlBottom, Form);
  end;
end;

function TDataModule1.APIGetRegistryContext: TRegistryContext;
begin
  Result := RegContext(HKEY(ApplicationInfo1.RegistryRoot), ApplicationInfo1.RegistryKey);
end;

procedure TDataModule1.APIRegisterFileTemplate(Template: TFileTemplate);
begin
  FileTemplates.Add(Template);
end;

procedure TDataModule1.APIUnregisterAction(Action: TAction);
begin
  Action.ActionList := nil;
end;

procedure TDataModule1.APIUnregisterFileTemplate(Template: TFileTemplate);
begin
  FileTemplates.Remove(Template);
end;

procedure TDataModule1.APIUnregisterFileType(FileType: TSourceType);
begin
  FileTypes.Remove(FileType);
end;

procedure TDataModule1.APIUnregisterForm(Form: TForm);
begin
  Form.Parent := nil;
end;

procedure TDataModule1.DataModuleDestroy(Sender: TObject);
begin
  SaveToRegistry(RegContext(HKEY(ApplicationInfo1.RegistryRoot), ApplicationInfo1.RegistryKey));
  FreeAndNil(ModuleManager);
  FreeAndNil(FormNewFile);
  FreeAndNil(FormMain);
  FreeAndNil(FormSettings);
  FreeAndNil(FormModuleList);
  FreeAndNil(OpenedFiles);
  FreeAndNil(FileTypes);
  FreeAndNil(FileTemplates);
end;

procedure TDataModule1.AutoOpen;
var
  FileName: string;
begin
  if (ParamCount > 0) then begin
    FileName := UTF8Encode(ParamStr(1));
    if FileExistsUTF8(FileName) then begin
      OpenedFiles.OpenFileName(FileName);
    end;
  end;
end;

procedure TDataModule1.APIOpenFile(FileName: string);
begin
  OpenedFiles.OpenFileName(FileName);
end;

procedure TDataModule1.APIRegisterAction(Action: TAction);
begin
  Action.ActionList := ActionListRegistred;
end;

end.