source: branches/overos/FormMain.pas

unit FormMain;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ExtCtrls,
  Types, Os.Window, Os.System, Os.Types, Os.Mouse, Os.Graphics, Os.Controls, Os.Application;

type
  TControlsMouseButton = Controls.TMouseButton;

  { TFormMain }

  TFormMain = class(TForm)
    Image1: TImage;
    Timer1: TTimer;
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure Image1MouseDown(Sender: TObject; Button: TControlsMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Image1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
    procedure Image1MouseUp(Sender: TObject; Button: TControlsMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormResize(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  public
    App: TApplication;
    System: TSystem;
  end;

  { TCanvasScreen }

  TCanvasScreen = class(TCanvas)
    Canvas: Graphics.TCanvas;
    procedure DrawLine(P1, P2: TPosition; Color: TColor); override;
    procedure DrawArea(Rect: TRectangle; Color: TColor); override;
    procedure DrawText(P: TPosition; Color: TColor; Text: string); override;
    function GetTextSize(Text: string): TSize; override;
  end;


var
  FormMain: TFormMain;

implementation

{$R *.lfm}

{ TCanvasScreen }

procedure TCanvasScreen.DrawLine(P1, P2: TPosition; Color: TColor);
begin
  Canvas.Pen.Color := Color;
  Canvas.Pen.Style := psSolid;
  Canvas.Line(P1.Left, P1.Top, P2.Left, P2.Top);
end;

procedure TCanvasScreen.DrawArea(Rect: TRectangle; Color: TColor);
begin
  Canvas.Brush.Color := Color;
  Canvas.Brush.Style := bsSolid;
  Canvas.FillRect(Rect.Position.Left, Rect.Position.Top,
    Rect.Position.Left + Rect.Size.Width,
    Rect.Position.Top + Rect.Size.Height);
end;

procedure TCanvasScreen.DrawText(P: TPosition; Color: TColor; Text: string);
begin
  Canvas.Brush.Style := bsClear;
  Canvas.Font.Color := Color;
  Canvas.TextOut(P.Left, P.Top, Text);
end;

function TCanvasScreen.GetTextSize(Text: string): TSize;
var
  Size: Types.TSize;
begin
  Size := Canvas.TextExtent(Text);
  Result := TSize.Create(Size.cx, Size.cy);
end;

{ TFormMain }

procedure TFormMain.Image1MouseDown(Sender: TObject; Button: TControlsMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  MouseButton: TMouseButton;
begin
  case Button of
    TControlsMouseButton.mbLeft: MouseButton := mbLeft;
    TControlsMouseButton.mbRight: MouseButton := mbRight;
    TControlsMouseButton.mbMiddle: MouseButton := mbMiddle;
  end;
  System.Mouse.ButtonDown(TPosition.Create(X, Y), MouseButton);
end;

procedure TFormMain.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  Timer1.Enabled := False;
  FreeAndNil(App);
  FreeAndNil(System);
end;

procedure TFormMain.Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  //Caption := IntToStr(X) + ',' + IntToStr(Y);
  System.Mouse.Move(TPosition.Create(X, Y));
end;

procedure TFormMain.Image1MouseUp(Sender: TObject; Button: TControlsMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  MouseButton: TMouseButton;
begin
  case Button of
    TControlsMouseButton.mbLeft: MouseButton := mbLeft;
    TControlsMouseButton.mbRight: MouseButton := mbRight;
    TControlsMouseButton.mbMiddle: MouseButton := mbMiddle;
  end;
  System.Mouse.ButtonUp(TPosition.Create(X, Y), MouseButton);
end;

procedure TFormMain.FormResize(Sender: TObject);
begin
  if Assigned(System) then begin
    Image1.Picture.Bitmap.SetSize(Image1.Width, Image1.Height);
    System.Screen.Size := TSize.Create(Image1.Width, Image1.Height);
    System.Screen.Paint;
  end;
end;

procedure TFormMain.FormShow(Sender: TObject);
var
  Window: TWindow;
  Button: TButton;
begin
  System := TSystem.Create;
  System.Screen.Canvas.Free;
  System.Screen.Canvas := TCanvasScreen.Create;
  TCanvasScreen(System.Screen.Canvas).Canvas := Image1.Canvas;
  System.Screen.Size := TSize.Create(Width, Height);

  App := TApplication.Create;

  Window := System.Screen.CreateWindow('Test');
  Window.Application := App;

  Window := System.Screen.CreateWindow('Commander');
  Window.Position := TPosition.Create(100, 50);
  Window.Size := TSize.Create(400, 200);
  Window.Application := App;
  Button := TButton.Create;
  Button.Rectangle := TRectangle.Create(TPosition.Create(10, 50), TSize.Create(100, 32));
  Button.ParentControl := Window;
  Button.Title := 'Click';
  Button.Visible := True;

  Window := System.Screen.CreateWindow('Calculator');
  Window.Application := App;
  Window.Position := TPosition.Create(200, 100);
  Window.Size := TSize.Create(300, 200);

  System.Screen.Paint;
end;

procedure TFormMain.Timer1Timer(Sender: TObject);
begin
  App.ProcessMessages;
end;

end.