source: tags/1.2.0/Target/UTargetPHP.pas

unit UTargetPHP;

{$mode Delphi}{$H+}

interface

uses
  Classes, SysUtils, UTarget, UBFTarget;

type

  { TTargetPHP }

  TTargetPHP = class(TBFTarget)
  private
    function GetMemoryCell: string;
  public
    constructor Create; override;
    procedure Compile; override;
    procedure Run; override;
  end;


implementation

{ TTargetPHP }

constructor TTargetPHP.Create;
begin
  inherited;
  FName := 'PHP';
  FSourceExtension := '.php';
  FRunExtension := '.php';
  FCompiledExtension := '.php';
  FImageIndex := 21;
  FCapabilities := [tcCompile, tcRun];
  {$IFDEF WINDOWS}
  CompilerPath := '';
  ExecutorPath := 'c:\Program Files\PHP\php.exe';
  {$ENDIF}
  {$IFDEF UNIX}
  CompilerPath := '';
  ExecutorPath := '/usr/bin/php';
  {$ENDIF}
end;

function TTargetPHP.GetMemoryCell: string;
begin
  Result := '$Memory[$Position';
  if FProgram[FProgramIndex].RelIndex > 0 then
    Result := Result + ' + ' + IntToStr(FProgram[FProgramIndex].RelIndex)
  else if FProgram[FProgramIndex].RelIndex < 0 then
    Result := Result + ' - ' + IntToStr(Abs(FProgram[FProgramIndex].RelIndex));
  Result := Result + ']';
end;

procedure TTargetPHP.Compile;
begin
  inherited;
  Indent := 0;
  FTargetCode := '';

  AddLine('<?php // ' + ProgramName);
  AddLine('');
  AddLine('$Memory = str_repeat("\0", ' + IntToStr(MemorySize) + ');');
  AddLine('$Position = 0;');
  FProgramIndex := 0;
  while FProgramIndex < FProgram.Count do begin
    case FProgram[FProgramIndex].Command of
      cmPointerInc: AddLine('$Position = $Position + ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmPointerDec: AddLine('$Position = $Position - ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmInc: AddLine(GetMemoryCell + ' = chr(ord(' + GetMemoryCell + ') + ' +
        IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmDec: AddLine(GetMemoryCell + ' = chr(ord(' + GetMemoryCell + ') - ' +
        IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmOutput: AddLine('echo(' + GetMemoryCell + ');');
      cmInput: AddLine(GetMemoryCell + ' = fgetc(STDIN);');
      cmSet: AddLine(GetMemoryCell + ' = chr(' + IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmMultiply: AddLine(GetMemoryCell + ' = chr(ord(' + GetMemoryCell + ') + ord($Memory[$Position]) * ' + IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmLoopStart: begin
        AddLine('while(' + GetMemoryCell + ' != "\0") {');
        Inc(Indent);
      end;
      cmLoopEnd: begin
        Dec(Indent);
        AddLine('}');
      end;
    end;
    Inc(FProgramIndex);
  end;

  CompileToFile;
end;

procedure TTargetPHP.Run;
begin
  inherited;
  RunFromFile;
end;

end.