source: branches/ByteArray/Disassembler.pas

unit Disassembler;

interface

uses
  Classes, SysUtils, Cpu, Instructions, StrUtils, Memory, BigInt;

type

  { TDisassembler }

  TDisassembler = class
  private
    InstText: string;
    InstBytes: string;
    InstDataWidth: TBigIntSize;
    InstAddressWidth: TBigIntSize;
    procedure DisassembleData;
    procedure DisassembleAddress;
    procedure DisassembleRegister;
    procedure DisassembleRegisterIndirect;
    procedure DisassembleRegisterIndirectIndex;
    procedure DisassembleDataWidth;
    procedure DisassembleAddressWidth;
  public
    InstructionSet: TInstructionInfos;
    Memory: TMemory;
    DataWidth: TBigIntSize;
    AddressWidth: TBigIntSize;
    procedure Disassemble(Lines: TStrings);
    procedure SaveToFile(FileName: string);
    constructor Create;
    destructor Destroy; override;
  end;


implementation

procedure TDisassembler.DisassembleData;
var
  Text: string;
begin
  Text := IntToHex(Memory.ReadPos(InstDataWidth));
  if not (Copy(Text, 1, 1)[1] in ['0'..'9']) then Text := '0' + Text;
  InstText := InstText + Text + 'h';
end;

procedure TDisassembler.DisassembleAddress;
var
  Text: string;
begin
  Text := IntToHex(Memory.ReadPos(InstAddressWidth));
  if not (Copy(Text, 1, 1)[1] in ['0'..'9']) then Text := '0' + Text;
  InstText := InstText + Text + 'h';
end;

procedure TDisassembler.DisassembleRegister;
begin
  InstText := InstText + 'R' + IntToStr(Byte(Memory.ReadPos(1)));
end;

procedure TDisassembler.DisassembleRegisterIndirect;
begin
  InstText := InstText + '(R' + IntToStr(Byte(Memory.ReadPos(1))) + ')';
end;

procedure TDisassembler.DisassembleRegisterIndirectIndex;
begin
  InstText := InstText + '(R' + IntToStr(Byte(Memory.ReadPos(1))) +
    ' + ';
  DisassembleAddress;
  InstText := InstText + ')';
end;

procedure TDisassembler.DisassembleDataWidth;
begin
  InstDataWidth := Memory.ReadPos(1);
  InstText := InstText + 'D' + IntToStr(InstDataWidth);
end;

procedure TDisassembler.DisassembleAddressWidth;
begin
  InstAddressWidth := Memory.ReadPos(1);
  InstText := InstText + 'A' + IntToStr(InstAddressWidth);
end;

procedure TDisassembler.Disassemble(Lines: TStrings);
var
  J: Integer;
  Value: TBigInt;
  Instruction: TInstruction;
  InstructionInfo: TInstructionInfo;
  Line: string;
  MemoryPos: Integer;
  InstructionByteSize: Integer;
  I: Integer;
begin
  Memory.Position := 0;
  while Memory.Position < Memory.Size do begin
    Line := IntToHex(Memory.Position, 8) + ' ';
    MemoryPos := Memory.Position;
    Value := Memory.ReadPos(1);
    InstBytes := IntToHex(Value, 2) + ' ';
    InstText := '';
    InstAddressWidth := AddressWidth;
    InstDataWidth := DataWidth;
    if (Value >= 0) and (Value <= Integer(High(TInstruction))) then begin
      Instruction := TInstruction(Int64(Value));
      InstructionInfo := InstructionSet.SearchInstruction(Instruction);
      if Assigned(InstructionInfo) then begin
        InstText := InstructionInfo.Name;
        for J := 0 to Length(InstructionInfo.Params) - 1 do begin
          if J > 0 then
            InstText := InstText + ', ' else
            InstText := InstText + ' ';
          case InstructionInfo.Params[J] of
            ptData: DisassembleData;
            ptAddress: DisassembleAddress;
            ptReg: DisassembleRegister;
            ptRegIndirect: DisassembleRegisterIndirect;
            ptRegIndirectIndex: DisassembleRegisterIndirectIndex;
            ptDataWidth: DisassembleDataWidth;
            ptAddressWidth: DisassembleAddressWidth;
          end;
        end;
      end;
    end;

    // Instruction bytes to hex string
    InstructionByteSize := Memory.Position - MemoryPos;
    Memory.Position := MemoryPos;
    InstBytes := '';
    for I := 0 to InstructionByteSize - 1 do
      InstBytes := InstBytes + IntToHex(Memory.ReadPos(1), 2) + ' ';
    InstBytes := InstBytes + DupeString(' ', 13 - Length(InstBytes));

    Line := Line + InstBytes + InstText;
    Lines.Add(Line);
  end;
end;

procedure TDisassembler.SaveToFile(FileName: string);
var
  Lines: TStringList;
begin
  Lines := TStringList.Create;
  Disassemble(Lines);
  Lines.SaveToFile(FileName);
  Lines.Free;
end;

constructor TDisassembler.Create;
begin
  InstructionSet := TInstructionInfos.Create;
  InstructionSet.Init;
  DataWidth := 1;
  AddressWidth := 1;
end;

destructor TDisassembler.Destroy;
begin
  FreeAndNil(InstructionSet);
  inherited;
end;

end.