source: branches/Independent/SystemApi.pas

unit SystemApi;

interface

uses
  Classes, SysUtils, Api, Os, DateUtils;

type
  { TSystemApi }

  TSystemApi = class(TApi)
  private
    FName: string;
    FText: string;
    procedure WriteLineSync;
    procedure RunAppSync;
  public
    App: TRunningApp;
    System: TSystem;
    procedure WriteLine(Text: string); override;
    procedure RunApp(Name: string); override;
    procedure Sleep(Time: TDateTime); override;
    function CreateWindow: THandle; override;
    procedure SetWindowName(Handle: THandle; Name: string); override;
    procedure SetWindowRect(Handle: THandle; Rect: TRect); override;
    procedure SetWindowVisible(Handle: THandle; Visible: Boolean); override;
    function GetMousePosition: TPoint; override;
  end;


implementation

{ TSystemApi }

procedure TSystemApi.WriteLineSync;
begin
  System.Console.Write(App.App.Name + ': ' + FText);
end;

procedure TSystemApi.RunAppSync;
begin
  System.RunApp(FName);
end;

procedure TSystemApi.WriteLine(Text: string);
begin
  FText := Text;
  TThread.Synchronize(App.AppThread, WriteLineSync);
end;

procedure TSystemApi.RunApp(Name: string);
begin
  FName := Name;
  TThread.Synchronize(App.AppThread, RunAppSync);
end;

procedure TSystemApi.Sleep(Time: TDateTime);
begin
  App.AppThread.Sleep(Round(Time / OneMillisecond));
end;

function TSystemApi.CreateWindow: THandle;
var
  Window: TWindow;
begin
  Window := System.Windows.AddNew;
  Window.Handle := System.Handles.AddNew;
  Result := Window.Handle;
end;

procedure TSystemApi.SetWindowName(Handle: THandle; Name: string);
var
  Window: TWindow;
begin
  Window := System.Windows.SearchByHandle(Handle);
  if Assigned(Window) then begin
    Window.Name := Name;
    System.Redraw;
  end;
end;

procedure TSystemApi.SetWindowRect(Handle: THandle; Rect: TRect);
var
  Window: TWindow;
begin
  Window := System.Windows.SearchByHandle(Handle);
  if Assigned(Window) then begin
    Window.Rect := Rect;
    System.Redraw;
  end;
end;

procedure TSystemApi.SetWindowVisible(Handle: THandle; Visible: Boolean);
var
  Window: TWindow;
begin
  Window := System.Windows.SearchByHandle(Handle);
  if Assigned(Window) then begin
    Window.Visible := Visible;
    System.Redraw;
  end;
end;

function TSystemApi.GetMousePosition: TPoint;
begin
  Result := System.Mouse.GetPosition;
end;

end.