source: branches/simple/Assembler.pas

unit Assembler;

interface

uses
  Classes, SysUtils, Instructions, Cpu, Generics.Collections,
  Memory, Message, Parser, Channel;

type
  { TLabelRef }

  TLabelRef = record
    LabelName: string;
    RefPos: QWord;
    TextPos: TPoint;
    BitWidth: TBitWidth;
    class function Create(LabelName: string; RefPos: Integer): TLabelRef; static;
  end;

  { TAssembler }

  TAssembler = class
  private
    FOnError: TErrorEvent;
    Parser: TParser;
    function ParseVar: Boolean;
    function ParseDb: Boolean;
    function ParseOrg: Boolean;
    function ParseInstruction: Boolean;
    function ParseLabel: Boolean;
    procedure UpdateLabelRefs;
    procedure ParseNumParam(Token: TToken; DataWidth: TBitWidth);
  public
    AddressWidth: TBitWidth;
    InstructionSet: TInstructionSet;
    Memory: TMemory64;
    Labels: TDictionary<string, QWord>;
    LabelRefs: TList<TLabelRef>;
    Variables: TDictionary<string, QWord>;
    Messages: TMessages;
    procedure Error(Text: string; Pos: TPoint);
    procedure Compile(Source: string);
    procedure LoadFromFile(FileName: string);
    function ParseStr(var Text: string; Separator: string): string;
    constructor Create;
    destructor Destroy; override;
    property OnError: TErrorEvent read FOnError write FOnError;
  end;


implementation

{ TLabelRef }

class function TLabelRef.Create(LabelName: string; RefPos: Integer): TLabelRef;
begin
  Result.LabelName := LabelName;
  Result.RefPos := RefPos;
end;

{ TAssembler }

procedure TAssembler.UpdateLabelRefs;
var
  I: Integer;
  Addr: QWord;
begin
  for I := 0 to LabelRefs.Count - 1 do begin
    if Labels.TryGetValue(LabelRefs[I].LabelName, Addr) then begin
      case AddressWidth of
        bw8: Memory.Write8(LabelRefs[I].RefPos, Addr);
        bw16: Memory.Write16(LabelRefs[I].RefPos, Addr);
        bw32: Memory.Write32(LabelRefs[I].RefPos, Addr);
        bw64: Memory.Write64(LabelRefs[I].RefPos, Addr);
      end;
    end else Error('Label ' + LabelRefs[I].LabelName + ' referenced but not defined.', LabelRefs[I].TextPos);
  end;
end;

procedure TAssembler.ParseNumParam(Token: TToken; DataWidth: TBitWidth);
var
  Value: Integer;
  Value8: Byte;
  Value16: Word;
  Value32: DWord;
  Value64: QWord;
begin
  if Token.Kind = tkNumber then begin
    case DataWidth of
      bw8: if TryStrToInt(Token.Value, Value) then Memory.WritePos8(Value);
      bw16: if TryStrToInt(Token.Value, Value) then Memory.WritePos16(Value);
      bw32: if TryStrToDWord(Token.Value, Value32) then Memory.WritePos32(Value32);
      bw64: if TryStrToQWord(Token.Value, Value64) then Memory.WritePos64(Value64);
    end;
  end else
  if Token.Kind = tkIdentifier then begin;
    if Variables.TryGetValue(Token.Value, Value64) then begin
      case DataWidth of
        bw8: Memory.WritePos8(Value64);
        bw16: Memory.WritePos16(Value64);
        bw32: Memory.WritePos32(Value64);
        bw64: Memory.WritePos64(Value64);
      end;
    end else
    if Labels.TryGetValue(Token.Value, Value64) then begin
      case DataWidth of
        bw8: Memory.WritePos8(Value64);
        bw16: Memory.WritePos16(Value64);
        bw32: Memory.WritePos32(Value64);
        bw64: Memory.WritePos64(Value64);
      end;
    end else begin
      LabelRefs.Add(TLabelRef.Create(Token.Value, Memory.Position));
      case DataWidth of
        bw8: Memory.WritePos8(0);
        bw16: Memory.WritePos16(0);
        bw32: Memory.WritePos32(0);
        bw64: Memory.WritePos64(0);
      end;
    end;
  end else Error('Unexpected token ' + Token.Value + '.', Token.Pos);
end;

procedure TAssembler.Error(Text: string; Pos: TPoint);
begin
  Messages.AddMessage(Text, Pos);
  if Assigned(FOnError) then
    FOnError(Text, Pos);
end;

