source: branches/AS8051toC/UParser.pas

unit UParser;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils;

const
  Instructions: array[0..40] of string = ('JB', 'JNB', 'NOP', 'LCALL', 'SJMP',
    'PUSH', 'POP', 'MOV', 'ADD', 'SUB', 'MUL', 'DIV', 'RET', 'RETI', 'MOVC',
    'CLR', 'SETB', 'CALL', 'INC', 'DEC', 'ORL', 'ANL', 'SUBB', 'XCH', 'CPL',
    'JC', 'JNC', 'JZ', 'JNZ', 'DJNZ', 'CJNE', 'DB', 'DBIT', 'DS', 'PUBLIC',
    'EXTRN', 'CSEG', 'RSEG', 'JMP', 'DW', 'SWAP');
type
  TErrorEvent = procedure (Message: string) of object;


  { TParser }

  TParser = class
  private
    FOnError: TErrorEvent;
  public
    procedure Error(Text: string); virtual;
    function Expect(Text: string): Boolean; virtual;
    function GetNext(ChangePos: Boolean = False): string; virtual;
    function ReadNext: string; virtual;
    property OnError: TErrorEvent read FOnError write FOnError;
  end;

  { TParserASM51 }

  TParserASM51 = class(TParser)
  public
    Source: string;
    Position: Integer;
    function Expect(Text: string): Boolean; override;
    function GetNext(ChangePos: Boolean = False): string; override;
    function ReadNext: string; override;
    function ReadChar: Char;
    function NextChar: Char;
    function ReadEol: string;
    function IsAlphabetic(Character: char): boolean;
    function IsAlphanumeric(Character: char): boolean;
    function IsHex(Character: char): boolean;
    function IsNumeric(Character: char): boolean;
    function IsIdentificator(Text: string): boolean;
    function IsKeyword(Text: string): Boolean;
    function IsNumber(Text: string): Boolean;
    function IsHexNumber(Text: string): Boolean;
    function IsString(Text: string): Boolean;
    function IsWhiteSpace(Character: char): boolean;
    function Eof: Boolean;
  end;

  TParserMacro = class

  end;


implementation

procedure TParser.Error(Text: string);
begin
  if Assigned(FOnError) then FOnError(Text);
end;

function TParser.Expect(Text: string): Boolean;
begin

end;

function TParser.GetNext(ChangePos: Boolean): string;
begin

end;

function TParser.ReadNext: string;
begin

end;

{ TParserASM51 }

function TParserASM51.Expect(Text: string): Boolean;
var
  NextToken: string;
begin
  NextToken := ReadNext;
  Result := NextToken = Text;
  if not Result then Error('Expected "' + Text + '" but "' + NextToken + '" found');
end;

function TParserASM51.GetNext(ChangePos: Boolean = False): string;
var
  OldPosition: Integer;
begin
  OldPosition := Position;
  while IsWhiteSpace(NextChar) do ReadChar; // Skip white spaces

  if IsAlphabetic(NextChar) or (NextChar = '_') then begin
    Result := ReadChar;
    while IsAlphanumeric(NextChar) or (NextChar = '_') do begin
      Result := Result + ReadChar;
    end;
  end else
  if IsHex(NextChar) then begin
    Result := ReadChar;
    while IsHex(NextChar) do begin
      Result := Result + ReadChar;
    end;
    if NextChar = 'h' then Result := Result + ReadChar;
//    else
  end else Result := ReadChar;
  if not ChangePos then Position := OldPosition;
end;

function TParserASM51.ReadNext: string;
begin
  Result := GetNext(True);
end;

function TParserASM51.ReadChar: Char;
begin
  Result := NextChar;
  Inc(Position);
end;

function TParserASM51.NextChar: Char;
begin
  Result := Source[Position];
end;

function TParserASM51.ReadEol: string;
begin
  Result := '';
  while (NextChar <> #13) and (NextChar <> #10) and not Eof do begin
    Result := Result + ReadChar;
  end;
  if NextChar = #13 then ReadChar;
  if NextChar = #10 then ReadChar;
end;

function TParserASM51.IsAlphabetic(Character: char): boolean;
begin
  Result := (Character in ['a'..'z']) or (Character in ['A'..'Z']);
end;

function TParserASM51.IsAlphanumeric(Character: char): boolean;
begin
  Result := IsAlphabetic(Character) or IsNumeric(Character);
end;

function TParserASM51.IsNumeric(Character: char): boolean;
begin
  Result := Character in ['0'..'9'];
end;

function TParserASM51.IsHex(Character: char): boolean;
begin
  Result := IsNumeric(Character) or (Character in ['A'..'F']) or
    (Character in ['a'..'f']);
end;

function TParserASM51.IsString(Text: string): Boolean;
begin
  raise Exception.Create('Not implemented');
end;

function TParserASM51.IsIdentificator(Text: string): boolean;
var
  I: integer;
begin
  Result := True;
  if Length(Text) = 0 then
    Result := False;
  //if IsKeyWord(Text) then
  //  Result := False;
  if Length(Text) > 0 then
    if not (Text[1] in ['a'..'z', 'A'..'Z', '_']) then
      Result := False;
  for I := 2 to Length(Text) do
    if not (Text[i] in ['a'..'z', 'A'..'Z', '0'..'9', '_']) then
      Result := False;
end;

function TParserASM51.IsWhiteSpace(Character: char): boolean;
begin
  Result := (Character <= ' ');
end;

function TParserASM51.Eof: Boolean;
begin
  Result := (Position > Length(Source)) or (Trim(Copy(Source, Position, Length(Source))) = '');
end;

function TParserASM51.IsKeyword(Text: string): Boolean;
var
  I: integer;
begin
  Result := False;
  for I := 0 to High(Instructions) do
    if Instructions[I] = Text then
      Result := True;
end;

function TParserASM51.IsNumber(Text: string): Boolean;
var
  Num: Integer;
begin
  Result := TryStrToInt(Text, Num);
end;

function TParserASM51.IsHexNumber(Text: string): Boolean;
var
  Num: Integer;
begin
  Result := TryStrToInt('$' + Text, Num);
end;


end.