source: branches/Void/Generators/UCGenerator.pas

unit UCGenerator;

{$mode Delphi}{$H+}

interface

uses
  Classes, SysUtils, UModel, StrUtils, UOutputGenerator;

type
  TCGenerator = class(TOutputGenerator)
  private
    function ConvertType(Name: string): string;
    function GenerateVariableValue(Value: TVariableValue): string;
  public
    procedure Generate(Model: TModel); override;
    procedure GenerateModule(Module: TModule);
  end;

implementation

{ TCGenerator }

function TCGenerator.ConvertType(Name: string): string;
begin
  if Name = 'String' then Result := 'char*'
  else if Name = 'Byte' then Result := 'unsigned char'
  else if Name = 'ShortInt' then Result := 'signed char'
  else if Name = 'Word' then Result := 'unsigned int'
  else if Name = 'Integer' then Result := 'int'
  else if Name = 'Real' then Result := 'float'
  else if Name = 'Double' then Result := 'double'
  else if Name = 'Char' then Result := 'char'
  else Result := Name;
end;

function TCGenerator.GenerateVariableValue(Value: TVariableValue): string;
begin
  case Value.ValueType of
    vtVariable: if Assigned(Value.VariableDef) then Result := Value.VariableDef.Name
      else Result := '';
    vtFloat: Result := FloatToStr(Value.FloatConstant);
    vtNumber: Result := IntToStr(Value.NumberConstant);
    vtString: Result := '"' + StringReplace(Value.StringConstant, '"', '\"', [rfReplaceAll]) + '"';
    vtChar: Result := '''' + Value.CharConstant + '''';
  end;
end;

procedure TCGenerator.Generate(Model: TModel);
begin
  inherited;
  IndentCount := 0;
  GenerateModule(Model.Module);
end;

procedure TCGenerator.GenerateModule(Module: TModule);
var
  I, P: Integer;
  Row: string;
  ParameterText: string;
begin
  with Module do begin
    // Prepare output
    Output.Clear;

    Output.Add('int main()');
    Output.Add('{');
    Inc(IndentCount);

    // Variable section
    for I := 0 to Variables.Count - 1 do
      with Variables[I] do
        Output.Add(Indent + ConvertType(VarType.Name) + ' ' + Name + ';');
    if Variables.Count > 0 then Output.Add('');

    // Code block
    for I := 0 to BeginEnd.Commands.Count - 1 do
      with BeginEnd.Commands[I] do begin
        if Name = 'Assignment' then Output.Add(Indent +
          Parameters[0].VariableDef.Name + ' = ' +
          GenerateVariableValue(TVariableValue(Parameters[1])) + ';')
        else begin
          if Name = 'WriteLn' then Row := 'printf'
          else if Name = 'ReadLn' then Row := 'scanf'
          else if Name = 'Exit' then Row := 'exit';
          Row := Row + '(';
          if Parameters.Count > 0 then begin
            ParameterText := '';
            for P := 0 to Parameters.Count - 1 do
              ParameterText := ParameterText + GenerateVariableValue(Parameters[P]) + ', ';
            Row := Row + Copy(ParameterText, 1, Length(ParameterText) - 2);
          end;
          Output.Add(Indent + Row + ');');
        end;
      end;
    Dec(IndentCount);
    Output.Add('}');
  end;
end;

end.