procedure TAssembler.Compile(Source: string);
begin
  Messages.Clear;
  Memory.Size := 0;
  Labels.Clear;
  LabelRefs.Clear;
  Parser.Reset;
  Parser.Source := Source;
  while not Parser.CheckNextKind(tkEof) do begin
    ParseLabel;
    if ParseVar then begin
    end else
    if ParseDb then begin
    end else
    if ParseOrg then begin
    end else
    if ParseInstruction then begin
    end;
    if Parser.CheckNextKind(tkEof) then begin
    end else Parser.Expect(tkEol);
  end;
  Parser.Expect(tkEof);
  UpdateLabelRefs;
  Error('Compilation finished.', Point(0, 0));
end;

function TAssembler.ParseVar: Boolean;
var
  TokenName: TToken;
  TokenValue: TToken;
  Number: QWord;
begin
  Result := False;
  if Parser.CheckNextAndRead(tkIdentifier, 'VAR') then begin
    Result := True;
    while True do begin
      TokenName := Parser.ReadNext;
      if TokenName.Kind = tkIdentifier then begin
        TokenValue := Parser.ReadNext;
        if TokenValue.Kind = tkNumber then begin
          if not Labels.ContainsKey(TokenName.Value) and not Variables.ContainsKey(TokenName.Value) then begin
            if TryStrToQWord(TokenValue.Value, Number) then
              Variables.Add(TokenName.Value, Number)
            else Error('Expected number', TokenValue.Pos);
          end else Error('Duplicate variable name ' + TokenName.Value, TokenName.Pos);
        end else Error('Expected variable value.', TokenValue.Pos);
      end else Error('Expected variable name.', TokenName.Pos);
      if Parser.CheckNextAndRead(tkSpecialSymbol, ',') then begin
        Continue;
      end;
      Break;
    end;
  end;
end;

function TAssembler.ParseDb: Boolean;
var
  Token: TToken;
begin
  Result := False;
  if Parser.CheckNextAndRead(tkIdentifier, 'DB') then begin
    Result := True;
    while True do begin
      Token := Parser.ReadNext;
      if Token.Kind = tkString then begin
        //Memory.WriteString(Token.Value);
      end else
        ParseNumParam(Token, bw8);
      if Parser.CheckNextAndRead(tkSpecialSymbol, ',') then begin
        Continue;
      end;
      Break;
    end;
  end;
end;

function TAssembler.ParseOrg: Boolean;
var
  Token: TToken;
begin
  Result := False;
  if Parser.CheckNextAndRead(tkIdentifier, 'ORG') then begin
    Result := True;
    Token := Parser.ReadNext;
    if Token.Kind = tkNumber then begin
      Memory.Position := StrToInt(Token.Value);
    end else Error('Expected number but ' + Token.Value + ' found.', Token.Pos);
  end;
end;

function TAssembler.ParseInstruction: Boolean;
var
  InstructionInfo: TInstructionInfo;
  I: Integer;
  Token: TToken;
  LastPos: TParserPos;
  Number: Integer;
