source: trunk/StudioPackage/Forms/UFormModuleList.pas

unit UFormModuleList;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, LResources, Forms, Controls, Graphics, Dialogs,
  ComCtrls, ExtCtrls, Menus, ActnList, SpecializedList, UModularSystem;

type

  { TFormModuleList }

  TFormModuleList = class(TForm)
    AInstall: TAction;
    AUninstall: TAction;
    AModuleUnregister: TAction;
    ActionList1: TActionList;
    ListViewModules: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    PopupMenu1: TPopupMenu;
    TimerRedraw: TTimer;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AInstallExecute(Sender: TObject);
    procedure AModuleUnregisterExecute(Sender: TObject);
    procedure AUninstallExecute(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormHide(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewModulesData(Sender: TObject; Item: TListItem);
    procedure ListViewModulesSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    procedure TimerRedrawTimer(Sender: TObject);
  private
    FModuleManager: TModuleManager;
    procedure SetModuleManager(AValue: TModuleManager);
    { private declarations }
  public
    property ModuleManager: TModuleManager read FModuleManager
      write SetModuleManager;
    procedure Reload;
    procedure UpdateInterface;
  end;

var
  FormModuleList: TFormModuleList;

implementation

resourcestring
  SNotInstalled = 'Not installed';
  SInstalled = 'Installed';

{ TFormModuleList }

procedure TFormModuleList.ListViewModulesData(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < FModuleManager.Modules.Count) then
  with TModule(FModuleManager.Modules[Item.Index]) do begin
    Item.Caption := Identification;
    Item.Data := FModuleManager.Modules[Item.Index];
    Item.SubItems.Add(Title);
    if Installed then Item.SubItems.Add(SInstalled)
      else Item.SubItems.Add(SNotInstalled);
    Item.SubItems.Add(Author);
    Item.SubItems.Add(License);
    Item.SubItems.Add(Version);
    Item.SubItems.Add(StringReplace(Dependencies.Text, LineEnding, ', ', [rfReplaceAll]));
  end;
end;

procedure TFormModuleList.ListViewModulesSelectItem(Sender: TObject;
  Item: TListItem; Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormModuleList.FormCreate(Sender: TObject);
begin
  DoubleBuffered := True;
  ControlStyle := ControlStyle + [csOpaque];
  ListViewModules.DoubleBuffered := True;
  ListViewModules.ControlStyle := ListViewModules.ControlStyle + [csOpaque];
end;

procedure TFormModuleList.AModuleUnregisterExecute(Sender: TObject);
begin
  if Assigned(ListViewModules.Selected) then begin
    FModuleManager.UnregisterModule(TModule(ListViewModules.Selected.Data));
    UpdateInterface;
  end;
end;

procedure TFormModuleList.AUninstallExecute(Sender: TObject);
begin
  if Assigned(ListViewModules.Selected) then begin
    TModule(ListViewModules.Selected.Data).Uninstall;
    UpdateInterface;
  end;
end;

procedure TFormModuleList.AInstallExecute(Sender: TObject);
begin
  if Assigned(ListViewModules.Selected) then begin
    TModule(ListViewModules.Selected.Data).Install;
    UpdateInterface;
  end
end;

procedure TFormModuleList.FormHide(Sender: TObject);
begin
  TimerRedraw.Enabled := False;
end;

procedure TFormModuleList.FormShow(Sender: TObject);
begin
  Reload;
  UpdateInterface;
  TimerRedraw.Enabled := True;
end;

procedure TFormModuleList.TimerRedrawTimer(Sender: TObject);
begin
  Reload;
end;

procedure TFormModuleList.SetModuleManager(AValue: TModuleManager);
begin
  if FModuleManager = AValue then Exit;
  FModuleManager := AValue;
  Reload;
end;

procedure TFormModuleList.Reload;
begin
  ListViewModules.Items.Count := FModuleManager.Modules.Count;
  ListViewModules.Refresh;
end;

procedure TFormModuleList.UpdateInterface;
begin
  AModuleUnregister.Enabled := Assigned(ListViewModules.Selected);
  AInstall.Enabled := Assigned(ListViewModules.Selected) and
    not TModule(ListViewModules.Selected.Data).Installed;
  AUninstall.Enabled := Assigned(ListViewModules.Selected) and
    TModule(ListViewModules.Selected.Data).Installed;
end;

initialization
  {$I UFormModuleList.lrs}

end.