source: trunk/UHostAddressList.pas

unit UHostAddressList;

interface

uses
  Classes, URegistry, Windows, SysUtils, Xmldom, XMLIntf, msxmldom, XMLDoc;

type
  THostAddress = class
    Address: string;
    User: string;
    Note: string;
    Password: string;
    KeepPassword: Boolean;
    SecureMode: Boolean;
    procedure LoadFromXmlNode(Node: IXMLNode);
    procedure SaveToXmlNode(Node: IXMLNode);
  end;

  THostAddressList = class(TList)
    procedure LoadFromXML(FileName: string);
    procedure SaveToXML(FileName: string);
    procedure LoadFromRegistry(Path: string);
    procedure SaveToRegistry(Path: string);
    procedure Clear; override;
  end;

implementation

{ THostAddressList }

procedure THostAddressList.Clear;
var
  I: Integer;
begin
  for I := 0 to Count - 1 do
    THostAddress(Items[I]).Free;
  inherited;
end;

procedure THostAddressList.LoadFromRegistry(Path: string);
var
  I: Integer;
begin
  with TRegistryEx.Create do try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(Path, True);
    Count := ReadIntegerWithDefault('Count', 0);
    for I := 0 to Count - 1 do begin
      OpenKey(Path + '\Host' + IntToStr(I), True);
      Items[I] := THostAddress.Create;
      with THostAddress(Items[I]) do begin
        Address := ReadStringWithDefault('Address', '');
        User := ReadStringWithDefault('User', 'admin');
        Note := ReadStringWithDefault('Note', '');
        Password := ReadStringWithDefault('Password', '');
        KeepPassword := ReadBoolWithDefault('KeepPassword', False);
        SecureMode := ReadBoolWithDefault('SecureMode', True);
      end;
    end;
  finally
    Free;
  end;
end;

procedure THostAddressList.LoadFromXML(FileName: string);
var
  XmlDocument: IXMLDocument;
  I: Integer;
  NewHostAddress: THostAddress;
begin
  if FileExists(FileName) then
  try
    XmlDocument := LoadXMLDocument(Filename);
    XmlDocument.Active := True;
    with XmlDocument do with DocumentElement do begin
      with ChildNodes.Nodes['HostAddressList'] do
      for I := 0 to ChildNodes.Count - 1 do begin
        if ChildNodes.Nodes[I].NodeName = 'HostAddress' then begin
          NewHostAddress := THostAddress.Create;
          Add(NewHostAddress);
          NewHostAddress.LoadFromXmlNode(ChildNodes.Nodes[I]);
        end;
      end;
   end;
  finally
    XmlDocument := nil;
  end;
end;

procedure THostAddressList.SaveToRegistry(Path: string);
var
  I: Integer;
begin
  with TRegistryEx.Create do try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(Path, True);
    WriteInteger('Count', Count);
    for I := 0 to Count - 1 do begin
      OpenKey(Path + '\Host' + IntToStr(I), True);
      with THostAddress(Items[I]) do begin
        WriteString('Address', Address);
        WriteString('User', User);
        WriteString('Note', Note);
        if KeepPassword then WriteString('Password', Password)
          else WriteString('Password', '');
        WriteBool('KeepPassword', KeepPassword);
        WriteBool('SecureMode', SecureMode);
      end;
    end;
  finally
    Free;
  end;
end;

procedure THostAddressList.SaveToXML(FileName: string);
var
  XmlDocument: TXMLDocument;
  NewNode: IXMLNode;
  HostAddressList: IXMLNode;
  I: Integer;
begin
  XmlDocument := TXMLDocument.Create(nil);
  with XmlDocument do begin
    Options := [doNodeAutoIndent, doNodeAutoCreate, doAttrNull, doAutoPrefix,
      doNameSpaceDecl];
    DOMVendor := DOMVendors.Find('Open XML');
    Active := True;
    NewNode := AddChild('Document');
    with NewNode do begin
      HostAddressList := AddChild('HostAddressList');
      for I := 0 to Count - 1 do
        THostAddress(Items[I]).SaveToXmlNode(HostAddressList);
    end;
  end;
  XmlDocument.Version := '1.0';
  XmlDocument.Encoding := 'utf-8';
  XmlDocument.SaveToFile(FileName);
end;

{ THostAddress }

procedure THostAddress.LoadFromXmlNode(Node: IXMLNode);
begin
  with Node do begin
    Address := ChildNodes.Nodes['Address'].Text;
    User := ChildNodes.Nodes['User'].Text;
    Password := ChildNodes.Nodes['Password'].Text;
    Note := ChildNodes.Nodes['Node'].Text;
    KeepPassword := StrToBool(ChildNodes.Nodes['KeepPassword'].Text);
    SecureMode := StrToBool(ChildNodes.Nodes['SecureMode'].Text);
  end;
end;

procedure THostAddress.SaveToXmlNode(Node: IXMLNode);
begin
  Node := Node.AddChild('HostAddress');
  with Node do begin
    AddChild('Address').Text := Address;
    AddChild('User').Text := User;
    AddChild('Password').Text := Password;
    AddChild('Note').Text := Note;
    AddChild('KeepPassword').Text := BoolToStr(KeepPassword);
    AddChild('SecureMode').Text := BoolToStr(SecureMode);
  end;
end;

end.