source: trunk/ULoaderForm.pas

unit ULoaderForm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls, Menus, UHostAddressList;

type
  TLoaderForm = class(TForm)
    Label1: TLabel;
    Edit1: TEdit;
    Label2: TLabel;
    Edit2: TEdit;
    Label3: TLabel;
    ButtonConnect: TButton;
    CheckBox1: TCheckBox;
    CheckBox2: TCheckBox;
    CheckBox3: TCheckBox;
    Label4: TLabel;
    Edit4: TEdit;
    Edit3: TEdit;
    ListView1: TListView;
    ButtonSave: TButton;
    ButtonRemove: TButton;
    ButtonTools: TButton;
    PopupMenu1: TPopupMenu;
    OpenDialog1: TOpenDialog;
    SaveDialog1: TSaveDialog;
    RemoveAllAddresses1: TMenuItem;
    ClearCache1: TMenuItem;
    N1: TMenuItem;
    ExportAddresses1: TMenuItem;
    ImportAddresses1: TMenuItem;
    procedure FormCreate(Sender: TObject);
    procedure ExportAddresses1Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ButtonRemoveClick(Sender: TObject);
    procedure ButtonSaveClick(Sender: TObject);
    procedure ButtonToolsClick(Sender: TObject);
    procedure ImportAddresses1Click(Sender: TObject);
    procedure RemoveAllAddresses1Click(Sender: TObject);
    procedure ButtonConnectClick(Sender: TObject);
  private
    HostAddressList: THostAddressList;
    RegistryKey: string;
    procedure LoadFromRegistry;
    procedure SaveToRegistry;
    procedure UpdateListView1;
    procedure LoadFormPosition(Form: TForm);
    procedure SaveFormPosition(Form: TForm);
  public
    { Public declarations }
  end;

var
  LoaderForm: TLoaderForm;

implementation

uses
  UApplicationInfo, URegistry, Registry, IdTCPClient, IdTCPConnection,
  UMainForm;

{$R *.dfm}

{ TLoaderForm }

procedure TLoaderForm.ButtonSaveClick(Sender: TObject);
var
  I: Integer;
  FoundIndex: Integer;
  NewHostAddress: THostAddress;
begin
  FoundIndex := -1;
  for I := 0 to HostAddressList.Count - 1 do begin
    if (THostAddress(HostAddressList[I]).Address = Edit1.Text) and (THostAddress(HostAddressList[I]).User = Edit2.Text) then begin
      FoundIndex := I;
      Break;
    end;
  end;
  if FoundIndex = -1 then begin
    NewHostAddress := THostAddress.Create;
    with NewHostAddress do begin
      Address := Edit1.Text;
      User := Edit2.Text;
      Note := Edit4.Text;
      if KeepPassword then Password := Edit3.Text
        else Password := '';
      KeepPassword := CheckBox1.Checked;
      SecureMode := CheckBox2.Checked;
    end;
    HostAddressList.Add(NewHostAddress);
  end else begin
    with THostAddress(HostAddressList[FoundIndex]) do begin
      if KeepPassword then Password := Edit3.Text
        else Password := '';
      Note := Edit4.Text;
      KeepPassword := CheckBox1.Checked;
      SecureMode := CheckBox2.Checked;
    end;
  end;
  UpdateListView1;
end;

procedure TLoaderForm.ButtonToolsClick(Sender: TObject);
var
  PopupPoint: TPoint;
begin
  PopupPoint := Point(ButtonTools.Left, ButtonTools.Top + ButtonTools.Height);
  PopupPoint := ClientToScreen(PopupPoint);
  PopupMenu1.Popup(PopupPoint.X, PopupPoint.Y);
end;

procedure TLoaderForm.ButtonConnectClick(Sender: TObject);
begin
  MainForm.Show;
  MainForm.RouterOS.Connect(Edit1.Text, Edit2.Text, Edit3.Text);
  Hide;
end;

