source: tags/1.3.0/Target/TargetRust.pas

unit TargetRust;

interface

uses
  Classes, SysUtils, FileUtil, Target, BFTarget, Process, Dialogs,
  LazFileUtils;

type

  { TTargetRust }

  TTargetRust = class(TBFTarget)
  private
    function GetMemoryCell: string;
  public
    function GetCompileParams: TStringArray; override;
    constructor Create; override;
    procedure Compile; override;
    procedure Run; override;
  end;


implementation

uses
  Common;

{ TTargetRust }

constructor TTargetRust.Create;
begin
  inherited;
  FName := 'Rust';
  FSourceExtension := '.rs';
  FImageIndex := 30;
  FCapabilities := [tcCompile, tcRun];
  {$IFDEF WINDOWS}
  CompilerPath := 'c:\Program Files\Rust\rustc.exe';
  FCompiledExtension := '.exe';
  {$ENDIF}
  {$IFDEF UNIX}
  CompilerPath := '/usr/bin/rustc';
  FCompiledExtension := '';
  {$ENDIF}
end;

function TTargetRust.GetMemoryCell: string;
begin
  Result := 'memory[pos';
  if FProgram[FProgramIndex].RelIndex > 0 then
    Result := Result + ' + ' + IntToStr(FProgram[FProgramIndex].RelIndex)
  else if FProgram[FProgramIndex].RelIndex < 0 then
    Result := Result + ' - ' + IntToStr(Abs(FProgram[FProgramIndex].RelIndex));
  Result := Result + ']';
end;

function TTargetRust.GetCompileParams: TStringArray;
begin
  Result := [GetSourceFileName, '-o', GetCompileFileName];
end;

procedure TTargetRust.Compile;
var
  Op: Char;
  MulValue: Integer;
begin
  inherited;
  Indent := 0;
  FTargetCode := '';

  AddLine('fn main()');
  AddLine('{');
  Inc(Indent);
  AddLine('let mut memory: [u8; ' + IntToStr(MemorySize) + '] = [0; ' + IntToStr(MemorySize) + '];');
  AddLine('let mut pos = 0;');
  AddLine('');
  FProgramIndex := 0;
  while FProgramIndex < FProgram.Count do begin
    case FProgram[FProgramIndex].Command of
      cmPointerInc: AddLine('pos += ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmPointerDec: AddLine('pos -= ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmInc: AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' + ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmDec: AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' - ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmOutput: AddLine('print!("{}", char::from(' + GetMemoryCell + '));');
      cmInput: AddLine(GetMemoryCell + ' = getchar().to_u8();');
      cmSet: AddLine(GetMemoryCell + ' = ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmMultiply: begin
        if FProgram[FProgramIndex].Parameter >= 0 then begin
          Op := '+';
          MulValue := FProgram[FProgramIndex].Parameter;
        end else begin
          Op := '-';
          MulValue := -FProgram[FProgramIndex].Parameter;
        end;
        if MulValue = 1 then
          AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' ' + Op + ' memory[pos];')
          else AddLine(GetMemoryCell + ' = ' + GetMemoryCell + ' ' + Op + ' memory[pos] * ' + IntToStr(MulValue) + ';');
      end;
      cmLoopStart: begin
        AddLine('while ' + GetMemoryCell + ' != 0');
        AddLine('{');
        Inc(Indent);
      end;
      cmLoopEnd: begin
        Dec(Indent);
        AddLine('}');
      end;
    end;
    Inc(FProgramIndex);
  end;
  Dec(Indent);
  AddLine('}');

  CompileToFile;
end;

procedure TTargetRust.Run;
begin
  inherited;
  RunFromFile;
end;

end.