source: trunk/Target/TargetRuby.pas

unit TargetRuby;

interface

uses
  Classes, SysUtils, FileUtil, Target, BFTarget, Process, Dialogs,
  LazFileUtils;

type

  { TTargetRuby }

  TTargetRuby = class(TBFTarget)
  private
    function GetMemoryCell: string;
  public
    function GetCompileParams: TStringArray; override;
    constructor Create; override;
    procedure Compile; override;
    procedure Run; override;
  end;


implementation

uses
  Common;

{ TTargetRuby }

constructor TTargetRuby.Create;
begin
  inherited;
  FName := 'Ruby';
  FSourceExtension := '.rb';
  FCompiledExtension := '.rb';
  FImageIndex := 33;
  FCapabilities := [tcCompile, tcRun];
  {$IFDEF WINDOWS}
  CompilerPath := '';
  ExecutorPath := 'c:\Program Files\Ruby\ruby.exe';
  {$ENDIF}
  {$IFDEF UNIX}
  CompilerPath := '';
  ExecutorPath := '/usr/bin/ruby';
  {$ENDIF}
end;

function TTargetRuby.GetMemoryCell: string;
begin
  Result := 'memory[pos';
  if FProgram[FProgramIndex].RelIndex > 0 then
    Result := Result + ' + ' + IntToStr(FProgram[FProgramIndex].RelIndex)
  else if FProgram[FProgramIndex].RelIndex < 0 then
    Result := Result + ' - ' + IntToStr(Abs(FProgram[FProgramIndex].RelIndex));
  Result := Result + ']';
end;

function TTargetRuby.GetCompileParams: TStringArray;
begin
  Result := [GetSourceFileName, '-o', GetCompileFileName];
end;

procedure TTargetRuby.Compile;
var
  Op: Char;
  MulValue: Integer;
begin
  inherited;
  Indent := 0;
  FTargetCode := '';

  AddLine('require ''io/console''');
  AddLine;
  AddLine('memory = Array.new(' + IntToStr(MemorySize) + ', 0)');
  AddLine('pos = 0');
  AddLine;
  FProgramIndex := 0;
  while FProgramIndex < FProgram.Count do begin
    case FProgram[FProgramIndex].Command of
      cmPointerInc: AddLine('pos += ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmPointerDec: AddLine('pos -= ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmInc: AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' + ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmDec: AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' - ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmOutput: AddLine('print ' + GetMemoryCell + '.chr');
      cmInput: AddLine(GetMemoryCell + ' = STDIN.getch');
      cmSet: AddLine(GetMemoryCell + ' = ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmMultiply: begin
        if FProgram[FProgramIndex].Parameter >= 0 then begin
          Op := '+';
          MulValue := FProgram[FProgramIndex].Parameter;
        end else begin
          Op := '-';
          MulValue := -FProgram[FProgramIndex].Parameter;
        end;
        if MulValue = 1 then
          AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' ' + Op + ' memory[pos]')
          else AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' ' + Op + ' memory[pos] * ' + IntToStr(MulValue));
      end;
      cmLoopStart: begin
        AddLine('while ' + GetMemoryCell + ' != 0');
        Inc(Indent);
      end;
      cmLoopEnd: begin
        Dec(Indent);
        AddLine('end');
      end;
    end;
    Inc(FProgramIndex);
  end;

  CompileToFile;
end;

procedure TTargetRuby.Run;
begin
  inherited;
  RunFromFile;
end;

end.