source: trunk/UCore.pas

unit UCore;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, XMLConf, LazFileUtils, ActnList, Controls, UVCS, UProject,
  ULastOpenedList, Forms, Dialogs, Menus, Contnrs, UBackend;

type

  { TCore }

  TCore = class(TDataModule)
    AAbout: TAction;
    ACommandUpdate: TAction;
    ACommandCleanup: TAction;
    ACommandCommit: TAction;
    ACommandStatus: TAction;
    AProjectGroupSaveAs: TAction;
    AProjectGroupSave: TAction;
    AProjectGroupClose: TAction;
    AProjectGroupOpen: TAction;
    AProjectGroupNew: TAction;
    AViewTest: TAction;
    AProjectCheckout: TAction;
    AProjectClose: TAction;
    ActionList1: TActionList;
    AHelp: TAction;
    AProjectOpen: TAction;
    AQuit: TAction;
    ASettings: TAction;
    AViewFavorites: TAction;
    ImageList1: TImageList;
    LastOpenedListProject: TLastOpenedList;
    LastOpenedListNewDir: TLastOpenedList;
    LastOpenedListProjectGroup: TLastOpenedList;
    LastOpenedListRepoURL: TLastOpenedList;
    OpenDialog1: TOpenDialog;
    SaveDialog1: TSaveDialog;
    XMLConfig1: TXMLConfig;
    procedure ACommandCheckoutExecute(Sender: TObject);
    procedure ACommandCleanupExecute(Sender: TObject);
    procedure ACommandCommitExecute(Sender: TObject);
    procedure ACommandUpdateExecute(Sender: TObject);
    procedure AProjectCheckoutExecute(Sender: TObject);
    procedure AProjectCloseExecute(Sender: TObject);
    procedure AProjectGroupCloseExecute(Sender: TObject);
    procedure AProjectGroupNewExecute(Sender: TObject);
    procedure AProjectGroupOpenExecute(Sender: TObject);
    procedure AProjectGroupSaveAsExecute(Sender: TObject);
    procedure AProjectGroupSaveExecute(Sender: TObject);
    procedure AProjectOpenExecute(Sender: TObject);
    procedure AQuitExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure AViewTestExecute(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
    procedure LastOpenedListProjectChange(Sender: TObject);
    procedure LastOpenedListProjectGroupChange(Sender: TObject);
  private
    procedure UpdateInterface;
    procedure RegisterBackends;
    procedure RegisterBackend(Backend: TBackend);
    function DetectBackend(Directory: string): TBackend;
  public
    Backends: TObjectList; // TList<TBackend>
    Project: TProject;
    ProjectGroup: TProjectGroup;
    UserName: string;
    Email: string;
    procedure LoadConfig;
    procedure SaveConfig;
    procedure Init;
    procedure Done;
    procedure ProjectOpen(Directory: string);
    procedure ProjectGroupOpen(FileName: string);
  end;

var
  Core: TCore;

implementation

{$R *.lfm}

uses
  UFormMain, UFormBrowse, UFormSettings, UFormCommit, UFormCheckout,
  USubversion, UBazaar, UCVS, UGit, UFormTest, UFormProjectGroup;

{ TCore }

procedure TCore.AQuitExecute(Sender: TObject);
begin
  Application.Terminate;
end;

procedure TCore.ASettingsExecute(Sender: TObject);
begin
  FormSettings.Load(XMLConfig1);
  if FormSettings.ShowModal = mrOk then begin
    FormSettings.Save(XMLConfig1);
  end;
end;

procedure TCore.AViewTestExecute(Sender: TObject);
begin
  FormTest.Show;
end;

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  Backends := TObjectList.Create;
  Project := nil;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  FreeAndNil(Project);
  FreeAndNil(Backends);
end;

procedure TCore.LastOpenedListProjectChange(Sender: TObject);
begin
  LastOpenedListProject.LoadToMenuItem(FormMain.MenuItemOpenRecent, FormMain.OpenRecentExecute);
end;

procedure TCore.LastOpenedListProjectGroupChange(Sender: TObject);
begin
  LastOpenedListProjectGroup.LoadToMenuItem(FormMain.MenuItemRecentProjectGroup, FormMain.ProjectGroupOpenRecentExecute);
end;

procedure TCore.UpdateInterface;
begin
  AProjectClose.Enabled := Assigned(Project);
  AProjectGroupClose.Enabled := Assigned(ProjectGroup);
  AProjectGroupSave.Enabled := Assigned(ProjectGroup);
  AProjectGroupSaveAs.Enabled := Assigned(ProjectGroup);
  FormMain.UpdateInterface;
end;

procedure TCore.RegisterBackends;
begin
  RegisterBackend(TBackendSubversion.Create);
  RegisterBackend(TBackendBazaar.Create);
  RegisterBackend(TBackendCVS.Create);
  RegisterBackend(TBackendGit.Create);
end;

procedure TCore.RegisterBackend(Backend: TBackend);
begin
  Backends.Add(Backend);
end;

function TCore.DetectBackend(Directory: string): TBackend;
var
  I: Integer;
begin
  I := 0;
  while (I < Backends.Count) and (not TBackend(Backends[I]).IsWorkingCopy(Directory)) do Inc(I);
  if I < Backends.Count then Result := TBackend(Backends[I])
    else Result := nil;
end;

procedure TCore.LoadConfig;
begin
  LastOpenedListProject.LoadFromXMLConfig(XMLConfig1, 'LastOpenedProjects');
  LastOpenedListRepoURL.LoadFromXMLConfig(XMLConfig1, 'LastOpenedRepoURL');
  LastOpenedListNewDir.LoadFromXMLConfig(XMLConfig1, 'LastOpenedNewDir');
  LastOpenedListProjectGroup.LoadFromXMLConfig(XMLConfig1, 'LastOpenedListProjectGroup');
  UserName := XMLConfig1.GetValue('UserName', '');
  Email := XMLConfig1.GetValue('Email', '');
end;

procedure TCore.SaveConfig;
begin
  LastOpenedListProject.SaveToXMLConfig(XMLConfig1, 'LastOpenedProjects');
  LastOpenedListRepoURL.SaveToXMLConfig(XMLConfig1, 'LastOpenedRepoURL');
  LastOpenedListNewDir.SaveToXMLConfig(XMLConfig1, 'LastOpenedNewDir');
  LastOpenedListProjectGroup.SaveToXMLConfig(XMLConfig1, 'LastOpenedListProjectGroup');
  XMLConfig1.SetValue('UserName', UserName);
  XMLConfig1.SetValue('Email', Email);
  XmlConfig1.Flush;
end;

procedure TCore.Init;
begin
  RegisterBackends;
  XMLConfig1.Filename := GetAppConfigDir(False) + 'Config.xml';
  ForceDirectoriesUTF8(ExtractFileDir(XMLConfig1.Filename));
  LoadConfig;
  if (LastOpenedListProject.Items.Count > 0) and DirectoryExistsUTF8(LastOpenedListProject.Items[0]) then
    ProjectOpen(LastOpenedListProject.Items[0]);
end;

procedure TCore.Done;
begin
  SaveConfig;
end;

procedure TCore.ProjectOpen(Directory: string);
begin
  AProjectClose.Execute;
  Project := TProject.Create;
  Project.Backend := DetectBackend(Directory);
  Project.WorkingCopy.UserName := Core.UserName;
  Project.WorkingCopy.Email := Core.Email;
  if Assigned(Project.Backend) then begin
    Project.Directory := Directory;
    UpdateInterface;
    FormBrowse.Directory := Project.Directory;
    FormBrowse.ReloadList;
    LastOpenedListProject.AddItem(Project.Directory);
  end else ShowMessage('Directory ''' + Directory + ''' not recognized as working copy of any of supported VCS systems');
end;

procedure TCore.ProjectGroupOpen(FileName: string);
begin
  AProjectGroupClose.Execute;
  ProjectGroup := TProjectGroup.Create;
  ProjectGroup.FileName := FileName;
  UpdateInterface;
  FormProjectGroup.ReloadTree;
  LastOpenedListProjectGroup.AddItem(FileName);
end;

procedure TCore.AProjectOpenExecute(Sender: TObject);
var
  Dir: string;
  OldDir: string;
begin
  if Assigned(Project) then OldDir := Project.Directory
    else OldDir := '';
  if SelectDirectory('Open project', OldDir, Dir) then begin
    ProjectOpen(Dir);
  end;
end;

procedure TCore.AProjectCloseExecute(Sender: TObject);
begin
  FreeAndNil(Project);
  FormBrowse.Directory := '';
  FormBrowse.ReloadList;
  UpdateInterface;
end;

procedure TCore.AProjectGroupCloseExecute(Sender: TObject);
begin
  FreeAndNil(ProjectGroup);
  UpdateInterface;
  FormProjectGroup.ReloadTree;
end;

procedure TCore.AProjectGroupNewExecute(Sender: TObject);
begin
  AProjectClose.Execute;
  ProjectGroup := TProjectGroup.Create;
  ProjectGroup.FileName := 'New project group.vcgrp';
  UpdateInterface;
  FormProjectGroup.ReloadTree;
end;

procedure TCore.AProjectGroupOpenExecute(Sender: TObject);
begin
  if LastOpenedListProjectGroup.Items.Count > 0 then
    OpenDialog1.FileName := LastOpenedListProjectGroup.Items[0];
  if OpenDialog1.Execute then begin
    AProjectClose.Execute;
    ProjectGroupOpen(OpenDialog1.FileName);
  end;
end;

procedure TCore.AProjectGroupSaveAsExecute(Sender: TObject);
begin
  SaveDialog1.FileName := ProjectGroup.FileName;
  if SaveDialog1.Execute then begin
    ProjectGroup.SaveToFile(SaveDialog1.FileName);
    UpdateInterface;
  end;
end;

procedure TCore.AProjectGroupSaveExecute(Sender: TObject);
begin
  if FileExistsUTF8(ProjectGroup.FileName) then ProjectGroup.SaveToFile(ProjectGroup.FileName)
    else AProjectGroupSaveAs.Execute;
end;

procedure TCore.ACommandUpdateExecute(Sender: TObject);
begin
  Project.WorkingCopy.Update;
end;

procedure TCore.AProjectCheckoutExecute(Sender: TObject);
var
  TempProject: TProject;
begin
  if LastOpenedListRepoURL.Items.Count > 0 then
    FormCheckout.EditURL.Text := LastOpenedListRepoURL.Items[0];
  if LastOpenedListNewDir.Items.Count > 0 then
    FormCheckout.EditDir.Text := LastOpenedListNewDir.Items[0];
  if FormCheckout.ShowModal = mrOk then begin
    LastOpenedListRepoURL.AddItem(FormCheckout.EditURL.Text);
    LastOpenedListNewDir.AddItem(FormCheckout.EditDir.Text);
    TempProject := TProject.Create;
    try
      TempProject.Backend := TBackend(FormCheckout.ComboBox1.Items.Objects[FormCheckout.ComboBox1.ItemIndex]);
      TempProject.Directory := FormCheckout.EditDir.Text;
      TempProject.RepositoryURL := FormCheckout.EditURL.Text;
      TempProject.WorkingCopy.Checkout;
    finally
      TempProject.Free;
    end;
    ProjectOpen(FormCheckout.EditDir.Text);
  end;
end;

procedure TCore.ACommandCleanupExecute(Sender: TObject);
begin
  Project.WorkingCopy.Cleanup;
end;

procedure TCore.ACommandCheckoutExecute(Sender: TObject);
begin

end;

procedure TCore.ACommandCommitExecute(Sender: TObject);
begin
  if FormCommit.ShowModal = mrOk then begin
    Project.WorkingCopy.Commit(FormCommit.MemoMessage.Lines);
  end;
end;

end.