source: tags/1.3.0/BFCodeTools.pas

unit BFCodeTools;

interface

uses
  Classes, SysUtils, StrUtils, Math;

function GenerateNumber(Number: Integer): string;
function GenerateNumberSimple(Number: Integer): string;
function GenerateText(Text: string): string;
function FormatCode(Text: string): string;
function ShrinkCode(Text: string): string;


implementation

function GenerateNumber(Number: Integer): string;
var
  Base: Integer;
  Multiplier: Integer;
  Remainder: Integer;
begin
  Result := '';
  Base := Trunc(Sqrt(Number));
  Remainder := Number;
  if Base > 1 then begin
    Multiplier := Trunc(Remainder / Base);
    Result := Result + '>' + GenerateNumberSimple(Base) + '[<' +
      GenerateNumberSimple(Multiplier) + '>-]<';
    Remainder := Remainder - Base * Multiplier;
  end;
  Result := Result + GenerateNumberSimple(Remainder);
  if Length(Result) > Number then
    Result := GenerateNumberSimple(Number);
end;

function GenerateNumberSimple(Number: Integer): string;
begin
  Result := DupeString('+', Number);
end;

function GenerateText(Text: string): string;
var
  I: Integer;
  MinValue: Integer;
begin
  Result := '';

  if Length(Text) > 1 then begin
    MinValue := MaxInt;
    for I := 1 to Length(Text) do
      MinValue := Min(MinValue, Ord(Text[I]));

    if MinValue > 1 then
      Result := DupeString('>', Length(Text)) + GenerateNumber(MinValue) +
        '[' + DupeString('<+', Length(Text)) + DupeString('>', Length(Text)) + '-]';
    Result := Result + DupeString('<', Length(Text));
  end;

  for I := 1 to Length(Text) do begin
    Result := Result + GenerateNumberSimple(Ord(Text[I]) - MinValue) + '>';
  end;
end;

function FormatCode(Text: string): string;
var
  IndentLevel: Integer;
  I: Integer;
const
  IndentText = '  ';
begin
  Result := '';
  IndentLevel := 0;
  for I := 1 to Length(Text) do begin
    if Text[I] = '[' then begin
      Result := Result + LineEnding + DupeString(IndentText, IndentLevel) +
        Text[I] + LineEnding ;
      Inc(IndentLevel);
      Result := Result + DupeString(IndentText, IndentLevel);
    end
    else if Text[I] = ']' then begin
      Dec(IndentLevel);
      Result := Result + LineEnding + DupeString(IndentText, IndentLevel) +
        Text[I] + LineEnding + DupeString(IndentText, IndentLevel);
    end
    else if Text[I] > ' ' then
      Result := Result + Text[I];
  end;
end;

// Remove all non-printable characters
function ShrinkCode(Text: string): string;
var
  Pos: Integer;
  I: Integer;
begin
  Pos := 1;
  for I := 1 to Length(Text) do begin
    if Text[I] > ' ' then begin
      Text[Pos] := Text[I];
      Inc(Pos);
    end;
  end;
  SetLength(Text, Pos - 1);
  Result := Text;
end;

end.