begin
  Result := False;
  LastPos := Parser.Pos;
  Token := Parser.ReadNext;
  InstructionInfo := InstructionSet.SearchName(Token.Value);
  if Assigned(InstructionInfo) then begin
    Result := True;
    Memory.WritePos8(Integer(InstructionInfo.Instruction));
    for I := 0 to Length(InstructionInfo.Params) - 1 do begin
      if I > 0 then
        Parser.Expect(tkSpecialSymbol, ',');
      if InstructionInfo.Params[I] = ptNumber then begin
        Token := Parser.ReadNext;
        ParseNumParam(Token, AddressWidth);
      end else
      if InstructionInfo.Params[I] = ptNumber8 then begin
        Token := Parser.ReadNext;
        ParseNumParam(Token, bw8);
      end else
      if InstructionInfo.Params[I] = ptNumber16 then begin
        Token := Parser.ReadNext;
        ParseNumParam(Token, bw16);
      end else
      if InstructionInfo.Params[I] = ptNumber32 then begin
        Token := Parser.ReadNext;
        ParseNumParam(Token, bw32);
      end else
      if InstructionInfo.Params[I] = ptNumber64 then begin
        Token := Parser.ReadNext;
        ParseNumParam(Token, bw64);
      end else
      if InstructionInfo.Params[I] = ptReg then begin
        Token := Parser.ReadNext;
        if (Token.Value <> '') and (Token.Value[1] = 'R') then begin
          Token.Value := Copy(Token.Value, 2, MaxInt);
          if TryStrToInt(Token.Value, Number) then
            Memory.WritePos8(Number)
            else Error('Expected numeric register index error', Token.Pos);
        end else Error('Expected register name starting with R character.', Token.Pos);
      end else
      if InstructionInfo.Params[I] = ptRegIndirect then begin
        Parser.Expect(tkSpecialSymbol, '(');
        Token := Parser.ReadNext;
        if (Token.Value <> '') and (Token.Value[1] = 'R') then begin
          Token.Value := Copy(Token.Value, 2, MaxInt);
          if TryStrToInt(Token.Value, Number) then
            Memory.WritePos8(Number)
            else Error('Expected numeric register index error', Token.Pos);
        end else Error('Expected register name starting with R character.', Token.Pos);
        Parser.Expect(tkSpecialSymbol, ')');
      end else
      if InstructionInfo.Params[I] = ptRegIndirectIndex then begin
        Parser.Expect(tkSpecialSymbol, '(');
        Token := Parser.ReadNext;
        if (Token.Value <> '') and (Token.Value[1] = 'R') then begin
          Token.Value := Copy(Token.Value, 2, MaxInt);
          if TryStrToInt(Token.Value, Number) then begin
            Memory.WritePos8(Number);
            Parser.Expect(tkSpecialSymbol, '+');
            Token := Parser.ReadNext;
            ParseNumParam(Token, bw8);
          end else Error('Expected numeric register index error', Token.Pos);
        end else Error('Expected register name starting with R character.', Token.Pos);
        Parser.Expect(tkSpecialSymbol, ')');
      end else
      if InstructionInfo.Params[I] = ptRegIndirectGroup then begin
        Parser.Expect(tkSpecialSymbol, '(');
        Token := Parser.ReadNext;
        if (Token.Value <> '') and (Token.Value[1] = 'R') then begin
          Token.Value := Copy(Token.Value, 2, MaxInt);
          if TryStrToInt(Token.Value, Number) then begin
            Memory.WritePos8(Number);
            Parser.Expect(tkSpecialSymbol, ':');
            Token := Parser.ReadNext;
            if (Token.Value <> '') and (Token.Value[1] = 'R') then begin
              Token.Value := Copy(Token.Value, 2, MaxInt);
              if TryStrToInt(Token.Value, Number) then begin
                Memory.WritePos8(Number);
              end else Error('Expected numeric register index error', Token.Pos);
            end else Error('Expected register name starting with R character.', Token.Pos);
          end else Error('Expected numeric register index error', Token.Pos);
        end else Error('Expected register name starting with R character.', Token.Pos);
        Parser.Expect(tkSpecialSymbol, ')');
      end else
    end;
  end;
  if not Result then Parser.Pos := LastPos;
end;

function TAssembler.ParseLabel: Boolean;
var
  LastPos: TParserPos;
  Token: TToken;
  Addr: QWord;
begin
  Result := False;
  LastPos := Parser.Pos;
  Token := Parser.ReadNext;
  if Parser.CheckNextAndRead(tkSpecialSymbol, ':') then begin
    Result := True;
    if not Labels.TryGetValue(Token.Value, Addr) then begin
      Labels.Add(Token.Value, Memory.Position);
    end else Error('Duplicate label ' + Token.Value + '.', Token.Pos);
  end;
  if not Result then Parser.Pos := LastPos;
end;

procedure TAssembler.LoadFromFile(FileName: string);
var
  Lines: TStringList;
begin
  Lines := TStringList.Create;
  try
    Lines.LoadFromFile(FileName);
    Compile(Lines.Text);
  finally
    Lines.Free;
  end;
end;

function TAssembler.ParseStr(var Text: string; Separator: string): string;
var
  P: Integer;
begin
  P := Pos(Separator, Text);
  if P > 0 then begin
    Result := Trim(Copy(Text, 1, P - 1));
    Text := Trim(Copy(Text, P + 1, MaxInt));
  end else begin
    Result := Trim(Text);
    Text := '';
  end;
end;

constructor TAssembler.Create;
begin
  Parser := TParser.Create;
  Parser.OnError := Error;
  Messages := TMessages.Create;
  Memory := TMemory64.Create;
  InstructionSet := TInstructionSet.Create;
  Labels := TDictionary<string, QWord>.Create;
  LabelRefs := TList<TLabelRef>.Create;
  Variables := TDictionary<string, QWord>.Create;
end;

destructor TAssembler.Destroy;
begin
  FreeAndNil(Variables);
  FreeAndNil(Labels);
  FreeAndNil(LabelRefs);
  FreeAndNil(InstructionSet);
  FreeAndNil(Memory);
  FreeAndNil(Messages);
  FreeAndNil(Parser);
  inherited;
end;

end.