source: branches/simple/Forms/FormDevices.pas

unit FormDevices;

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ComCtrls, ExtCtrls,
  Machine, Device;

type

  { TFormDevices }

  TFormDevices = class(TForm)
    TreeView1: TTreeView;
    procedure FormShow(Sender: TObject);
    procedure TreeView1DblClick(Sender: TObject);
  public
    Devices: TDevices;
    procedure ReloadDevices;
  end;


implementation

{$R *.lfm}

uses
  FormConsole, FormScreen, FormStorage, FormDevice;

const
  DeviceClassFormClasses: array[TDeviceClass] of TFormDeviceClass = (
    nil, nil, nil, TFormStorage, TFormScreen, TFormConsole, nil);

{ TFormDevices }

procedure TFormDevices.FormShow(Sender: TObject);
begin
  ReloadDevices;
end;

procedure TFormDevices.TreeView1DblClick(Sender: TObject);
var
  FormClass: TFormDeviceClass;
  Device: TDevice;
begin
  if Assigned(TreeView1.Selected) then begin
    if Assigned(TreeView1.Selected.Data) and (TObject(TreeView1.Selected.Data) is TDevice) then begin
      Device := TDevice(TreeView1.Selected.Data);
      if not Assigned(Device.Form) then begin
        FormClass := DeviceClassFormClasses[Device.DeviceClass];
        if Assigned(FormClass) then begin
          Device.Form := FormClass.Create(nil);
          Device.Form.Device := Device;
          Device.Form.Show;
        end;
      end
    end;
  end;
end;

procedure TFormDevices.ReloadDevices;
var
  I: Integer;
  GroupNode: TTreeNode;
  Node: TTreeNode;
  DeviceClasses: TDeviceClassSet;
  DeviceClass: TDeviceClass;
  ClassDevices: TDevices;
begin
  with TreeView1 do
  try
    BeginUpdate;
    Items.Clear;
    Items.AddChild(nil, 'Devices');
    DeviceClasses := Devices.GetClasses;
    for DeviceClass := Low(TDeviceClass) to High(TDeviceClass) do
    if DeviceClass in DeviceClasses then begin
      GroupNode := Items.AddChild(TopItem, DeviceClassText[DeviceClass]);
      ClassDevices := Devices.GetDevicesByClass(DeviceClass);
      for I := 0 to ClassDevices.Count - 1 do begin
        Node := Items.AddChild(GroupNode, ClassDevices[I].Name);
        Node.Data := ClassDevices[I];
      end;
      ClassDevices.Free;
    end;
    TopItem.Expand(True);
  finally
    EndUpdate;
  end;
end;

end.