source: trunk/Packages/Kernel/Kernel.KernelAPI.pas@ 68

unit Kernel.KernelAPI;

interface

uses
  Classes, SysUtils, Kernel.API, Kernel.Core, Kernel.Graphics, Kernel.IPC;

type
  TKernelApi = class(TSystemApi)
    Kernel: TKernel;
    function Call(Command: TApiCommand; Data: Pointer): Pointer; override;
    procedure WriteText(Text: string); override;
    procedure DrawText(CanvasId: Integer; P: TPoint; Text: string; Color: TColor); override;
    procedure DrawLine(CanvasId: Integer; P1, P2: TPoint; Color: TColor); override;
    procedure DrawRect(CanvasId: Integer; Rect: TRectangle; Color: TColor); override;
    procedure DrawFrame(CanvasId: Integer; Rect: TRectangle; Color: TColor); override;
    procedure Sleep(Time: TDateTime); override;
    procedure ReadMessage(Message: TIPCMessage); override;
    function WindowCreate: Integer; override;
    function GetWindowCanvas(WindowId: Integer): Integer; override;
    procedure WindowSetAttr(WindowId: Integer; Bounds: TRectangle; Visible: Boolean); override;
  end;


implementation

uses
  Kernel.Device, Kernel.Screen, Kernel.Scheduler;

{ TKernelApi }

function TKernelApi.Call(Command: TApiCommand; Data: Pointer
  ): Pointer;
begin
  case Command of
    acDrawLine: DrawLine(TDrawLineParams(Data^).CanvasId, TDrawLineParams(Data^).P1,
      TDrawLineParams(Data^).P2, TDrawLineParams(Data^).Color);
    acDrawRect: DrawRect(TDrawRectParams(Data^).CanvasId, TDrawRectParams(Data^).Rect,
      TDrawRectParams(Data^).Color);
    acDrawFrame: DrawFrame(TDrawRectParams(Data^).CanvasId, TDrawRectParams(Data^).Rect,
      TDrawRectParams(Data^).Color);
    acDrawText: DrawText(TDrawTextParams(Data^).CanvasId, TDrawTextParams(Data^).P,
      TDrawTextParams(Data^).Text, TDrawTextParams(Data^).Color);
    acSleep: Sleep(TDateTime(Data^));
    acWindowCreate: Result := Pointer(WindowCreate);
    acWindowSetAttr: WindowSetAttr(TWindowSetAttrParams(Data^).WindowId,
      TWindowSetAttrParams(Data^).Bounds, TWindowSetAttrParams(Data^).Visible);
    acWriteText: WriteText(string(Data));
    acReadMessage: ReadMessage(Data);
    acGetWindowCanvas: Result := Pointer(GetWindowCanvas(Integer(Data)));
  end;
end;

procedure TKernelApi.WriteText(Text: string);
var
  Device: TDeviceSerial;
begin
  Device := TDeviceSerial(TKernel(Kernel).Devices.FindByName('Serial0'));
  if Assigned(Device) then begin
    Device.WriteText(Text);
  end else raise Exception.Create('Device Serial0 not found');
end;

procedure TKernelApi.DrawText(CanvasId: Integer; P: TPoint; Text: string; Color: TColor);
var
  Screen: TScreen;
  Canvas: TCanvas;
begin
  Canvas := TKernel(Kernel).Desktop.FindCanvasById(CanvasId);
  if Assigned(Canvas) then begin
    Canvas.DrawText(P, Text, Color);
  end;
end;

procedure TKernelApi.DrawLine(CanvasId: Integer; P1, P2: TPoint; Color: TColor);
var
  Screen: TScreen;
  Canvas: TCanvas;
begin
  Canvas := TKernel(Kernel).Desktop.FindCanvasById(CanvasId);
  if Assigned(Canvas) then begin
    Canvas.DrawLine(P1.Add(Canvas.Position), P2.Add(Canvas.Position), Color);
  end;
end;

procedure TKernelApi.DrawRect(CanvasId: Integer; Rect: TRectangle; Color: TColor);
var
  Canvas: TCanvas;
begin
  Canvas := TKernel(Kernel).Desktop.FindCanvasById(CanvasId);
  if Assigned(Canvas) then begin
    Canvas.DrawRect(Rect, Color);
  end;
end;

procedure TKernelApi.DrawFrame(CanvasId: Integer; Rect: TRectangle;
  Color: TColor);
var
  Canvas: TCanvas;
begin
  Canvas := TKernel(Kernel).Desktop.FindCanvasById(CanvasId);
  if Assigned(Canvas) then begin
    Canvas.DrawFrame(Rect, Color);
  end;
end;

procedure TKernelApi.Sleep(Time: TDateTime);
var
  Task: TTask;
begin
  Task := TKernel(Kernel).Scheduler.GetCurrentTask;
  Task.Sleep(Time);
end;

procedure TKernelApi.ReadMessage(Message: TIPCMessage);
var
  Task: TTask;
begin
  Task := TKernel(Kernel).Scheduler.GetCurrentTask;
  while Task.Messages.List.Count = 0 do Task.WaitForMessage;
end;

function TKernelApi.WindowCreate: Integer;
var
  Window: TWindow;
begin
  Window := TKernel(Kernel).Desktop.CreateWindow;
  Window.Desktop := TKernel(Kernel).Desktop;
  Result := Window.Id;
end;

function TKernelApi.GetWindowCanvas(WindowId: Integer): Integer;
var
  Window: TWindow;
  Canvas: TCanvas;
begin
  Window := TWindow(TKernel(Kernel).Desktop.FindObjectById(WindowId));
  if Assigned(Window) then begin
    Canvas := Window.Canvas;
    Result := Canvas.Id;
  end else Result := -1;
end;

procedure TKernelApi.WindowSetAttr(WindowId: Integer; Bounds: TRectangle; Visible: Boolean);
var
  Window: TWindow;
begin
  Window := TWindow(TKernel(Kernel).Desktop.FindObjectById(WindowId));
  if Assigned(Window) then begin
    Window.Bounds := Bounds;
    Window.Canvas.Position := Bounds.Position;
    Window.Visible := Visible;
    Window.Desktop.Paint;
  end;
end;


end.