source: trunk/Forms/UFormAccounts.pas

unit UFormAccounts;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  StdCtrls, ExtCtrls, ActnList, Menus, Buttons, SpecializedList;

type

  { TFormAccounts }

  TFormAccounts = class(TForm)
    AAdd: TAction;
    ARemove: TAction;
    ActionList1: TActionList;
    BitBtnAdd: TBitBtn;
    BitBtnRemove: TBitBtn;
    ButtonOk: TButton;
    ButtonCancel: TButton;
    LabeledEditToken: TLabeledEdit;
    LabeledEditName: TLabeledEdit;
    ListView1: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    PopupMenu1: TPopupMenu;
    procedure AAddExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure LabeledEditTokenChange(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  private
    DisableEditUpdate: Boolean;
  public
    Accounts: TListObject;
    procedure Reload;
    procedure UpdateInterface;
  end;

var
  FormAccounts: TFormAccounts;

implementation

uses
  UCore;

{$R *.lfm}

{ TFormAccounts }

procedure TFormAccounts.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < Accounts.Count) then
  with TAccount(Accounts[Item.Index]) do begin
    Item.Caption := IntToStr(Item.Index + 1);
    Item.Data := Accounts[Item.Index];
    Item.SubItems.Add(Name);
    Item.SubItems.Add(Number);
    Item.SubItems.Add(BankCode);
    Item.SubItems.Add(FloatToStr(Balance));
    Item.SubItems.Add(DateToStr(Time));
    Item.SubItems.Add(Token);
  end;
end;

procedure TFormAccounts.ListView1SelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  if Assigned(ListView1.Selected) then begin
    DisableEditUpdate := True;
    LabeledEditToken.Text := TAccount(ListView1.Selected.Data).Token;
    LabeledEditName.Text := TAccount(ListView1.Selected.Data).Name;
    DisableEditUpdate := False;
  end;
  UpdateInterface;
end;

procedure TFormAccounts.FormShow(Sender: TObject);
begin
  UpdateInterface;
  Reload;
end;

procedure TFormAccounts.LabeledEditTokenChange(Sender: TObject);
begin
  if not DisableEditUpdate then begin
    if Assigned(ListView1.Selected) then begin
      TAccount(ListView1.Selected.Data).Token := LabeledEditToken.Text;
      TAccount(ListView1.Selected.Data).Name := LabeledEditName.Text;
    end;
    Reload;
  end;
end;

procedure TFormAccounts.FormCreate(Sender: TObject);
begin
  Accounts := TAccountList.Create;
end;

procedure TFormAccounts.ARemoveExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    Accounts.Delete(Accounts.IndexOf(ListView1.Selected.Data));
    Reload;
  end;
end;

procedure TFormAccounts.AAddExecute(Sender: TObject);
begin
  with Accounts.AddNew(TAccount.Create) do begin
  end;
  Reload;
end;

procedure TFormAccounts.FormDestroy(Sender: TObject);
begin
  FreeAndNil(Accounts);
end;

procedure TFormAccounts.Reload;
begin
  ListView1.Items.Count := Accounts.Count;
  ListView1.Refresh;
  UpdateInterface;
end;

procedure TFormAccounts.UpdateInterface;
begin
  ARemove.Enabled := Assigned(ListView1.Selected);
  LabeledEditToken.Enabled := Assigned(ListView1.Selected);
  LabeledEditName.Enabled := Assigned(ListView1.Selected);
end;

end.