source: trunk/UContext.pas

unit UContext;

{$mode delphi}

interface

uses
  Classes, SysUtils, UDevice;

type
  { TContextFile }

  TContextFile = class(TContext)
    RootDir: string;
    function CommandPrint(Sender: TObject; Command: TCommand): string;
    function GetCommands: TCommands; override;
  end;

  { TContextRoot }

  TContextRoot = class(TContext)
    function CommandImport(Sender: TObject; Command: TCommand): string;
    function GetCommands: TCommands; override;
  end;


implementation

uses
  UTerminal;

function GetFiles(DirName: string): TStrings;
var
  Path: string;
  SR: TSearchRec;
begin
  Path := ExtractFileDir(DirName);
  Result := TStringList.Create;
  if FindFirst(Path + '*.*', faArchive, SR) = 0 then begin
    repeat
      Result.Add(SR.Name);
    until FindNext(SR) <> 0;
    FindClose(SR);
  end;
end;

{ TContextRoot }

function TContextRoot.CommandImport(Sender: TObject; Command: TCommand): string;
var
  Lines: TStringList;
  FileName: string;
  I: Integer;
  Line: string;
  Index: Integer;
  CombinedLine: string;
  InitialContext: TContext;
begin
  Result := '';
  InitialContext := TTerminal(Sender).Context;
  FileName := TTerminal(Sender).CommandLine;
  if FileExists(FileName) then begin
    Lines := TStringList.Create;
    Lines.LoadFromFile(FileName);
    CombinedLine := '';
    for I := 0 to Lines.Count - 1 do begin
      Line := Lines[I];
      Index := Pos('#', Line);
      if Index > 0 then
        Line := Trim(Copy(Line, 1, Index - 1));
      if Line <> '' then begin
        if Line[Length(Line)] = '\' then begin
          CombinedLine := CombinedLine + Trim(Copy(Line, 1, Length(Line) - 1));
          Continue;
        end else CombinedLine := CombinedLine + Trim(Line);
        TTerminal(Sender).Write(LineEnding + CombinedLine);
        TTerminal(Sender).ExecuteCommand(CombinedLine);
        CombinedLine := '';
      end;
    end;
    Lines.Free;
  end else TTerminal(Sender).Write('File not found');
  TTerminal(Sender).Context := InitialContext;
end;

function TContextRoot.GetCommands: TCommands;
begin
  Result := inherited;
  with Result.AddNew('import', '') do
    Execute := CommandImport;
end;

{ TContextFile }

function TContextFile.CommandPrint(Sender: TObject; Command: TCommand): string;
var
  I: Integer;
  Files: TStrings;
begin
  Files := GetFiles(RootDir);
  Result := '';
  for I := 0 to Files.Count - 1 do begin
    Result := Result + Files[I];
    if I < Files.Count - 1 then
      Result := Result + LineEnding;
  end;
  Files.Free;
end;

function TContextFile.GetCommands: TCommands;
begin
  Result := inherited;
  with Result.AddNew('print', 'Print values of item properties') do
    Execute := CommandPrint;
end;


end.