source: branches/topdown/OsSystem.pas

unit OsSystem;

interface

uses
  Classes, SysUtils, Forms, Generics.Collections;

type
  TSystem = class;
  TFormTask = class;
  TFormTaskClass = class of TFormTask;

  { TApp }

  TApp = class
    Name: string;
    FormClass: TFormTaskClass;
  end;

  { TApps }

  TApps = class(TObjectList<TApp>)
    function AddNew(Name: string; FormClass: TFormTaskClass): TApp;
  end;

  { TTask }

  TTask = class
    Form: TFormTask;
    Terminated: Boolean;
    destructor Destroy; override;
  end;

  { TFormTask }

  TFormTask = class(TForm)
    Task: TTask;
    procedure Terminate;
  end;

  { TTasks }

  TTasks = class(TObjectList<TTask>)
  private
    FOnChange: TNotifyEvent;
  public
    function AddNew(Form: TFormTask): TTask;
    function Search(Form: TFormTask): TTask;
    procedure StartTask(FormClass: TFormTaskClass);
    procedure DoOnChange;
    property OnChange: TNotifyEvent read FOnChange write FOnChange;
  end;

  { TSystem }

  TSystem = class
    Apps: TApps;
    Tasks: TTasks;
    ScreenForm: TForm;
    constructor Create;
    destructor Destroy; override;
    procedure ShutDown;
    procedure Reboot;
  end;

var
  BaseSystem: TSystem;


implementation

{ TTask }

destructor TTask.Destroy;
begin
  Form.Free;
  inherited;
end;

{ TFormTask }

procedure TFormTask.Terminate;
begin
  Task.Terminated := True;
  Visible := False;
  BaseSystem.Tasks.DoOnChange;
end;

{ TTasks }

function TTasks.AddNew(Form: TFormTask): TTask;
begin
  Result := TTask.Create;
  Result.Form := Form;
  Add(Result);
end;

function TTasks.Search(Form: TFormTask): TTask;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and (Items[I].Form <> Form) do Inc(I);
  if I < Count then Result := Items[I]
    else Result := nil;
end;

procedure TTasks.StartTask(FormClass: TFormTaskClass);
var
  Form: TFormTask;
  Task: TTask;
begin
  Form := FormClass.Create(nil);
  Task := AddNew(Form);
  Form.Task := Task;
  //Form.Parent := BaseSystem.ScreenForm;
  Form.Show;
  DoOnChange;
end;

procedure TTasks.DoOnChange;
begin
  if Assigned(FOnChange) then FOnChange(Self);
end;

{ TApps }

function TApps.AddNew(Name: string; FormClass: TFormTaskClass): TApp;
begin
  Result := TApp.Create;
  Result.Name := Name;
  Result.FormClass := FormClass;
  Add(Result);
end;

{ TSystem }

constructor TSystem.Create;
begin
  Apps := TApps.Create;
  Tasks := TTasks.Create;
end;

destructor TSystem.Destroy;
begin
  Tasks.Free;
  Apps.Free;
  inherited;
end;

procedure TSystem.ShutDown;
begin
  Application.Terminate;
end;

procedure TSystem.Reboot;
begin
  Tasks.Clear;
  Tasks.DoOnChange;
end;

initialization

BaseSystem := TSystem.Create;

finalization

FreeAndNil(BaseSystem);

end.