source: trunk/Forms/FormKeyShortcuts.pas

unit FormKeyShortcuts;

interface

uses
  Classes, SysUtils, FileUtil, LResources, Forms, Controls, Graphics, Dialogs,
  ComCtrls, ActnList, LCLProc, Menus, FormEx, Generics.Collections, ImgList;

type

  { TFormKeyShortcuts }

  TFormKeyShortcuts = class(TFormEx)
    ListView1: TListView;
    MenuItem1: TMenuItem;
    PopupMenu1: TPopupMenu;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure MenuItem1Click(Sender: TObject);
  private
    function GetImageList: TCustomImageList;
    procedure SetImageList(AValue: TCustomImageList);
  public
    SourceComponents: TObjectList<TComponent>;
    MainForm: TForm;
    procedure LoadFromComponent(C: TComponent);
    property ImageList: TCustomImageList read GetImageList write SetImageList;
  end;


implementation

{$R *.lfm}

resourcestring
  SMainForm = 'Main window';
  SGlobal = 'Global';

{ TFormKeyShortcuts }

procedure TFormKeyShortcuts.FormShow(Sender: TObject);
var
  I: Integer;
begin
  try
    ListView1.BeginUpdate;
    ListView1.Clear;
    for I := 0 to SourceComponents.Count - 1 do
      LoadFromComponent(SourceComponents[I]);
  finally
    ListView1.EndUpdate;
  end;
end;

procedure TFormKeyShortcuts.FormCreate(Sender: TObject);
begin
  SourceComponents := TObjectList<TComponent>.Create;
  SourceComponents.OwnsObjects := False;
end;

procedure TFormKeyShortcuts.FormDestroy(Sender: TObject);
begin
  FreeAndNil(SourceComponents);
end;

procedure TFormKeyShortcuts.MenuItem1Click(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then
    TAction(ListView1.Selected.Data).Execute;
end;

function TFormKeyShortcuts.GetImageList: TCustomImageList;
begin
  Result := ListView1.SmallImages;
end;

procedure TFormKeyShortcuts.SetImageList(AValue: TCustomImageList);
begin
  ListView1.SmallImages := AValue
end;

procedure TFormKeyShortcuts.LoadFromComponent(C: TComponent);
var
  I: Integer;
  NewItem: TListItem;
begin
  if C is TActionList then
  with TActionList(C) do begin
    for I := 0 to ActionCount - 1 do
      if Actions[I] is TAction then
        with TAction(Actions[I]) do
        //if ShortCut > 0 then
        begin
          NewItem := ListView1.Items.Add;
          NewItem.Caption := Caption;
          NewItem.ImageIndex := ImageIndex;
          NewItem.Data := TAction(Actions[I]);
          with NewItem.SubItems do begin
            if C.Owner = MainForm then Add(SMainForm)
            else if C.Owner is TDataModule then Add(SGlobal)
            else if C.Owner is TForm then Add(TForm(C.Owner).Caption)
            else Add(C.Name);
            Add(ShortCutToText(ShortCut));
          end;
        end;
  end;
  for I := 0 to C.ComponentCount - 1 do
    LoadFromComponent(C.Components[I]);
end;

end.