source: trunk/UPakFile.pas

unit UPakFile;

{$mode delphi}

interface

uses
  Classes, SysUtils, Contnrs, UStreamHelper;

type
  TPakItem = class
    Name: string;
    Start: Integer;
    Size: Integer;
  end;

  { TPakFile }

  TPakFile = class
  private
    function GetOpenned: Boolean;
  public
    DataFile: TFileStream;
    FileName: string;
    Files: TObjectList;
    procedure Open(FileName: string);
    procedure Close;
    procedure ExtractTo(Directory: string);
    constructor Create;
    destructor Destroy; override;
    property Openned: Boolean read GetOpenned;
  end;

implementation

{ TPakFile }

function TPakFile.GetOpenned: Boolean;
begin
  Result := Assigned(DataFile);
end;

procedure TPakFile.Open(FileName: string);
var
  Buffer: array of Byte;
  I: Integer;
  NewItem: TPakItem;
  Helper: TStreamHelper;
begin
  Close;
  Self.FileName := FileName;
  DataFile := TFileStream.Create(FileName, fmOpenRead);
  Helper := TStreamHelper.Create(DataFile);

  while Helper.Position < Helper.Size do begin
    NewItem := TPakItem.Create;
    NewItem.Start := Helper.ReadCardinal;
    if NewItem.Start = 0 then begin
      NewItem.Free;
      TPakItem(Files.Last).Size := Datafile.Size - TPakItem(Files.Last).Start;
      Break;
    end;
    NewItem.Name := Helper.ReadStringTerminated;
    if Files.Count > 0 then
      TPakItem(Files.Last).Size := NewItem.Start - TPakItem(Files.Last).Start;
    Files.Add(NewItem);
  end;
  Helper.Free;
end;

procedure TPakFile.Close;
begin
  if Openned then begin
    FreeAndNil(DataFile);
    Files.Count := 0;
  end;
end;

procedure TPakFile.ExtractTo(Directory: string);
var
  NewFile: TFileStream;
  I: Integer;
begin
  for I := 0 to Files.Count - 1 do begin
    ForceDirectories(Directory + DirectorySeparator + ExtractFileName(FileName));
    NewFile := TFileStream.Create(Directory + DirectorySeparator + ExtractFileName(FileName) +
      DirectorySeparator + TPakItem(Files[I]).Name, fmCreate);
    DataFile.Position := TPakItem(Files[I]).Start;
    NewFile.CopyFrom(DataFile, TPakItem(Files[I]).Size);
    NewFile.Free;
  end;
end;

constructor TPakFile.Create;
begin
  Files := TObjectList.Create;
  DataFile := nil;
  FileName := '';
end;

destructor TPakFile.Destroy;
begin
  Close;
  FreeAndNil(Files);
  inherited Destroy;
end;

end.