procedure TLoaderForm.ButtonRemoveClick(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    HostAddressList.Delete(ListView1.Selected.Index);
    UpdateListView1;
  end;
end;

procedure TLoaderForm.ExportAddresses1Click(Sender: TObject);
begin
  if SaveDialog1.Execute then begin
    HostAddressList.SaveToXML(SaveDialog1.FileName);
  end;
end;

procedure TLoaderForm.FormCreate(Sender: TObject);
begin
  HostAddressList := THostAddressList.Create;
  RegistryKey := '\Software\' + ApplicationInfo.CompanyName + '\' + ApplicationInfo.Name;
  LoadFromRegistry;
  UpdateListView1;
end;

procedure TLoaderForm.FormDestroy(Sender: TObject);
begin
  SaveToRegistry;
  HostAddressList.Free;
end;

procedure TLoaderForm.ImportAddresses1Click(Sender: TObject);
begin
  if OpenDialog1.Execute then begin
    HostAddressList.LoadFromXML(OpenDialog1.FileName);
    UpdateListView1;
  end;
end;

procedure TLoaderForm.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if Item.Index < HostAddressList.Count then
  with Item, THostAddress(HostAddressList[Item.Index]) do begin
    Caption := Address;
    with SubItems do begin
      Add(User);
      Add(Note);
    end;
  end;
end;

procedure TLoaderForm.ListView1SelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  ButtonRemove.Enabled := Assigned(ListView1.Selected);
  if Assigned(ListView1.Selected) then
  with THostAddress(HostAddressList[ListView1.Selected.Index]) do begin
    Edit1.Text := Address;
    Edit2.Text := User;
    Edit3.Text := Password;
    Edit4.Text := Note;
    CheckBox1.Checked := KeepPassword;
    CheckBox2.Checked := SecureMode;
  end;
end;

procedure TLoaderForm.LoadFormPosition(Form: TForm);
begin
  with Form, TRegistryEx.Create do
  try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(RegistryKey + '\Forms\' + Form.Name, True);
    Width := ReadIntegerWithDefault('Width', Width);
    Height := ReadIntegerWithDefault('Height', Height);
    Top := ReadIntegerWithDefault('Top', (Screen.Height - Height) div 2);
    Left := ReadIntegerWithDefault('Left', (Screen.Width - Width) div 2);
    if Left < 0 then Left := 0;
    if Left > (Screen.Width - 50) then Left := Screen.Width - 50;
    if Top < 0 then Top := 0;
    if Top > (Screen.Height - 50) then Top := Screen.Height - 50;
    if ReadBoolWithDefault('Maximized', False) then begin
      WindowState := wsMaximized;
    end;
  finally
    Free;
  end;
end;

procedure TLoaderForm.LoadFromRegistry;
begin
  with TRegistryEx.Create do try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(RegistryKey, True);
    CheckBox3.Checked := ReadBoolWithDefault('LoadPreviousSession', True);
    CheckBox2.Checked := ReadBoolWithDefault('SecureMode', True);
    CheckBox1.Checked := ReadBoolWithDefault('KeepPassword', False);
    if CheckBox3.Checked then begin
      Edit1.Text := ReadStringWithDefault('Address', '');
      Edit2.Text := ReadStringWithDefault('User', '');
      Edit3.Text := ReadStringWithDefault('Password', '');
      Edit4.Text := ReadStringWithDefault('Note', '');
    end else
      Edit2.Text := 'admin';
  finally
    Free;
  end;
  HostAddressList.LoadFromRegistry(RegistryKey + '\HostAddressList');
  LoadFormPosition(Self);
end;

procedure TLoaderForm.RemoveAllAddresses1Click(Sender: TObject);
begin
  HostAddressList.Clear;
  UpdateListView1;    
end;

procedure TLoaderForm.SaveFormPosition(Form: TForm);
var
  Pl : TWindowPlacement;  // used for API call
  R: TRect;               // used for wdw pos
begin
  {Calculate window's normal size and position using
  Windows API call - the form's Width, Height, Top and
  Left properties will give maximized window size if
  form is maximised, which is not what we want here}
  Pl.Length := SizeOf(TWindowPlacement);
  GetWindowPlacement(Form.Handle, @Pl);
  R := Pl.rcNormalPosition;

  with Form, TRegistryEx.Create do
  try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(RegistryKey + '\Forms\' + Form.Name, True);
    WriteInteger('Width', R.Right - R.Left);
    WriteInteger('Height', R.Bottom - R.Top);
    WriteInteger('Top', R.Top);
    WriteInteger('Left', R.Left);
    WriteBool('Maximized', WindowState = wsMaximized);
  finally
    Free;
  end;
end;

procedure TLoaderForm.SaveToRegistry;
begin
  with TRegistryEx.Create do try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(RegistryKey, True);

    WriteString('Address', Edit1.Text);
    WriteString('User', Edit2.Text);
    WriteString('Note', Edit4.Text);
    WriteBool('KeepPassword', CheckBox1.Checked);
    if CheckBox1.Checked then WriteString('Password', Edit3.Text)
      else WriteString('Password', '');
    WriteBool('SecureMode', CheckBox2.Checked);
    WriteBool('LoadPreviouisSession', CheckBox3.Checked);
  finally
    Free;
  end;
  HostAddressList.SaveToRegistry(RegistryKey + '\HostAddressList');
  SaveFormPosition(Self);
end;

procedure TLoaderForm.UpdateListView1;
begin
  with ListView1, Items do begin
    Count := HostAddressList.Count;
    Refresh;
  end;
end;

end.