source: branches/ByteArray/Core.pas

unit Core;

interface

uses
  Classes, SysUtils, Machine, ActnList, Forms, Common.PersistentForm,
  Common.ApplicationInfo, Common.RegistryEx, Common.Translator, Common.Theme,
  FormConsole, FormScreen, FormSourceEditor, FormMemory, FormDisassembler,
  FormStorage, FormDebugger;

type

  { TCore }

  TCore = class(TDataModule)
    AAbout: TAction;
    AConsole: TAction;
    ActionList1: TActionList;
    ADebugger: TAction;
    ADevices: TAction;
    ADisassembler: TAction;
    AExit: TAction;
    AFullscreen: TAction;
    AMemory: TAction;
    ApplicationInfo1: TApplicationInfo;
    AScreen: TAction;
    ASettings: TAction;
    ASourceEditor: TAction;
    AStorage: TAction;
    PersistentForm1: TPersistentForm;
    ThemeManager1: TThemeManager;
    Translator1: TTranslator;
    procedure AAboutExecute(Sender: TObject);
    procedure AConsoleExecute(Sender: TObject);
    procedure ADebuggerExecute(Sender: TObject);
    procedure ADisassemblerExecute(Sender: TObject);
    procedure AExitExecute(Sender: TObject);
    procedure AFullscreenExecute(Sender: TObject);
    procedure AMemoryExecute(Sender: TObject);
    procedure AScreenExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure ASourceEditorExecute(Sender: TObject);
    procedure AStorageExecute(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    procedure InitMachine;
    procedure LoadConfig;
    procedure SaveConfig;
  public
    MainForm: TForm;
    FormScreen: TFormScreen;
    FormConsole: TFormConsole;
    FormMemory: TFormMemory;
    FormSourceEditor: TFormSourceEditor;
    FormDisassembler: TFormDisassembler;
    FormStorage: TFormStorage;
    FormDebugger: TFormDebugger;
    StartUpForm: string;
    AutoStartMachine: Boolean;
    Machine: TMachine;
  end;

var
  Core: TCore;


implementation

{$R *.lfm}

uses
  BigInt, Cpu, Common.FormEx, FormSettings, Common.FormAbout;

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  Machine := TMachine.Create;
  //InitMachine;
  LoadConfig;

  TFormEx.Translator := Translator1;
  TFormEx.ThemeManager := ThemeManager1;
  TFormEx.PersistentForm := PersistentForm1;

  if StartUpForm = 'Screen' then begin
    AScreen.Execute;
  end;
  if StartUpForm = 'Source editor' then begin
    ASourceEditor.Execute;
  end;
  if StartUpForm = 'Debugger' then begin
    ADebugger.Execute;
  end;
  if AutoStartMachine then
    Machine.PowerOn;
end;

procedure TCore.AExitExecute(Sender: TObject);
begin
  Application.Terminate;
end;

procedure TCore.ADebuggerExecute(Sender: TObject);
begin
  if not Assigned(FormDebugger) then begin
    FormDebugger := TFormDebugger.Create(nil);
  end;
  FormDebugger.Show;
end;

procedure TCore.ADisassemblerExecute(Sender: TObject);
begin
  if not Assigned(FormDisassembler) then begin
    FormDisassembler := TFormDisassembler.Create(nil);
    if not Assigned(MainForm) then MainForm := FormDisassembler;
  end;
  FormDisassembler.Disassembler.Memory := Machine.Memory;
  FormDisassembler.Disassembler.DataWidth := Machine.Cpu.DataWidth;
  FormDisassembler.Disassembler.AddressWidth := Machine.Cpu.AddressWidth;
  FormDisassembler.Show;
end;

procedure TCore.AConsoleExecute(Sender: TObject);
begin
  if not Assigned(FormConsole) then begin
    FormConsole := TFormConsole.Create(nil);
    Machine.Serial.OnWrite := FormConsole.ConsoleWrite;
  end;
  FormConsole.Show;
end;

procedure TCore.AAboutExecute(Sender: TObject);
var
  FormAbout: TFormAbout;
begin
  FormAbout := TFormAbout.Create(nil);
  try
    FormAbout.ApplicationInfo := ApplicationInfo1;
    FormAbout.ShowModal;
  finally
    FreeAndNil(FormAbout);
  end;
end;

procedure TCore.AFullscreenExecute(Sender: TObject);
begin
  PersistentForm1.SetFullScreen(not PersistentForm1.FormFullScreen);
end;

procedure TCore.AMemoryExecute(Sender: TObject);
begin
  if not Assigned(FormMemory) then begin
    FormMemory := TFormMemory.Create(nil);
    FormMemory.Memory := Machine.Memory;
  end;
  FormMemory.Show;
end;

procedure TCore.AScreenExecute(Sender: TObject);
begin
  if not Assigned(FormScreen) then begin
    FormScreen := TFormScreen.Create(nil);
    if not Assigned(MainForm) then MainForm := FormScreen;
    FormScreen.FrameBuffer := Machine.FrameBuffer;
    Machine.FrameBuffer.OnChange := FormScreen.ScreenChange;
  end;
  FormScreen.Show;
end;

procedure TCore.ASettingsExecute(Sender: TObject);
var
  FormSettings: TFormSettings;
begin
  FormSettings := TFormSettings.Create(nil);
  try
    FormSettings.ShowModal;
  finally
    FormSettings.Free;
  end;
end;

procedure TCore.ASourceEditorExecute(Sender: TObject);
begin
  if not Assigned(FormSourceEditor) then begin
    FormSourceEditor := TFormSourceEditor.Create(nil);
    if not Assigned(MainForm) then MainForm := FormSourceEditor;
    FormSourceEditor.Machine := Machine;
  end;
  FormSourceEditor.Show;
end;

procedure TCore.AStorageExecute(Sender: TObject);
begin
  if not Assigned(FormStorage) then begin
    FormStorage := TFormStorage.Create(nil);
    FormStorage.Storage := Machine.Storage;
  end;
  FormStorage.Show;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  SaveConfig;
  if Assigned(FormSourceEditor) then FreeAndNil(FormSourceEditor);
  if Assigned(FormScreen) then FreeAndNil(FormScreen);
  if Assigned(FormConsole) then FreeAndNil(FormConsole);
  if Assigned(FormMemory) then FreeAndNil(FormMemory);
  if Assigned(FormDisassembler) then FreeAndNil(FormDisassembler);
  if Assigned(FormStorage) then FreeAndNil(FormStorage);
  if Assigned(FormDebugger) then FreeAndNil(FormDebugger);

  FreeAndNil(Machine);
end;

procedure TCore.InitMachine;
var
  Loop: TBigInt;
begin
  with Machine.Cpu do begin
    Reset;

    // LD A, 'A'
    WriteInstruction(inLoadConst);
    WriteRegister(0);
    Write(DataWidth, Ord('A'));

    // LD B, 8
    WriteInstruction(inLoadConst);
    WriteRegister(1);
    Write(DataWidth, Machine.Serial.BaseAddress);

    // OUT (B), A
    WriteInstruction(inOutput);
    WriteRegister(1);
    WriteRegister(0);

    // LD B,
    WriteInstruction(inLoadConst);
    WriteRegister(1);
    Write(DataWidth, Machine.FrameBuffer.BaseAddress);

    WriteInstruction(inLoadConst);
    WriteRegister(2);
    Write(DataWidth, 10);

    Loop := PC;

    WriteInstruction(inOutput);
    WriteRegister(1);
    WriteRegister(0);

    WriteInstruction(inInc);
    WriteRegister(0);

    WriteInstruction(inDec);
    WriteRegister(2);

    WriteInstruction(inJumpNotZero);
    WriteRegister(2);
    Write(AddressWidth, Loop);

    WriteInstruction(inHalt);
  end;
end;

procedure TCore.LoadConfig;
begin
  PersistentForm1.RegistryContext := ApplicationInfo1.GetRegistryContext;

  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;
    if ValueExists('LanguageCode') then
      Translator1.Language := Translator1.Languages.SearchByCode(ReadStringWithDefault('LanguageCode', ''))
      else Translator1.Language := Translator1.Languages.SearchByCode('');
    if ValueExists('Theme') then
      ThemeManager1.Theme := ThemeManager1.Themes.FindByName(ReadStringWithDefault('Theme', 'System'))
      else ThemeManager1.Theme := ThemeManager1.Themes.FindByName('System');
    StartUpForm := ReadStringWithDefault('StartUpForm', 'Screen');
    AutoStartMachine := ReadBoolWithDefault('AutoStartMachine', True);
  finally
    Free;
  end;
end;

procedure TCore.SaveConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;
    if Assigned(Translator1.Language) and (Translator1.Language.Code <> '') then
      WriteString('LanguageCode', Translator1.Language.Code)
      else DeleteValue('LanguageCode');
    if Assigned(ThemeManager1.Theme) and (ThemeManager1.Theme.Name <> '') then
      WriteString('Theme', ThemeManager1.Theme.Name)
      else DeleteValue('Theme');
    WriteString('StartUpForm', StartUpForm);
    WriteBool('AutoStartMachine', AutoStartMachine);
  finally
    Free;
  end;
end;

end.