source: tags/1.3.0/Target/TargetFPC.pas

unit TargetFPC;

interface

uses
  Classes, SysUtils, Target, BFTarget;

type

  { TTargetFPC }

  TTargetFPC = class(TBFTarget)
  private
    function GetMemoryCell: string;
  public
    constructor Create; override;
    procedure Compile; override;
    procedure Run; override;
  end;

implementation

{ TTargetFPC }

constructor TTargetFPC.Create;
begin
  inherited;
  FName := 'FPC';
  FSourceExtension := '.pas';
  FImageIndex := 22;
  FCapabilities := [tcCompile, tcRun];
  {$IFDEF WINDOWS}
  FCompiledExtension := '.exe';
  CompilerPath := 'fpc.exe';
  {$ENDIF}
  {$IFDEF UNIX}
  FCompiledExtension := '';
  CompilerPath := '/usr/bin/fpc';
  {$ENDIF}
end;

function TTargetFPC.GetMemoryCell: string;
begin
  Result := 'Memory[Pos';
  if FProgram[FProgramIndex].RelIndex > 0 then
    Result := Result + ' + ' + IntToStr(FProgram[FProgramIndex].RelIndex)
  else if FProgram[FProgramIndex].RelIndex < 0 then
    Result := Result + ' - ' + IntToStr(Abs(FProgram[FProgramIndex].RelIndex));
  Result := Result + ']';
end;

procedure TTargetFPC.Compile;
begin
  inherited;
  Indent := 0;
  FTargetCode := '';

  AddLine('program ' + ProgramName + ';');
  AddLine('var');
  AddLine('  Memory: array[0..' + IntToStr(MemorySize) + '] of Byte;');
  AddLine('  Pos: Integer;');
  AddLine('  ReadChar: Char;');
  AddLine('begin');
  Inc(Indent);
  AddLine('Pos := 0;');
  FProgramIndex := 0;
  while FProgramIndex < FProgram.Count do begin
    case FProgram[FProgramIndex].Command of
      cmPointerInc: AddLine('Inc(Pos, ' + IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmPointerDec: AddLine('Dec(Pos, ' + IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmInc: AddLine(GetMemoryCell + ' := ' + GetMemoryCell + ' + ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmDec: AddLine(GetMemoryCell + ' := ' + GetMemoryCell + ' - ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmSet: AddLine(GetMemoryCell + ' := ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmMultiply: AddLine(GetMemoryCell + ' := ' + GetMemoryCell + ' + Memory[Pos] * ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmOutput: AddLine('Write(Chr(' + GetMemoryCell + '));');
      cmInput: AddLine('Read(ReadChar); ' + GetMemoryCell + ' := Ord(ReadChar);');
      cmLoopStart: begin
        AddLine('while ' + GetMemoryCell + ' <> 0 do begin');
        Inc(Indent);
      end;
      cmLoopEnd: begin
        Dec(Indent);
        AddLine('end;');
      end;
    end;
    Inc(FProgramIndex);
  end;
  Dec(Indent);
  AddLine('end.');

  CompileToFile;
end;

procedure TTargetFPC.Run;
begin
  inherited;
  RunFromFile;
end;

end.