source: trunk/Target/TargetLua.pas

unit TargetLua;

interface

uses
  Classes, SysUtils, FileUtil, Target, BFTarget, Process, Dialogs,
  LazFileUtils;

type

  { TTargetLua }

  TTargetLua = class(TBFTarget)
  private
    function GetMemoryCell: string;
  public
    function GetCompileParams: TStringArray; override;
    constructor Create; override;
    procedure Compile; override;
    procedure Run; override;
  end;


implementation

uses
  Common;

{ TTargetLua }

constructor TTargetLua.Create;
begin
  inherited;
  FName := 'Lua';
  FSourceExtension := '.lua';
  FCompiledExtension := '.lua';
  FImageIndex := 34;
  FCapabilities := [tcCompile, tcRun];
  {$IFDEF WINDOWS}
  CompilerPath := '';
  ExecutorPath := 'c:\Program Files\Lua\lua.exe';
  {$ENDIF}
  {$IFDEF UNIX}
  CompilerPath := '';
  ExecutorPath := '/usr/bin/lua';
  {$ENDIF}
end;

function TTargetLua.GetMemoryCell: string;
begin
  Result := 'memory[pos';
  if FProgram[FProgramIndex].RelIndex > 0 then
    Result := Result + ' + ' + IntToStr(FProgram[FProgramIndex].RelIndex)
  else if FProgram[FProgramIndex].RelIndex < 0 then
    Result := Result + ' - ' + IntToStr(Abs(FProgram[FProgramIndex].RelIndex));
  Result := Result + ']';
end;

function TTargetLua.GetCompileParams: TStringArray;
begin
  Result := [GetSourceFileName, '-o', GetCompileFileName];
end;

procedure TTargetLua.Compile;
var
  Op: Char;
  MulValue: Integer;
begin
  inherited;
  Indent := 0;
  FTargetCode := '';

  AddLine('memory = {}');
  AddLine('for i = 0, ' + IntToStr(MemorySize - 1) + ' do');
  AddLine('  memory[i] = 0');
  AddLine('end');
  AddLine('pos = 0');
  AddLine;
  FProgramIndex := 0;
  while FProgramIndex < FProgram.Count do begin
    case FProgram[FProgramIndex].Command of
      cmPointerInc: AddLine('pos = pos + ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmPointerDec: AddLine('pos = pos - ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmInc: AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' + ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmDec: AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' - ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmOutput: AddLine('io.write(string.char(' + GetMemoryCell + '))');
      cmInput: AddLine(GetMemoryCell + ' = io.read(1)');
      cmSet: AddLine(GetMemoryCell + ' = ' + IntToStr(FProgram[FProgramIndex].Parameter));
      cmMultiply: begin
        if FProgram[FProgramIndex].Parameter >= 0 then begin
          Op := '+';
          MulValue := FProgram[FProgramIndex].Parameter;
        end else begin
          Op := '-';
          MulValue := -FProgram[FProgramIndex].Parameter;
        end;
        if MulValue = 1 then
          AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' ' + Op + ' memory[pos]')
          else AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' ' + Op + ' memory[pos] * ' + IntToStr(MulValue));
      end;
      cmLoopStart: begin
        AddLine('while(' + GetMemoryCell + ' ~= 0)');
        AddLine('do');
        Inc(Indent);
      end;
      cmLoopEnd: begin
        Dec(Indent);
        AddLine('end');
      end;
    end;
    Inc(FProgramIndex);
  end;

  CompileToFile;
end;

procedure TTargetLua.Run;
begin
  inherited;
  RunFromFile;
end;

end.