source: trunk/Forms/FormConsole.pas

unit FormConsole;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ExtCtrls, Process, FormEx;

type

  { TFormConsole }

  TFormConsole = class(TFormEx)
    ButtonAbort: TButton;
    EditCommand: TEdit;
    Memo1: TMemo;
    Timer1: TTimer;
    procedure ButtonAbortClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    Process: TProcess;
  public
    Executable: string;
    Parameters: TStringList;
    WorkingDir: string;
    EnvironmentVariables: TStringList;
    Aborted: Boolean;
    Log: TStringList;
    procedure Perform;
  end;


implementation

{$R *.lfm}

{ TFormConsole }

procedure TFormConsole.FormCreate(Sender: TObject);
begin
  Parameters := TStringList.Create;
  Log := TStringList.Create;
  EnvironmentVariables := TStringList.Create;
end;

procedure TFormConsole.FormDestroy(Sender: TObject);
begin
  FreeAndNil(EnvironmentVariables);
  FreeAndNil(Log);
  FreeAndNil(Parameters);
end;

procedure TFormConsole.FormShow(Sender: TObject);
begin
  ButtonAbort.Enabled := False;
  Timer1.Enabled := True;
end;

procedure TFormConsole.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := False;
  Perform;
end;

procedure TFormConsole.ButtonAbortClick(Sender: TObject);
begin
  if Assigned(Process) then begin
    Aborted := True;
    Process.Terminate(0);
  end;
end;

procedure TFormConsole.FormClose(Sender: TObject; var CloseAction: TCloseAction
  );
begin
  ButtonAbort.Click;
end;

procedure TFormConsole.Perform;
var
  Buffer: string;
  Count: Integer;
  Text: string;
  Line: string;
  CommandLine: string;
begin
  Buffer := '';
  Text := '';
  try
    Process := TProcess.Create(nil);
    Aborted := False;
    ButtonAbort.Enabled := True;
    Log.Clear;
    Memo1.Clear;
    if WorkingDir <> '' then
      Process.CurrentDirectory := WorkingDir;
    Process.Environment.Assign(EnvironmentVariables);
    Process.Parameters.Assign(Parameters);
    Process.Executable := Executable;
    CommandLine := Executable + ' ' + StringReplace(Parameters.Text, LineEnding,
      ' ', [rfReplaceAll]);
    if CommandLine[Length(CommandLine)] = LineEnding then
      SetLength(CommandLine, Length(CommandLine) - 1);
    EditCommand.Text := CommandLine;
    Process.Options := [poUsePipes, poNoConsole];
    Process.Execute;
    Application.ProcessMessages;
    while Process.Running or (Process.Output.NumBytesAvailable > 0) or
    (Process.Stderr.NumBytesAvailable > 0) do
    begin
      if Process.Output.NumBytesAvailable > 0 then begin
        SetLength(Buffer, 1000);
        Count := Process.Output.Read(Buffer[1], Length(Buffer));
        SetLength(Buffer, Count);
        Text := Text + Buffer;
        Text := StringReplace(Text, #10#13, LineEnding, [rfReplaceAll]);
        while Pos(LineEnding, Text) > 0 do begin
          Line := Copy(Text, 1, Pos(LineEnding, Text) - 1);
          Delete(Text, 1, Length(Line) + Length(LineEnding));
          if Visible then Memo1.Lines.Add(Line);
          Log.Add(Line);
        end;
      end;

      if Process.Stderr.NumBytesAvailable > 0 then begin
        SetLength(Buffer, 1000);
        Count := Process.Stderr.Read(Buffer[1], Length(Buffer));
        SetLength(Buffer, Count);
        Text := Text + Buffer;
        Text := StringReplace(Text, #10#13, LineEnding, [rfReplaceAll]);
        while Pos(LineEnding, Text) > 0 do begin
          Line := Copy(Text, 1, Pos(LineEnding, Text) - 1);
          Delete(Text, 1, Length(Line) + Length(LineEnding));
          if Visible then Memo1.Lines.Add(Line);
          Log.Add(Line);
        end;
      end;
      Sleep(10);
      Application.ProcessMessages;
    end;
  finally
    if Visible then Memo1.Lines.Add(Text);
    Log.Add(Text);
    FreeAndNil(Process);
  end;
  ButtonAbort.Enabled := False;
  //ModalResult := mrOK;
  //Close;
end;

end.