source: trunk/Forms/FormMemory.pas

unit FormMemory;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, Math, FormEx;

const
  RowSize = 16;

type

  { TFormMemory }

  TFormMemory = class(TFormEx)
    Label6: TLabel;
    ListViewMemory: TListView;
    procedure ListViewMemoryData(Sender: TObject; Item: TListItem);
  public
    procedure Reload;
  end;


implementation

{$R *.lfm}

uses
  Core, TargetInterpreter;

{ TFormMemory }

procedure TFormMemory.Reload;
begin
  if Core.Core.CurrentTarget is TTargetInterpreter then
  with TTargetInterpreter(Core.Core.CurrentTarget) do begin
    if MemoryChanged then begin
      MemoryChanged := False;
      ListViewMemory.Items.Count := Ceil((MemoryMaxUsedAddr + 1) / RowSize);
      ListViewMemory.Refresh;
    end;
  end;
end;

procedure TFormMemory.ListViewMemoryData(Sender: TObject; Item: TListItem);
var
  Row: string;
  I: Integer;
  Text: string;
  Address: Integer;
begin
  if Core.Core.CurrentTarget is TTargetInterpreter then
  with TTargetInterpreter(Core.Core.CurrentTarget) do
  if (Item.Index >= 0) and (Item.Index <= Trunc((MemoryMaxUsedAddr + 1) / RowSize)) then begin
    Item.Caption := IntToHex(Item.Index * RowSize, 8);
    Row := '';
    Text := Default(string);
    SetLength(Text, RowSize);
    for I := 0 to RowSize - 1 do begin
      Address := Item.Index * RowSize + I;
      if Address < (MemoryMaxUsedAddr + 1) then begin
        Row := Row + ' ' + IntToHex(Memory[Address], 2);
        if Memory[Address] > Ord(' ') then Text[I + 1] := Chr(Memory[Address])
          else Text[I + 1] := ' ';
      end else Text[I + 1] := ' ';
    end;
    Item.SubItems.Add(Row);
    Item.SubItems.Add(Text);
  end;
end;

end.