source: trunk/UExternalTool.pas

unit UExternalTool;

{$mode delphi}

interface

uses
  Classes, SysUtils, process;

var
  ClearToolPath: string;
  OMakePath: string;
  SubstPath: string;
  RationalRosePath: string;
  SuperTracerPath: string;
  BeyondComparePath: string;

const
  SVNPath: string = 'c:\Program Files\TortoiseSVN\bin\svn.exe';
  SVNAdminPath: string = 'c:\Program Files\TortoiseSVN\bin\svnadmin.exe';

function ExecuteProcessOut(Executable: string; Parameters: array of string;
  CurrentDir: string = ''): string;
function ClearTool(Parameters: array of string; CurrentDir: string = ''): string;
procedure ExecuteNoWait(AExecutable: string; Params: array of string;
  Maximized: Boolean = false; CurrentDir: string = '');
function SVN(Parameters: array of string; CurrentDir: string = ''): string;


implementation

function ExecuteProcessOut(Executable: string; Parameters: array of string;
  CurrentDir: string = ''): string;
var
  Process: TProcess;
  I: Integer;
  Cmd: string;
  Buffer: string;
  Count: Integer;
begin
  Result := '';
  try
    Process := TProcess.Create(nil);
    Process.CurrentDirectory := CurrentDir;
    Process.Executable := Executable;
    Process.ShowWindow := swoHIDE;
    Process.StartupOptions := [suoUseShowWindow];
    for I := 0 to Length(Parameters) - 1 do
      Process.Parameters.Add(Parameters[I]);
    for I := 0 to GetEnvironmentVariableCount - 1 do
      Process.Environment.Add(GetEnvironmentString(I));
    Process.Options := [poUsePipes, poNoConsole];
    Process.Parameters.LineBreak := ' ';
    Process.Execute;

    while Process.Running or (Process.Output.NumBytesAvailable > 0) or
    (Process.Stderr.NumBytesAvailable > 0) do
    begin
      if Process.Output.NumBytesAvailable > 0 then begin
        SetLength(Buffer, 1000);
        Count := Process.Output.Read(Buffer[1], Length(Buffer));
        SetLength(Buffer, Count);
        Result := Result + Buffer;
      end;

      if Process.Stderr.NumBytesAvailable > 0 then begin
        SetLength(Buffer, 1000);
        Count := Process.Stderr.Read(Buffer[1], Length(Buffer));
        SetLength(Buffer, Count);
        Result := Result + Buffer;
      end;
      Sleep(1);
    end;

    if Process.ExitCode <> 0 then begin
      Cmd := Process.Executable + ' ' + Process.Parameters.Text;
      raise Exception.Create('Execution of "' + Cmd + '" failed with exit code ' + IntToStr(Process.ExitCode) + ' error: ' + Result);
    end;
  finally
    Process.Free;
  end;
end;

function ClearTool(Parameters: array of string; CurrentDir: string = ''): string;
begin
  Result := Trim(ExecuteProcessOut(ClearToolPath, Parameters, CurrentDir));
end;

function SVN(Parameters: array of string; CurrentDir: string = ''): string;
begin
  Result := Trim(ExecuteProcessOut(SVNPath, Parameters, CurrentDir));
end;

procedure ExecuteNoWait(AExecutable: string; Params: array of string;
  Maximized: Boolean = false; CurrentDir: string = '');
var
  I: Integer;
begin
  with TProcess.Create(nil) do
  try
    Executable := AExecutable;
    CurrentDirectory := CurrentDir;
    for I := 0 to Length(Params) - 1 do
      Parameters.Add(Params[I]);
    if Maximized then ShowWindow := swoMaximize;
    Options := [poNoConsole];
    Execute;
  finally
    Free;
  end;
end;


end.