source: branches/Independent/Os.pas

unit Os;

interface

uses
  Classes, SysUtils, Generics.Collections, DateUtils, Api, Console, FileSystem;

type
  TSystem = class;

  TRunningApp = class;

  { TAppThread }

  TAppThread = class(TThread)
    App: TRunningApp;
    procedure Execute; override;
  end;

  { TRunningApp }

  TRunningApp = class
  private
    FApp: TApp;
    procedure SetApp(AValue: TApp);
  public
    Context: TAppContext;
    AppThread: TAppThread;
    procedure Run;
    constructor Create;
    destructor Destroy; override;
    property App: TApp read FApp write SetApp;
  end;

  { TRunningApps }

  TRunningApps = class(TObjectList<TRunningApp>)
    function AddNew(App: TApp; System: TSystem): TRunningApp;
  end;

  { TWindow }

  TWindow = class
    Handle: THandle;
    Name: string;
    Visible: Boolean;
    Rect: TRect;
  end;

  { TWindows }

  TWindows = class(TObjectList<TWindow>)
    function AddNew: TWindow;
    function SearchByHandle(Handle: THandle): TWindow;
  end;

  { TSystem }

  TSystem = class
  private
    FOnDraw: TNotifyEvent;
  public
    Console: TConsole;
    FileSystem: TFileSystem;
    Apps: TApps;
    RunningApps: TRunningApps;
    Windows: TWindows;
    Handles: THandles;
    procedure Redraw;
    procedure RunApp(Name: string);
    procedure Start;
    constructor Create;
    destructor Destroy; override;
    property OnDraw: TNotifyEvent read FOnDraw write FOnDraw;
  end;


implementation

uses
  AppCode, AppTest, SystemApi;

{ TAppThread }

procedure TAppThread.Execute;
begin
  App.App.Run(App.Context);
end;

{ TRunningApp }

procedure TRunningApp.SetApp(AValue: TApp);
begin
  if FApp = AValue then Exit;
  FApp := AValue;
end;

procedure TRunningApp.Run;
begin
  AppThread.Start;
end;

constructor TRunningApp.Create;
begin
  Context := TAppContext.Create;
  AppThread := TAppThread.Create(True);
  AppThread.App := Self;
end;

destructor TRunningApp.Destroy;
begin
  AppThread.Terminate;
  AppThread.WaitFor;
  FreeAndNil(AppThread);
  FreeAndNil(Context);
  inherited;
end;

{ TRunningApps }

function TRunningApps.AddNew(App: TApp; System: TSystem): TRunningApp;
var
  SystemApi: TSystemApi;
begin
  Result := TRunningApp.Create;
  SystemApi := TSystemApi.Create;
  SystemApi.App := Result;
  SystemApi.System := System;
  Result.Context.Api := SystemApi;
  Result.App := App;
  Add(Result);
end;

{ TWindows }

function TWindows.AddNew: TWindow;
begin
  Result := TWindow.Create;
  Add(Result);
end;

function TWindows.SearchByHandle(Handle: THandle): TWindow;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and (Items[I].Handle <> Handle) do Inc(I);
  if I < Count then Result := Items[I]
    else Result := nil;
end;

{ TSystem }

procedure TSystem.Redraw;
begin
  if Assigned(FOnDraw) then FOnDraw(Self);
end;

procedure TSystem.RunApp(Name: string);
var
  App: TApp;
  RunningApp: TRunningApp;
begin
  App := Apps.SearchByName(Name);
  if Assigned(App) then begin
    RunningApp := RunningApps.AddNew(App, Self);
    RunningApp.Run;
  end else raise Exception.Create('App ' + Name + ' not found.');
end;

procedure TSystem.Start;
var
  AppCode: TAppCode;
begin
  Apps.AddNew(TAppTest);
  AppCode := TAppCode(Apps.AddNew(TAppCode));
  AppCode.Code.Text := FileSystem.LoadFile('Code.exe');

  RunApp('Test');
  RunApp('Test');
  RunApp('Code');
end;

constructor TSystem.Create;
begin
  Handles := THandles.Create;
  Windows := TWindows.Create;
  Console := TConsole.Create;
  FileSystem := TFileSystem.Create;
  RunningApps := TRunningApps.Create;
  Apps := TApps.Create;
end;

destructor TSystem.Destroy;
begin
  FreeAndNil(Apps);
  FreeAndNil(RunningApps);
  FreeAndNil(Console);
  FreeAndNil(FileSystem);
  FreeAndNil(Windows);
  FreeAndNil(Handles);
  inherited;
end;

end.