source: branches/Void/Generators/UPascalGenerator.pas

unit UPascalGenerator;

{$mode Delphi}{$H+}

interface

uses
  Classes, SysUtils, UModel, StrUtils, UOutputGenerator;

type
  TPascalGenerator = class(TOutputGenerator)
  private
    function GenerateVariableValue(Value: TVariableValue): string;
  public
    procedure Generate(Model: TModel); override;
    procedure GenerateModule(Module: TModule);
  end;

implementation

{ TPascalGenerator }

function TPascalGenerator.GenerateVariableValue(Value: TVariableValue): string;
begin
  case Value.ValueType of
    vtVariable: if Assigned(Value.VariableDef) then Result := Value.VariableDef.Name
      else Result := '';
    vtFloat: Result := FloatToStr(Value.FloatConstant);
    vtNumber: Result := IntToStr(Value.NumberConstant);
    vtString: Result := '''' + StringReplace(Value.StringConstant, '''', '''''', [rfReplaceAll]) + '''';
    vtChar: Result := '''' + Value.CharConstant + '''';
  end;
end;

procedure TPascalGenerator.Generate(Model: TModel);
begin
  inherited;
  GenerateModule(Model.Module);
end;

procedure TPascalGenerator.GenerateModule(Module: TModule);
var
  I, P: Integer;
  ParameterText: string;
  Row: string;
begin
  with Module do begin
    // Prepare output
    Output.Clear;
    Output.Add('program ' + Name + ';');
    Output.Add('{$APPTYPE CONSOLE}');

    // var section
    if Variables.Count > 0 then Output.Add('var');
    Inc(IndentCount);
    for I := 0 to Variables.Count - 1 do
      with Variables[I] do
        Output.Add(Indent + Name + ': ' + VarType.Name + ';');
    Dec(IndentCount);

    // Code block
    Output.Add('begin');
    Inc(IndentCount);
    for I := 0 to BeginEnd.Commands.Count - 1 do
      with BeginEnd.Commands[I] do begin
        if Name = 'Assignment' then Output.Add(Indent +
          Parameters[0].VariableDef.Name + ' := ' +
          GenerateVariableValue(TVariableValue(Parameters[1])) + ';')
        else begin
        Row := Name;
        if Parameters.Count > 0 then begin
          ParameterText := '';
          for P := 0 to Parameters.Count - 1 do
            ParameterText := ParameterText + GenerateVariableValue(Parameters[P]) + ', ';
          Row := Row + '(' + Copy(ParameterText, 1, Length(ParameterText) - 2) + ')';
        end;
        Output.Add(Indent + Row + ';');
        end;
      end;
    Dec(IndentCount);
    Output.Add('end.');
  end;
end;

end.