source: trunk/Examples/Others/dbf2c.b

Last change on this file was 11, checked in by chronos, 12 years ago
  • Added: Some other examples from web.
File size: 1.2 KB
Line 
1+++[>+++++<-]>>+<[>>++++>++>+++++>+++++>+>>+<++[++<]>---]
2
3>++++.>>>.+++++.>------.<--.+++++++++.>+.+.<<<<---.[>]<<.<<<.-------.>++++.
4<+++++.+.>-----.>+.<++++.>>++.>-----.
5
6<<<-----.+++++.-------.<--.<<<.>>>.<<+.>------.-..--.+++.-----<++.<--[>+<-]
7>>>>>--.--.<++++.>>-.<<<.>>>--.>.
8
9<<<<-----.>----.++++++++.----<+.+++++++++>>--.+.++<<<<.[>]<.>>
10
11,[>>+++[<+++++++>-]<[<[-[-<]]>>[>]<-]<[<+++++>-[<+++>-[<-->-[<+++>-
12[<++++[>[->>]<[>>]<<-]>[<+++>-[<--->-[<++++>-[<+++[>[-[-[-[->>]]]]<[>>]<<-]
13>[<+>-[<->-[<++>-[<[-]>-]]]]]]]]]]]]]
14
15<[
16 -[-[>+<-]>]
17 <[<<<<.>+++.+.+++.-------.>---.++.<.>-.++<<<<.[>]>>>>>>>>>]
18 <[[<]>++.--[>]>>>>>>>>]
19 <[<<++..-->>>>>>]
20 <[<<..>>>>>]
21 <[<<..-.+>>>>]
22 <[<<++..---.+>>>]
23 <[<<<.>>.>>>>>]
24 <[<<<<-----.+++++>.----.+++.+>---.<<<-.[>]>]
25 <[<<<<.-----.>++++.<++.+++>----.>---.<<<.-[>]]
26 <[<<<<<----.>>.<<.+++++.>>>+.++>.>>]
27 <.>
28]>
29,]
30
31<<<<<.<+.>++++.<----.>>---.<<<-.>>>+.>.>.[<]>++.[>]<.
32>[Translates brainfuck to C. Assumes no-change-on-EOF or EOF->0.
33Generated C does no-change-on-EOF, and uses unistd.h read and write calls.
34Daniel B Cristofani (cristofdathevanetdotcom)
35http://www.hevanet.com/cristofd/brainfuck/]
Note: See TracBrowser for help on using the repository browser.