source: tags/1.3.0/Target/TargetCSharp.pas

unit TargetCSharp;

interface

uses
  Classes, SysUtils, FileUtil, Target, BFTarget, Dialogs;

type

  { TTargetCSharp }

  TTargetCSharp = class(TBFTarget)
  private
    function GetMemoryCell: string;
  public
    constructor Create; override;
    procedure Compile; override;
    procedure Run; override;
  end;


implementation

{ TTargetCSharp }

constructor TTargetCSharp.Create;
begin
  inherited;
  FName := 'C#';
  FSourceExtension := '.cs';
  FCompiledExtension := '.exe';
  FImageIndex := 27;
  FCapabilities := [tcCompile, tcRun];
  {$IFDEF WINDOWS}
  CompilerPath := 'C:\Program Files (x86)\Microsoft Visual Studio\2017\Community\MSBuild\15.0\Bin\Roslyn\csc.exe';
  ExecutorPath := '';
  {$ENDIF}
  {$IFDEF UNIX}
  CompilerPath := '/usr/bin/mcs';
  ExecutorPath := '';
  {$ENDIF}
end;

function TTargetCSharp.GetMemoryCell: string;
begin
  Result := 'Memory[Pos';
  if FProgram[FProgramIndex].RelIndex > 0 then
    Result := Result + ' + ' + IntToStr(FProgram[FProgramIndex].RelIndex)
  else if FProgram[FProgramIndex].RelIndex < 0 then
    Result := Result + ' - ' + IntToStr(Abs(FProgram[FProgramIndex].RelIndex));
  Result := Result + ']';
end;

procedure TTargetCSharp.Compile;
begin
  inherited;
  Indent := 0;
  FTargetCode := '';

  AddLine('using System;');
  AddLine;
  AddLine('public class ' + ProgramName);
  AddLine('{');
  Inc(Indent);
  AddLine('public static void Main()');
  AddLine('{');
  Inc(Indent);
  AddLine('int[] Memory;');
  AddLine('int Pos;');
  AddLine;
  AddLine('Memory = new int[' + IntToStr(MemorySize) + '];');
  AddLine('Pos = 0;');
  FProgramIndex := 0;
  while FProgramIndex < FProgram.Count do begin
    case FProgram[FProgramIndex].Command of
      cmPointerInc: AddLine('Pos += ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmPointerDec: AddLine('Pos -= ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmInc: AddLine(GetMemoryCell + ' += ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmDec: AddLine(GetMemoryCell + ' -= ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmOutput: AddLine('Console.Write((char)' + GetMemoryCell + ');');
      cmInput: AddLine(GetMemoryCell + ' = (int)Console.ReadKey().KeyChar;');
      cmSet: AddLine(GetMemoryCell + ' = ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmMultiply: begin
        if FProgram[FProgramIndex].Parameter = 1 then
          AddLine(GetMemoryCell + ' += Memory[Pos];')
        else
        if FProgram[FProgramIndex].Parameter > 0 then
          AddLine(GetMemoryCell + ' += Memory[Pos] * ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';')
        else
        if FProgram[FProgramIndex].Parameter < 0 then
          AddLine(GetMemoryCell + ' -= Memory[Pos] * ' + IntToStr(Abs(FProgram[FProgramIndex].Parameter)) + ';');
      end;
      cmLoopStart: begin
        AddLine('while (' + GetMemoryCell + ' != 0)');
        AddLine('{');
        Inc(Indent);
      end;
      cmLoopEnd: begin
        Dec(Indent);
        AddLine('}');
      end;
    end;
    Inc(FProgramIndex);
  end;
  Dec(Indent);
  AddLine('}');
  Dec(Indent);
  AddLine('}');

  CompileToFile;
end;

procedure TTargetCSharp.Run;
begin
  inherited;
  RunFromFile;
end;

end.