source: trunk/Forms/USourceSelection.pas

unit USourceSelection;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  StdCtrls, USource, HttpSend;

type

  { TSourceSelectionForm }

  TSourceSelectionForm = class(TForm)
    ButtonOk: TButton;
    ButtonCancel: TButton;
    ButtonUpdateSource: TButton;
    ListView1: TListView;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ButtonUpdateSourceClick(Sender: TObject);
  private
    { private declarations }
  public
    ProjectType: string;
    Sources: TSourceList;
    procedure ReloadList;
  end; 

var
  SourceSelectionForm: TSourceSelectionForm;

implementation

{$R *.lfm}

uses
  UMainForm;

{ TSourceSelectionForm }

procedure TSourceSelectionForm.ReloadList;
var
  I: Integer;
begin
  Sources.Clear;
  for I := 0 to MainForm.Sources.Count - 1 do
    if (TSource(MainForm.Sources[I]).ProjectType = ProjectType) or
    (ProjectType = '') then
      Sources.Add(MainForm.Sources[I]);
  if ListView1.Items.Count <> Sources.Count then
    ListView1.Items.Count := Sources.Count;
  ListView1.Items[-1]; // workaround
  ListView1.Refresh;
end;

procedure TSourceSelectionForm.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if Item.Index < Sources.Count then
  with TSource(Sources[Item.Index]) do begin
    Item.Caption := ProjectName;
    Item.Data := Sources[Item.Index];
    Item.SubItems.Add(VersionType);
    Item.SubItems.Add(VersionNumber);
    Item.SubItems.Add('');
    Item.SubItems.Add('');
    Item.SubItems.Add(BooleanText[Downloaded]);
    Item.SubItems.Add(SubversionURL);
  end;
end;

procedure TSourceSelectionForm.FormShow(Sender: TObject);
begin
  ReloadList;
end;

procedure TSourceSelectionForm.FormCreate(Sender: TObject);
begin
  Sources := TSourceList.Create;
  Sources.OwnsObjects := False;
end;

procedure TSourceSelectionForm.FormDestroy(Sender: TObject);
begin
  Sources.Free;
end;

procedure TSourceSelectionForm.ButtonUpdateSourceClick(Sender: TObject);
var
  fs: TFileStream;
begin
  fs := TFileStream.Create(ExtractFileName(MainForm.SourceURL), fmOpenWrite or fmCreate);
  try
    HttpGetBinary(MainForm.SourceURL, fs);
  finally
    fs.Free;
  end;
  MainForm.Sources.UpdateFormFile(ExtractFileName(MainForm.SourceURL));
  ReloadList;
end;

end.