source: tags/1.1.0/Forms/UFormMain.pas

unit UFormMain;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, Menus,
  ExtCtrls, UEngine, LCLType, types, UTranslator, UApplicationInfo, URegistry,
  UPersistentForm;

type

  { TFormMain }

  TFormMain = class(TForm)
    ApplicationInfo1: TApplicationInfo;
    PaintBox1: TPaintBox;
    PersistentForm1: TPersistentForm;
    Timer1: TTimer;
    Translator1: TTranslator;
    procedure FormActivate(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormKeyPress(Sender: TObject; var Key: char);
    procedure FormKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);
    procedure FormShow(Sender: TObject);
    procedure PaintBox1MouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure PaintBox1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure PaintBox1MouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure PaintBox1MouseWheelDown(Sender: TObject; Shift: TShiftState;
      MousePos: TPoint; var Handled: Boolean);
    procedure PaintBox1MouseWheelUp(Sender: TObject; Shift: TShiftState;
      MousePos: TPoint; var Handled: Boolean);
    procedure PaintBox1Paint(Sender: TObject);
    procedure PaintBox1Resize(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    Initialized: Boolean;
    procedure LoadConfig;
    procedure SaveConfig;
  public
    FullScreen: Boolean;
    Engine: TEngine;
    procedure EraseBackground(DC: HDC); override;
  end;

var
  FormMain: TFormMain;


implementation

{$R *.lfm}

uses
  UFormImages;

{ TFormMain }

procedure TFormMain.FormCreate(Sender: TObject);
begin
  Engine := TEngine.Create;
  LoadConfig;
  //PaintBox1.ControlStyle := [csOpaque];
  Randomize;
end;

procedure TFormMain.FormActivate(Sender: TObject);
begin
end;

procedure TFormMain.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  PersistentForm1.Save(Self);
end;

procedure TFormMain.FormDestroy(Sender: TObject);
begin
  SaveConfig;
  Engine.Free;
end;

procedure TFormMain.FormKeyPress(Sender: TObject; var Key: char);
begin
  if Key = #32 then begin
    if Engine.State = gsRunning then Engine.State := gsPaused
    else if Engine.State = gsPaused then Engine.State := gsRunning;
  end;
end;

procedure TFormMain.FormKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState
  );
const
  KeyF11 = 122;
begin
  if Key = KeyF11 then begin
    FullScreen := not FullScreen;
    PersistentForm1.SetFullScreen(FormMain.FullScreen);
  end else
    Engine.KeyUp(Key);
end;

procedure TFormMain.FormShow(Sender: TObject);
begin
  if not Initialized then begin
    Initialized := True;
    PersistentForm1.RegistryContext := ApplicationInfo1.GetRegistryContext;
    PersistentForm1.Load(Self, False, True);
    FullScreen := PersistentForm1.FormFullScreen;
    Engine.InitMenus;
    Engine.ImagePassenger.Picture.Assign(FormImages.ImagePassenger.Picture);
    Engine.ImageLocomotive.Picture.Assign(FormImages.ImageLocomotive.Picture);
    Engine.Map.Size := Point(PaintBox1.Width, PaintBox1.Height);
    Engine.View.DestRect := Rect(0, 0, PaintBox1.Width, PaintBox1.Height);
    Engine.MainMenu;
  end;
end;

procedure TFormMain.PaintBox1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Engine.MouseDown(Button, Point(X, Y));
end;

procedure TFormMain.PaintBox1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  Engine.MouseMove(Point(X, Y));
end;

procedure TFormMain.PaintBox1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Engine.MouseUp(Button, Point(X, Y));
end;

procedure TFormMain.PaintBox1MouseWheelDown(Sender: TObject;
  Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
begin
  Engine.View.Zoom := Engine.View.Zoom / 1.2;
end;

procedure TFormMain.PaintBox1MouseWheelUp(Sender: TObject; Shift: TShiftState;
  MousePos: TPoint; var Handled: Boolean);
begin
  Engine.View.Zoom := Engine.View.Zoom * 1.2;
end;

procedure TFormMain.PaintBox1Paint(Sender: TObject);
begin
  Engine.View.DestRect := Rect(0, 0, PaintBox1.Width, PaintBox1.Height);
  Engine.Paint(PaintBox1.Canvas, Point(PaintBox1.Width, PaintBox1.Height));
end;

procedure TFormMain.PaintBox1Resize(Sender: TObject);
begin
  Engine.Redraw;
end;

procedure TFormMain.Timer1Timer(Sender: TObject);
begin
  Engine.Tick;
  if Engine.RedrawPending then
    PaintBox1.Repaint;
end;

procedure TFormMain.EraseBackground(DC: HDC);
begin
  // Do nothing, all background space covered by controls
end;

procedure TFormMain.LoadConfig;
var
  LangCode: string;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;

    if ValueExists('LanguageCode') then begin
      LangCode := ReadStringWithDefault('LanguageCode', '');
      Translator1.Language := Translator1.Languages.SearchByCode(LangCode);
    end else Translator1.Language := Translator1.Languages.SearchByCode('');
    Engine.DarkMode := ReadBoolWithDefault('DarkMode', False);
    Engine.HighestServedPassengerCount := ReadIntegerWithDefault('HighestPassengers', 0);
    Engine.HighestServedDaysCount := ReadIntegerWithDefault('HighestDays', 0);
  finally
    Free;
  end;
end;

procedure TFormMain.SaveConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;

    if Assigned(Translator1.Language) and (Translator1.Language.Code <> '') then
      WriteString('LanguageCode', Translator1.Language.Code)
      else DeleteValue('LanguageCode');
    WriteBool('DarkMode', Engine.DarkMode);
    WriteInteger('HighestPassengers', Engine.HighestServedPassengerCount);
    WriteInteger('HighestDays', Engine.HighestServedDaysCount);
  finally
    Free;
  end;
end;


end.