source: branches/virtualcpu4/Forms/UFormMain.pas

unit UFormMain;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, StdCtrls, ExtCtrls,
  ComCtrls, UCpu, UMachine, UInstructionWriter;

type

  { TFormMain }

  TFormMain = class(TForm)
    ButtonAssembler: TButton;
    ButtonCompilerPascal: TButton;
    ButtonClearMemory: TButton;
    ButtonScreen: TButton;
    ButtonDisassembler: TButton;
    ButtonMemory: TButton;
    ButtonCpuState: TButton;
    ButtonConsole: TButton;
    ButtonStart: TButton;
    ButtonStop: TButton;
    procedure ButtonAssemblerClick(Sender: TObject);
    procedure ButtonClearMemoryClick(Sender: TObject);
    procedure ButtonCompilerPascalClick(Sender: TObject);
    procedure ButtonConsoleClick(Sender: TObject);
    procedure ButtonCpuStateClick(Sender: TObject);
    procedure ButtonMemoryClick(Sender: TObject);
    procedure ButtonScreenClick(Sender: TObject);
    procedure ButtonDisassemblerClick(Sender: TObject);
    procedure ButtonStartClick(Sender: TObject);
    procedure ButtonStopClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    procedure LoadProgram;
  public
    Machine: TMachine;
    InstructionWriter: TInstructionWriter;
  end;

var
  FormMain: TFormMain;


implementation

{$R *.lfm}

uses
  UFormDisassembler, UFormMemory, UFormCpuState, UFormScreen, UFormConsole,
  UFormAssembler, UFormCompilerPascal;

{ TFormMain }

procedure TFormMain.ButtonStartClick(Sender: TObject);
begin
  Machine.Cpu.Start;
end;

procedure TFormMain.ButtonDisassemblerClick(Sender: TObject);
begin
  if not Assigned(FormDisassembler) then
    FormDisassembler := TFormDisassembler.Create(Self);
  FormDisassembler.Disassembler.Cpu := Machine.Cpu;
  FormDisassembler.Show;
  FormDisassembler.Reload;
end;

procedure TFormMain.ButtonMemoryClick(Sender: TObject);
begin
  if not Assigned(FormMemory) then
    FormMemory := TFormMemory.Create(Self);
  FormMemory.Machine := Machine;
  FormMemory.Show;
  FormMemory.Reload;
end;

procedure TFormMain.ButtonScreenClick(Sender: TObject);
begin
  if not Assigned(FormScreen) then
    FormScreen := TFormScreen.Create(Self);
  FormScreen.Machine := Machine;
  FormScreen.Show;
  FormScreen.Reload;
end;

procedure TFormMain.ButtonCpuStateClick(Sender: TObject);
begin
  if not Assigned(FormCpuState) then
    FormCpuState := TFormCpuState.Create(Self);
  FormCpuState.Machine := Machine;
  FormCpuState.Show;
  FormCpuState.Reload;
end;

procedure TFormMain.ButtonConsoleClick(Sender: TObject);
begin
  if not Assigned(FormConsole) then
    FormConsole := TFormConsole.Create(Self);
  FormConsole.Machine := Machine;
  FormConsole.Show;
end;

procedure TFormMain.ButtonAssemblerClick(Sender: TObject);
begin
  if not Assigned(FormAssembler) then
    FormAssembler := TFormAssembler.Create(Self);
  FormAssembler.Assembler.InstructionWriter.Cpu := Machine.Cpu;
  FormAssembler.Show;
end;

procedure TFormMain.ButtonClearMemoryClick(Sender: TObject);
begin
  Machine.ClearMemory;
end;

procedure TFormMain.ButtonCompilerPascalClick(Sender: TObject);
begin
  if not Assigned(FormCompilerPascal) then
    FormCompilerPascal := TFormCompilerPascal.Create(Self);
  FormCompilerPascal.CompilerPascal.Reader.Cpu := Machine.Cpu;
  FormCompilerPascal.Show;
end;

procedure TFormMain.ButtonStopClick(Sender: TObject);
begin
  Machine.Cpu.Stop;
end;

procedure TFormMain.FormCreate(Sender: TObject);
begin
  Machine := TMachine.Create;
  InstructionWriter := TInstructionWriter.Create;
  InstructionWriter.Cpu := Machine.Cpu;
end;

procedure TFormMain.FormDestroy(Sender: TObject);
begin
  InstructionWriter.Free;
  Machine.Free;
end;

procedure TFormMain.FormShow(Sender: TObject);
begin
  LoadProgram;
end;

procedure TFormMain.LoadProgram;
var
  R1: Byte;
  R2: Byte;
  R3: Byte;
  R4: Byte;
  LabelText: Integer;
  LabelText2: Integer;
  LabelPrint: Integer;
  LabelClearScreen: Integer;
  LabelPrintLoop: Integer;
  LabelConsole: Integer;
  LabelMain: Integer;
begin
  R1 := 1;
  R2 := 2;
  R3 := 3;
  R4 := 4;
  with InstructionWriter do begin
    Init;
    DataPrefix32; Loadi(R1, $12345678);
    DataPrefix8; Loadi(R1, $ff);
    DataPrefix8; Convert(R1);

    LabelMain := $100;
    Jump(LabelMain);

  LabelText := IP;
    WriteString('Hello World!');

  LabelText2 := IP;
    WriteString('Good day!');
    Write8(0);
    Write8(0);
    Write8(0);
    Write8(0);

  LabelPrint := IP;
    Push(R3);
    Push(R2);
    Push(R1);
  LabelPrintLoop := IP;
    DataPrefix8; LoadMem(R3, R1);
    AddrPrefix8; DataPrefix8; Output(0, R3);
    Increment(R1);
    Decrement(R2);
    Test(R2);
    AddrPrefix8; JumpRelNotZero(LabelPrintLoop);
    Pop(R1);
    Pop(R2);
    Pop(R3);
    Return;

    IP := LabelMain;

    // Print Hello world text
    Loadi(R1, LabelText);
    Loadi(R2, 12);
    Call(LabelPrint);
    Loadi(R1, LabelText2);
    Loadi(R2, 9);
    Call(LabelPrint);

    // Draw to video memory
    Loadi(R1, Machine.Screen.MemoryBase);
    Loadi(R2, $10000);
    Loadi(R3, $7f);
  LabelClearScreen := IP;
    DataPrefix8; StoreMem(R1, R3);
    Increment(R1);
    Decrement(R2);
    Test(R2);
    AddrPrefix8; JumpRelNotZero(LabelClearScreen);

    // Update screen area
    Push(R1);
    Loadi(R1, 0);
    Output(4, R1);
    Loadi(R1, $10000);
    Output(5, R1);
    Pop(R1);

    // Read keyboard and print to console
    Loadi(R1, 0);
  LabelConsole := IP;
    Increment(R1);
    Loadi(R2, $ff);
    DataPrefix8; StoreMem(R2, R1);
    AddrPrefix8; DataPrefix8; Input(R2, 0);
    AddrPrefix8; DataPrefix8; Output(0, R2);
    Jump(LabelConsole);

    Halt;
  end;
end;

end.